hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.05.04. 02:17

Megválaszolatlan témák | Aktív témák



» » »


Navigáció
Jelenlévő felhasználók

Jelenleg 526 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 526 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  Oldal: 1 / 4
  [ 40 hozzászólás ]  Oldal 1 2 3 4 Következő
  Nyomtatóbarát verzió | Barát értesítése e-mailben Előző téma | Következő téma 
Szerző Üzenet
Silent
 Hozzászólás témája: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 13:42 
Offline
Signore Senior
Avatar

Csatlakozott: 2011.09.09. 17:39
Hozzászólások: 4020
Megköszönt másnak: 12 alkalommal
Megköszönték neki: 139 alkalommal
Ebben a tutoriálban meg fogom mutatni, hogyan készíthetünk egy egyszerű XP-módot.
Figyelem! A tutoriál megértéséhez tisztában kell legyél egy kicsit az amxmodx szkriptinggel.


Először is adjuk hozzá a függvénykönyvtárakat, amik szükségesek.

Kód:

#include <amxmodx> 
#include <amxmisc>
#include <nvault>  //ez kell majd a játékos XP-k mentéséhez
 


Definiáljuk, hogy hány db "class", faj közül lehessen választani. Jelenleg 5-el dolgozunk, de ha te hozzáakarsz még adni mondjuk egy "madár" fajt akkor írd át 6-ra.

Kód:
#define MAXCLASSES 5                


Deklaráljuk a változókat, amik majd a játékosok XP-it, Szintjeit, Faját tárolja. Utána létrehozunk változókat a speciális ölésekhez(pl fejlövés).
És utoljára a g_vault változót, ami az nvault mentéshez kell majd.

Kód:

new PlayerXP[33],PlayerLevel[33],PlayerClass[33]
new XP_Kill,XP_Knife,XP_Hs,SaveXP
new g_vault 


Itt pedig megadjuk a fajok neveit. Én most állatokat fogok írni, de te akár Predátort is írhatsz. Fontos, hogy annyi legyen amennyi a MAXCLASSES. Tehát jelen esetben 5.

Kód:

new const CLASSES[MAXCLASSES][] = {
    "Nincs",
    "Kutya",
    "Macska",
    "Lovacska",
    "Boci"
}
 




Most pedig létrehozzuk a szinteket, és hogy egyes szintekhez mennyi XP szükséges. Jelen esetben 7 db szint lesz.

Kód:

new const LEVELS[7] = {
0,
100,// második szinthez 100 xp kell
200,// harmadikhoz 200xp
400,// negyedikhez 400xp
800,// stb
1600,// stb
3200 // stb
}


Most pedig jöhet a plugin_init.

Kód:

public plugin_init()
{
    register_plugin("Animal-Mod", "1.0", "Te")
 
    register_event("DeathMsg", "eDeath", "a") // Erre szükségünk van, hogy lecsekkoljuk a halálokat.

    SaveXP = register_cvar("SaveXP","1")  //csinálunk egy cvart, ami azt irányítja, hogy lementse e az xp-ket.

    XP_Kill=register_cvar("XP_per_kill", "20")  //  --||--, ami azt irányítja, hogy mennyi XP-t kapjanak ölésenként

    XP_Hs=register_cvar("XP_hs_bonus","20") // --||--, ami azt irányítja, hogy mennyi XP bónuszt kapjanak fejlövésért

    XP_Knife=register_cvar("XP_knife_bonus","20") // --||--, ami azt irányítja, hogy mennyi XP bónuszt kapjanak késelésért

    g_vault = nvault_open("animalmod") // Most pedig létrehozzuk magát az nvault fájlt, amibe menjük az xpket/szinteket. 

    register_clcmd("say /faj", "ChangeClass") // Regisztrálunk egy chat parancsot, a fajváltáshoz.
    register_clcmd("say_team /faj", "ChangeClass") //Regisztráljuk team chatbe is.

    register_clcmd("say /xp", "ShowHud") // Regisztrálunk egy chat parancsot, ami megmutatja hogy mennyi XP-d van.
    register_clcmd("say_team /xp", "ShowHud") //Regisztráljuk team chatbe is.
}



