hlmod.hu
https://hlmod.hu/

ReAPI - Buy Nades Limit
https://hlmod.hu/viewtopic.php?f=134&t=29756
Oldal: 1 / 1

Szerző:  theglorious [ 2019.02.08. 16:39 ]
Hozzászólás témája:  ReAPI - Buy Nades Limit

ReAPI - Buy Nades Limit
Leírás:
  • Körönként korlátozható a gránátok vásárolható mennyisége
Cvar / Beállítás:
  • amx_flashbang_max 2 - Vásárolható villantógránát
  • amx_hegrenade_max 1 - Vásárolható robbanógránát
  • amx_smokegrenade_max 1 - Vásárolható füstgránát
Verzió:
  • v0.0.2
Követelmények:
  • ReApi
Kompatibilis:
  • Amx Mod X 1.8.2
  • Amx Mod X 1.8.3-1.9.0dev
Készítő:
  • steelzorrr
Lang:
  1. [hu]
  2. BNL_FLASHBANG = Ebben a körben csak %d flash gránátot vásárolhatsz
  3. BNL_HEGRENADE = Ebben a körben csak %d he gránátot vásárolhatsz
  4. BNL_SMOKEGRENADE = Ebben a körben csak %d füstgránátot vásárolhatsz

Plugin:
  1. #include <amxmodx>
  2. #include <reapi>
  3.  
  4. #if !defined MAX_PLAYERS
  5. const MAX_PLAYERS = 32;
  6. #endif
  7.  
  8. enum (+=1)
  9. {
  10.     NADE_FLASH = 0,
  11.     NADE_HE,
  12.     NADE_SMOKE,
  13.  
  14.     NADE_NONE
  15. };
  16.  
  17. new const g_szMessages[][]=
  18. {
  19.     "BNL_FLASHBANG",
  20.     "BNL_HEGRENADE",
  21.     "BNL_SMOKEGRENADE"
  22. };
  23.  
  24. new g_pCvars[NADE_NONE];
  25. new g_iLimit[MAX_PLAYERS+1][NADE_NONE];
  26.  
  27. public plugin_init()
  28. {
  29.     register_plugin("[ReAPI:AMXX] Buy Nades Limit", "0.0.2", "steelzorrr");
  30.  
  31.     RegisterHookChain(RG_CBasePlayer_HasRestrictItem, "CPlayer_HasRestrictItem_Pre", .post = false);
  32.     RegisterHookChain(RG_CBasePlayer_Spawn, "CPlayer_Spawn_Post", .post = true);
  33.  
  34.     g_pCvars[NADE_FLASH] = register_cvar("amx_flashbang_max", "2");
  35.     g_pCvars[NADE_HE] = register_cvar("amx_hegrenade_max", "1");
  36.     g_pCvars[NADE_SMOKE] = register_cvar("amx_smokegrenade_max", "1");
  37.  
  38.     register_dictionary("buy_nades_limit.txt");
  39. }
  40.  
  41. public CPlayer_HasRestrictItem_Pre(iPlayer, ItemID:iItem, ItemRestType:iType)
  42. {
  43.     if(iType != ITEM_TYPE_BUYING)
  44.     {
  45.         return HC_CONTINUE
  46.     }  
  47.  
  48.     new iKey = getKeybyItemID(iItem);
  49.  
  50.     if(iKey == NADE_NONE)
  51.     {
  52.         return HC_CONTINUE;
  53.     }
  54.  
  55.     new iLimit = get_pcvar_num(g_pCvars[iKey]);
  56.  
  57.     if(++g_iLimit[iPlayer][iKey] > iLimit)
  58.     {
  59.         client_print(iPlayer, print_center, "%L", iPlayer, g_szMessages[iKey], iLimit);
  60.         SetHookChainReturn(ATYPE_INTEGER, true);
  61.         return HC_SUPERCEDE;
  62.     }
  63.     return HC_CONTINUE;
  64. }
  65.  
  66. public CPlayer_Spawn_Post(iPlayer)
  67. {
  68.     if(!is_user_connected(iPlayer))
  69.     {
  70.         return;
  71.     }
  72.  
  73.     arrayset(g_iLimit[iPlayer], 0, sizeof(g_iLimit[]));
  74. }
  75.  
  76. getKeybyItemID(ItemID:item)
  77. {
  78.     switch(item)
  79.     {
  80.         case ITEM_FLASHBANG:
  81.         {
  82.             return NADE_FLASH;
  83.         }
  84.         case ITEM_HEGRENADE:
  85.         {
  86.             return NADE_HE;
  87.         }
  88.         case ITEM_SMOKEGRENADE:
  89.         {
  90.             return NADE_SMOKE;
  91.         }
  92.     }
  93.     return NADE_NONE;
  94. }

Oldal: 1 / 1 Minden időpont UTC+01:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/