hlmod.hu

 
/**
*	Modified by Safety1st
*
*	Home post:
*	  http://c-s.net.ua/forum/index.php?act=f ... pid=639977
*/
 
#include <amxmodx>
#include <fakemeta>
 
/*---------------EDIT ME------------------*/
#define CHECK_CHAT	// comment to disable
/*----------------------------------------*/
 
#pragma ctrlchar	'\'
 
public plugin_init() {
	register_plugin("Fast Fix #", "1.1", "PRoSToTeM@");
 
	register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged_Pre", false);
 
#if defined CHECK_CHAT
	register_clcmd( "say", "CheckChat" );
	register_clcmd( "say_team", "CheckChat" );
#endif
}
 
public ClientUserInfoChanged_Pre(const iClient, const pszInfoBuffer) {
	new szNetName[32];
	pev(iClient, pev_netname, szNetName, charsmax(szNetName));
 
	new szBufferName[32];
	engfunc(EngFunc_InfoKeyValue, pszInfoBuffer, "name", szBufferName, charsmax(szBufferName));
 
	if (szNetName[0] != '\0' && equal(szNetName, szBufferName)) {
		return FMRES_IGNORED;
	}
 
	new bool:fChanged;
 
	for (new i = 0; szBufferName[i] != '\0'; i++) {
		if (szBufferName[i] == '#' || (szBufferName[i] == '+' && !('0' <= szBufferName[i + 1] <= '9'))) {
			szBufferName[i] = ' ';
 
			fChanged = true;
		}
	}
 
	if (fChanged) {
		engfunc(EngFunc_SetClientKeyValue, iClient, pszInfoBuffer, "name", szBufferName);
	}
 
	return FMRES_IGNORED;
}
 
#if defined CHECK_CHAT
public CheckChat(id) {
	static szMsg[191];
	read_args( szMsg, charsmax(szMsg) );
 
	if( contain( szMsg, "#" ) != -1 )
		return PLUGIN_HANDLED
 
	return PLUGIN_CONTINUE
}
#endif