Most pedig létrehozzuk a halál funkciót. Emlékezz, már "lehookoltuk" plugin_initben eDeath néven.

Kód:

public eDeath( ) //funkció neve
{ 

    new attacker = read_data( 1 ) //Deklaráljuk a támadó változót.

    new iVictim = read_data( 2 )  //Deklaráljuk az áldozat változót.

    new headshot = read_data( 3 ) //Deklaráljuk azt a változót, ami azt nézi, hogy fejlövés volt-e.

     if(PlayerClass[attacker] == 0) //Leellenőrizzük, hogy van e kiválasztott faja, ha nincs akkor nemis megyünk vele tovább.
         return PLUGIN_CONTINUE //Kilépünk a funkcióból.

    new clip, ammo, weapon = get_user_weapon(attacker,clip,ammo);  //Lekérjük a támadó fegyverét.

    PlayerXP[attacker] += get_pcvar_num(XP_Kill) //Majd hozzáadunk cvar szerint a támadó xpjéhez.

    
    if(headshot)  //Leellenőrizzük, hogy fejlövés volt-e.
        PlayerXP[attacker] += get_pcvar_num(XP_Hs)  //Ha igen, akkor hozzáadunk még cvar szerint az XP-jéhez.

    if(weapon == CSW_KNIFE) //Leellenőrizzük, hogy késelés volt-e.
        PlayerXP[attacker] += get_pcvar_num(XP_Knife)  //Ha igen, akkor hozzáadunk még cvar szerint az XP-jéhez.

   //Most pedig nézzük meg, hogy elérte-e már a következő szinthez elegendő XP-t.
 
     while(PlayerXP[attacker] >= LEVELS[PlayerLevel[attacker]]) 
    {  
        client_print(attacker, print_chat, "[Animal Mod] Grat! Te egy %i szintu %s vagy!", PlayerLevel[attacker],CLASSES[PlayerClass[attacker]])  //Ha igen, akkor kiírunk neki egy gratuláló üzenetet.
      
        PlayerLevel[attacker] += 1  //Végül hozzáadunk egyet a szintjéhez.
    } 

    ShowHud(attacker) //Majd elindítjuk a ShowHud funkciót, amiről röviden annyit, hogy kiírja neki a szintjét.
 
} 



Jöhet a ShowHud funkció, amiben megmutatjuk neki a szintjét, xp-jét, faját.

Megjegyzés: ^n új sort jelent.

Kód:

public ShowHud(id) 
{ 
    set_hudmessage(255, 0, 0, 0.75, 0.01, 0, 6.0, 15.0) 
    show_hudmessage(id, "Szinted: %i^nXP-d: %i^nFajod: %s",PlayerLevel[id],PlayerXP[id],CLASSES[PlayerClass[id]]) 
}



Jöhet a menü, amiben kiválaszthatja a játékos a faját. Most nem mennék bele a menü részleteibe, erről bővebb infót találsz az eredeti tutorialban.

Kód:

public ChangeClass(id) 
{
    new menu = menu_create("Faj Menu" , "Class_Handle");
    menu_additem(menu ,"Kutya", "1" , 0); 
    menu_additem(menu ,"Macska", "2" , 0); 
    menu_additem(menu ,"Lovacska", "3" , 0); 
    menu_additem(menu ,"Boci", "4" , 0);
    menu_setprop(menu , MPROP_EXIT , MEXIT_ALL);
    menu_display(id , menu , 0); 
    return PLUGIN_CONTINUE; 
} 
 
