hlmod.hu
https://hlmod.hu/

Zene lejátszás csatlakozáskor
https://hlmod.hu/viewtopic.php?f=29&t=24563		 Oldal: 1 / 1
Szerző:  saxypro [2016.04.07. 21:21 ]
Hozzászólás témája:  Zene lejátszás csatlakozáskor
Sziasztok! Egy olyan plugint keresnék, amely feladata, hogy ha egy adott ID-jű játékos- akit megadtunk -, feljön a szerverre és lejátszik egy egyedi hangot. Minden ID-nél más-más hang, amit te adsz meg.
Szerző:  csongika [2016.04.08. 16:02 ]
Hozzászólás témája:  Re: Zene lejátszás csatlakozáskor
Kód: [Egész kijelölése] [Mutatás/Eltüntetés]
  1. #include <amxmodx>
  2.  
  3. // change this number to the amount of sounds u have
  4. #define Maxsounds 1
  5.  
  6. // add here your sounds, sounds must be somewhere in <ModDir>/sounds
  7. // format must be like: {"misc/sound1","ambience/sound2"}
  8. new soundlist[Maxsounds][] = {"misc/welcome-by-Sp0oN"}
  9.  
  10. new plugin_author[] = "S.p.0_o.N"
  11. new plugin_version[] = "1.2.3"
  12.  
  13. public plugin_init(){
  14.     register_plugin("Join_Music",plugin_version,plugin_author)
  15.     register_cvar("join_music_version",plugin_version,FCVAR_SERVER)
  16. }
  17.  
  18. public plugin_precache(){
  19.     for ( new a = 0; a < Maxsounds; a++ ){
  20.         new temp[128]
  21.         format(temp,127,"sound/%s.wav", soundlist[a])
  22.         if ( file_exists(temp) ){
  23.             new soundfile[128]
  24.             format(soundfile,127,"%s.wav", soundlist[a])
  25.             precache_sound( soundfile )
  26.         }
  27.     }
  28. }
  29.  
  30. public client_putinserver(id){
  31.     set_task(1.0,"consound",100+id)
  32. }
  33.  
  34. public consound(timerid_id){
  35.     new id = timerid_id - 100
  36.     new Usertime
  37.     Usertime = get_user_time(id, 0)
  38.     if ( Usertime <= 0 ){
  39.         set_task(1.0,"consound",timerid_id)
  40.     }else{
  41.         new i = random(Maxsounds)
  42.         client_cmd(id,"spk ^"%s^"",soundlist[i])
  43.     }
  44.    
  45.     return PLUGIN_CONTINUE
  46. }
GeSHi © Codebox Plus
Szerző:  kengurumancs [2016.04.08. 16:24 ]
Hozzászólás témája:  Re: Zene lejátszás csatlakozáskor
Off Topic
Látom előszeretettel szeretsz kommentálni, de a akkor legalább a kérésre válaszolj.
Szerző:  mforce [2016.04.16. 15:38 ]
Hozzászólás témája:  Re: Zene lejátszás csatlakozáskor
configs/unique_connect_sounds.ini

Kód:
"STEAM_0:0:12345678" "hangok/valami.mp3"
"STEAM_0:0:87654321" "hangok/izehoze.mp3"


támogat .wav és .mp3 fájlokat is.

Plugin(frissítve):
Kód: [Egész kijelölése] [Mutatás/Eltüntetés]
  1. #include <amxmodx>
  2.  
  3. new const PLUGIN[] = "Unique Connect Sounds"
  4. new const VERSION[] = "1.0"
  5. new const AUTHOR[] = "mforce"
  6.  
  7. new Trie:g_SteamID;
  8.  
  9. public plugin_init() {
  10.     register_plugin(PLUGIN, VERSION, AUTHOR);
  11. }
  12.  
  13. public plugin_precache() {
  14.     g_SteamID = TrieCreate();
  15.  
  16.     new sBuffer[256], sFile[64], sData[2][32], pFile;
  17.  
  18.     get_localinfo("amxx_configsdir", sFile, charsmax(sFile));
  19.     format(sFile, charsmax(sFile), "%s/unique_connect_sounds.ini", sFile);
  20.  
  21.     pFile = fopen(sFile, "rt");
  22.  
  23.     if(pFile) {    
  24.         while(!feof(pFile)) {
  25.             fgets(pFile, sBuffer, charsmax(sBuffer));
  26.             trim(sBuffer);
  27.             if(sBuffer[0] == ';') continue;
  28.  
  29.             parse(sBuffer, sData[0], charsmax(sData[]), sData[1], charsmax(sData[]));
  30.  
  31.             if(containi(sData[1], ".mp3") != -1 || containi(sData[1], ".wav") != -1) {
  32.                 precache_sound(sData[1])
  33.                 TrieSetString(g_SteamID, sData[0], sData[1])
  34.             }
  35.         }
  36.         fclose(pFile);
  37.     }
  38.     else fprintf(pFile, ";^"STEAM_0:0:12345678^" ^"connectsounds/anybody.mp3^"^n");
  39. }
  40.  
  41.  
  42. public client_putinserver(id) {
  43.     set_task(5.0, "makesound", id);
  44. }
  45.  
  46. public makesound(id) {
  47.     if(is_user_bot(id)) return;
  48.  
  49.     new steamid[32], connect_sound[64];
  50.     get_user_authid(id, steamid, charsmax(steamid));
  51.    
  52.     if(TrieKeyExists(g_SteamID, steamid)) {
  53.         TrieGetString(g_SteamID, steamid, connect_sound, charsmax(connect_sound));
  54.         playsound(connect_sound);
  55.     }
  56. }
  57.  
  58. public client_disconnect(id) {
  59.     remove_task(id);
  60. }
  61.  
  62. public plugin_end() {
  63.     TrieDestroy(g_SteamID);
  64. }
  65.  
  66. stock playsound(const connect_sound[]) {   
  67.     if(containi(connect_sound, ".mp3") != -1)
  68.         client_cmd(0, "mp3 play ^"sound/%s^"", connect_sound);
  69.     else
  70.         client_cmd(0, "spk ^"%s^"", connect_sound);
  71. }
GeSHi © Codebox Plus
Szerző:  saxypro [2016.04.18. 17:03 ]
Hozzászólás témája:  Re: Zene lejátszás csatlakozáskor
Köszönöm szépen!
Oldal: 1 / 1 Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/