public Class_Handle(id , menu , item) 
{ 
    if(item == MENU_EXIT) 
    { 
        menu_destroy(menu); 
    } 
    new szCommand[6] , szName[64]; new access , callback; 
    menu_item_getinfo(menu , item , access , szCommand , 5 , szName , 63 , callback); 
    new i = str_to_num(szCommand) 
    if(PlayerClass[id] != i)  //Ha a választott faj nem egyezik a jelenlegi fajával, átváltjuk a faját.
    { 
        PlayerClass[id] = i; client_print(id,print_chat,"A te uj fajod: %s",CLASSES[i]) 
    }
    else //Ha a választott faj egyezik a jelenlegi fajával, kiírjuk, hogy nem lehet, mert már most is az a faja.
    { 
        client_print(id,print_chat,"Eddig is egy %s voltal",CLASSES[i]) 
    } 
    menu_destroy(menu); 
    return PLUGIN_CONTINUE 
} 


Jöhet a client_connect funkció. Bevezetőleg annyit, hogy akkor fut le, amikor a játékos csatlakozik a szerverre.

Kód:

public client_connect(id) 
{
    if(get_pcvar_num(SaveXP) == 1) //Megnézzük, hogy be van-e kapcsolva az XP mentés.
    { 
        //Ha igen akkor betöltjük az XP-jét.
        LoadData(id) 
    } 
}



Jöhet a client_disconnect funkció. Röviden róla annyit, hogy akkor fut le, amikor a játékos lecsatlakozik a szerverről.
Kód:

public client_disconnect(id) 
{ 
     if(get_pcvar_num(SaveXP) == 1) //Most is megnézzük, hogy az XP mentés be van e kapcsolva.
     { 
          //Ha igen akkor elmentjük az XP-jét.
          SaveData(id) 
     } 
}


Most pedig nézzük meg az XP mentést.

Kód:

public SaveData(id) 
{ 
    new name[32] //Létrehozzuk a name változót, mivel név szerint fogjuk lementeni az XP-jét.
    get_user_name(id, name, 31) //Le is kérjük a nevét.
 
    new vaultkey[64],vaultdata[256] //Létrehozzuk a játékos Vault"Kulcs"-át és Vault"Adatát". 
    //Utána vaultkey-be "bemásoljuk" a játékosnevét és egy kis egyéni szócskát.
    format(vaultkey,63,"%sANIMALMOD", name) 
   //Majd a vaultdatába "bemásoljuk" a játékos XP-jét és a szintjét.
    format(vaultdata,255,"%i#%i#",PlayerXP[id],PlayerLevel[id])

    //Most pedig mentsük el az XP-jét és a szintjét.

    nvault_set(g_vault,vaultkey,vaultdata) 
    return PLUGIN_CONTINUE 
}
 


És végül de nem utolsó sorban nézzük meg az XP betöltést.

Kód:

public LoadData(id) 
{ 
    new name[32]
    get_user_name(id, name, 31) 
    new vaultkey[64],vaultdata[256] 
    //Megkeressük, hogy van-e ilyen sor.
    format(vaultkey,63,"%sANIMALMOD", name) 
    format(vaultdata,255,"%i#%i#",PlayerXP[id],PlayerLevel[id]) 
    //Majd betöltjük a játékos XP-jét és Szintjét.
    nvault_get(g_vault,vaultkey,vaultdata,255) 
    replace_all(vaultdata, 255, "#", " ") 
    new playerxp[32], playerlevel[32] 
    parse(vaultdata, playerxp, 31, playerlevel, 31) 
    PlayerXP[id] = str_to_num(playerxp) 
    PlayerLevel[id] = str_to_num(playerlevel) 
    return PLUGIN_CONTINUE 
}


Röviden tömören ennyi. :)

Természetesen fel turbózhatod ilyenekkel, hogy a bocinak több hpja legyen, a macska gyorsabb legyen, a kutya többet sebezzen stb. És persze ezeket szinthez is kötheted.
Ezekhez a
Kód:
PlayerXP[játékos]
és a
Kód:
PlayerLevel[játékos]
tömböket használhatod.

Most pedig a teljes kód, hozzászólások nélkül:

Kód:
  1.  

  2.  

  3. #include <amxmodx> 

  4. #include <amxmisc>

  5. #include <nvault>

  6.  

  7. #define MAXCLASSES 5  

  8.  

  9.  

  10. new PlayerXP[33],PlayerLevel[33],PlayerClass[33]

  11. new XP_Kill,XP_Knife,XP_Hs,SaveXP

  12. new g_vault 

  13.  

  14. new const CLASSES[MAXCLASSES][] = {

  15.     "Nincs",

  16.     "Kutya",

  17.     "Macska",

  18.     "Lovacska",

  19.     "Boci"

  20. }

  21.  

  22.  

  23. new const LEVELS[7] = {

  24. 0,

  25. 100,

  26. 200,

  27. 400,

  28. 800,

  29. 1600,

  30. 3200

  31. } 

  32.  

  33. public plugin_init()

  34. {

  35.     register_plugin("Animal-Mod", "1.0", "Te")

  36.  

  37.     register_event("DeathMsg", "eDeath", "a")

  38.  

  39.     SaveXP = register_cvar("SaveXP","1")

  40.  

  41.     XP_Kill=register_cvar("XP_per_kill", "20")

  42.  

  43.     XP_Hs=register_cvar("XP_hs_bonus","20")

  44.  

  45.     XP_Knife=register_cvar("XP_knife_bonus","20")

  46.  

  47.     g_vault = nvault_open("animalmod")

  48.  

  49.     register_clcmd("say /faj", "ChangeClass")

  50.     register_clcmd("say_team /faj", "ChangeClass")

  51.  

  52.     register_clcmd("say /xp", "ShowHud")

  53.     register_clcmd("say_team /xp", "ShowHud")

  54. } 

  55.  

  56. public eDeath()

  57. { 

  58.  

  59.     new attacker = read_data( 1 )

  60.  

  61.     new iVictim = read_data( 2 ) 

  62.  

  63.     new headshot = read_data( 3 ) 

  64.  

  65.      if(PlayerClass[attacker] == 0)

  66.          return PLUGIN_CONTINUE 

  67.  

  68.     new clip, ammo, weapon = get_user_weapon(attacker,clip,ammo);

  69.  

  70.     PlayerXP[attacker] += get_pcvar_num(XP_Kill) 

  71.  

  72.     

  73.     if(headshot)

  74.         PlayerXP[attacker] += get_pcvar_num(XP_Hs)

  75.  

  76.     if(weapon == CSW_KNIFE)

  77.         PlayerXP[attacker] += get_pcvar_num(XP_Knife)

  78.  

  79.         

  80.      while(PlayerXP[attacker] >= LEVELS[PlayerLevel[attacker]]) 

  81.     {  

  82.         client_print(attacker, print_chat, "[Animal Mod] Grat! Te egy %i szintu %s vagy!", PlayerLevel[attacker],CLASSES[PlayerClass[attacker]])  //Ha igen, akkor kiírunk neki egy gratuláló üzenetet.

  83.       

  84.         PlayerLevel[attacker] += 1 

  85.     } 

  86.  

  87.     ShowHud(attacker)

  88.  

  89. } 

  90.  

  91.  

  92.  

  93. public ShowHud(id) 

  94. { 

  95.     set_hudmessage(255, 0, 0, 0.75, 0.01, 0, 6.0, 15.0) 

  96.     show_hudmessage(id, "Szinted: %i^nXP-d: %i^nFajod: %s",PlayerLevel[id],PlayerXP[id],CLASSES[PlayerClass[id]]) 

  97. }

  98.  

  99.  

  100.  

  101. public ChangeClass(id) 

  102. {

  103.     new menu = menu_create("Faj Menu" , "Class_Handle");

  104.     menu_additem(menu ,"Kutya", "1" , 0); 

  105.     menu_additem(menu ,"Macska", "2" , 0); 

  106.     menu_additem(menu ,"Lovacska", "3" , 0); 

  107.     menu_additem(menu ,"Boci", "4" , 0);

  108.     menu_setprop(menu , MPROP_EXIT , MEXIT_ALL);

  109.     menu_display(id , menu , 0); 

  110.     return PLUGIN_CONTINUE; 

  111. } 

  112.  

  113. public Class_Handle(id , menu , item) 

  114. { 

  115.     if(item == MENU_EXIT) 

  116.     { 

  117.         menu_destroy(menu); 

  118.     } 

  119.     new szCommand[6] , szName[64]; new access , callback; 

  120.     menu_item_getinfo(menu , item , access , szCommand , 5 , szName , 63 , callback); 

  121.     new i = str_to_num(szCommand) 

  122.     if(PlayerClass[id] != i) 

  123.     { 

  124.         PlayerClass[id] = i;  client_print(id,print_chat,"A te uj fajod: %s",CLASSES[i])

  125.     }

  126.     else

  127.     { 

  128.         client_print(id,print_chat,"Eddig is egy %s voltal",CLASSES[i]) 

  129.     } 

  130.     menu_destroy(menu); 

  131.     return PLUGIN_CONTINUE 

  132. }

  133.  

  134.  

  135. public client_connect(id) 

  136. {

  137.     if(get_pcvar_num(SaveXP) == 1)

  138.     { 

  139.         LoadData(id) 

  140.     } 

  141. }

  142.  

  143. public client_disconnect(id) 

  144. { 

  145.      if(get_pcvar_num(SaveXP) == 1)

  146.      {

  147.           SaveData(id) 

  148.      } 

  149. }

  150.  

  151.  

  152. public SaveData(id) 

  153. { 

  154.     new name[32] 

  155.     get_user_name(id, name, 31) 

  156.  

  157.     new vaultkey[64],vaultdata[256] 

  158.     

  159.     format(vaultkey,63,"%sANIMALMOD", name) 

  160.     

  161.     format(vaultdata,255,"%i#%i#",PlayerXP[id],PlayerLevel[id])

  162.  

  163.     

  164.  

  165.     nvault_set(g_vault,vaultkey,vaultdata) 

  166.     return PLUGIN_CONTINUE 

  167. }

  168.  

  169.  

  170. public LoadData(id) 

  171. { 

  172.     new name[32]

  173.     get_user_name(id, name, 31) 

  174.     new vaultkey[64],vaultdata[256] 

  175.     

  176.     format(vaultkey,63,"%sANIMALMOD", name) 

  177.     format(vaultdata,255,"%i#%i#",PlayerXP[id],PlayerLevel[id]) 

  178.     

  179.     nvault_get(g_vault,vaultkey,vaultdata,255) 

  180.     replace_all(vaultdata, 255, "#", " ") 

  181.     

  182.     new playerxp[32], playerlevel[32] 

  183.     parse(vaultdata, playerxp, 31, playerlevel, 31) 

  184.     

  185.     PlayerXP[id] = str_to_num(playerxp) 

  186.     PlayerLevel[id] = str_to_num(playerlevel) 

  187.     

  188.     return PLUGIN_CONTINUE 

  189. }  

  190.  

  191.  


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
tson_
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 14:36 
Offline
Őstag
Avatar

Csatlakozott: 2012.02.14. 15:09
Hozzászólások: 1423
Megköszönték neki: 2 alkalommal
Szkriptingel, nem inkább szkriptinggel ?
szkripting+vel = 2 g
Még a böngésző sem húzza alá 2 G-vel :D
Amúgy nem rossz tutorial csak én nemhiszem, hogy fogom használni a közeljövőben. ;)

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
oroszrulett
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 14:54 
Offline
Veterán
Avatar

Csatlakozott: 2011.06.07. 15:29
Hozzászólások: 1728
Megköszönt másnak: 1 alkalommal
Megköszönték neki: 63 alkalommal
Ezt úgy mondod, mintha neked csinálta volna...

És, ha már a helyesírási hibáknál tartunk:
Idézet:
Még a böngésző sem húzza alá 2 G-vel :D
Amúgy nem rossz tutorial csak én nemhiszem, hogy fogom használni a közeljövőben. ;)

helyett:
Még a böngésző sem húzza alá 2 G-vel. :D
Amúgy nem rossz tutorial, csak én nemhiszem, hogy fogom használni a közeljövőben. ;)


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
HunGamer
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 16:49 
Offline
Félisten

Csatlakozott: 2012.01.07. 21:10
Hozzászólások: 850
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 154 alkalommal
Ez jó :)
Az nvaultos rész pont kellett is.
Csak 2 észrevétel:
Kód:
PlayerClass[id] =  client_print(id,print_chat,"A te uj fajod: %s",CLASSES[i])

Ez mit csinál :? Így is átállítja a faját?
A másik meg: a mentésnél illetve a betöltésnél a faját nem kell elmenteni?

Amúgy meg tényleg nagyon jó, részletes és nagyon hasznos lett. :)

_________________
Megköszönni nem szégyen!
Csak kattints a Kép jelre. --->


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
kiki
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 18:29 
Offline
Developer
Avatar

Csatlakozott: 2011.06.01. 21:11
Hozzászólások: 7962
Megköszönt másnak: 295 alkalommal
Megköszönték neki: 535 alkalommal
Széptutorial, nice!

_________________
http://www.easyrankup.eu


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Silent
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 18:31 
Offline
Signore Senior
Avatar

Csatlakozott: 2011.09.09. 17:39
Hozzászólások: 4020
Megköszönt másnak: 12 alkalommal
Megköszönték neki: 139 alkalommal
HunGamer: igaz, javítva.
kiki: kösz


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
HunGamer
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 18:37 
Offline
Félisten

Csatlakozott: 2012.01.07. 21:10
Hozzászólások: 850
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 154 alkalommal
Oké :)
a vaultkeyt lehet így, hogy mindegyik class külön fejlődjön és ne egybe menjen a szint?
Kód:
format(vaultkey,63,"%s#%i#ANIMALMOD", name, PlayerClass[id])

Nem tudom pontosan hogy kell, de valami hasonlóképpen lenne :)

_________________
Megköszönni nem szégyen!
Csak kattints a Kép jelre. --->


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Silent
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 18:41 
Offline
Signore Senior
Avatar

Csatlakozott: 2011.09.09. 17:39
Hozzászólások: 4020
Megköszönt másnak: 12 alkalommal
Megköszönték neki: 139 alkalommal
Akkor már nem i, hanem s. Mivel sztring :D


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
HunGamer
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.22. 18:48 
Offline
Félisten

Csatlakozott: 2012.01.07. 21:10
Hozzászólások: 850
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 154 alkalommal
Akkor az :D te jobban értesz ehhez, mint én.

De no. a PlayerClass tömb az csak sima változó.
a CLASSES[][] ben vannak a stringek.

_________________
Megköszönni nem szégyen!
Csak kattints a Kép jelre. --->


A hozzászólást 1 alkalommal szerkesztették, utoljára HunGamer 2012.04.23. 14:58-kor.

Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Vath
 Hozzászólás témája: Re: XP-mód tutoriál
HozzászólásElküldve: 2012.04.23. 05:24 
Offline
Nagyúr
Avatar

Csatlakozott: 2011.09.07. 18:41
Hozzászólások: 642
Megköszönt másnak: 15 alkalommal
Megköszönték neki: 6 alkalommal
Kód:
files/1581131/1581131.sma(64) : warning 217: loose indentation
files/1581131/1581131.sma(67) : warning 217: loose indentation
files/1581131/1581131.sma(79) : warning 217: loose indentation
files/1581131/1581131.sma(86) : warning 217: loose indentation
files/1581131/1581131.sma(88) : warning 204: symbol is assigned a value that is never used: "iVictim"
files/1581131/1581131.sma(88) : warning 209: function "eDeath" should return a value


Meg egy egyszerű 6-os szinthez kötött hp növelés hogy nézne ki?

_________________
Kép
Kép
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  Oldal: 1 / 4
  [ 40 hozzászólás ]  Oldal 1 2 3 4 Következő

» » »


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 7 vendég

Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole