hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2025.10.31. 17:39

Megválaszolatlan témák | Aktív témák



» » » »


Navigáció
Jelenlévő felhasználók

Jelenleg 245 felhasználó van jelen :: 2 regisztrált, 0 rejtett és 243 vendég

A legtöbb felhasználó (2883 fő) 2025.07.30. 16:00-kor tartózkodott itt.

Regisztrált felhasználók: Bing [Bot], Google [Bot]az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása Hozzászólás a témához  Oldal: 1 / 1
  [2 hozzászólás ] 
 Nyomtatóbarát verzió |Barát értesítése e-mailben Előző téma | Következő téma 
Szerző Üzenet
Zoli06
 Hozzászólás témája: FPS kijelző
HozzászólásElküldve:2021.04.29. 20:41 
Offline
Lelkes

Csatlakozott:2020.08.17. 15:48
Hozzászólások:20
Sziasztok!!!
Régebben láttam fent egy olyan plugint, hogy amikor beirjuk a chatbe /fps akkor a chatben kimutatja, hogy Pistának van 100fps-e.
Valamikor használtam is ezt a plugint, de már nem emlékszek a nevére :D
A segítségeket megköszönöm! :)


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Csabika20034
 Hozzászólás témája: Re: FPS kijelző
HozzászólásElküldve:2021.04.29. 20:58 
Offline
Jómunkásember
Avatar

Csatlakozott:2019.11.03. 22:00
Hozzászólások:382
Megköszönt másnak: 37 alkalommal
Megköszönték neki: 28 alkalommal
Zoli06 írta:
Sziasztok!!!
Régebben láttam fent egy olyan plugint, hogy amikor beirjuk a chatbe /fps akkor a chatben kimutatja, hogy Pistának van 100fps-e.
Valamikor használtam is ezt a plugint, de már nem emlékszek a nevére :D
A segítségeket megköszönöm! :)

Szia ez talán jó neked.

Kód: [Egész kijelölése] [Mutatás/Eltüntetés]
  1. /*
  2. *
  3. * FPS:
  4. *
  5. *
  6. * CVars:
  7. *         cfps             1/0 // Enable/Disable FPS.                Default: 1/on.
  8. *         cfpsall             1/0 // Print FPS MSG to all players?    Default: 1/on.
  9. *         cfpsvisual         1/0 // Show/Hide /fps chat message?    Default: 1/on.
  10. *
  11. * Usage:
  12. *         Type " /fps <nick/#userid> " in say.
  13. *         Type " /cfps " in say/say_team for about plugin.
  14. *
  15. * Notes:
  16. *         To change delay between user /fps command, edit DELAY_COMMAND and recompile.
  17. *        This is engine FPS.
  18. *         Original FPS Code by newbie.
  19. */
  20.  
  21. #include <amxmodx>
  22. #include <amxmisc>
  23. #include <fakemeta>
  24.  
  25. #define PLUGIN_NAME        "FPS.Meter"
  26. #define PLUGIN_VERSION        "1.0"
  27. #define PLUGIN_AUTHOR        "Raggy"
  28.  
  29. #pragma semicolon        1
  30.  
  31. #define DELAY_COUNT        1.0    //Delay between frame counts, adjust this according to server ticrate. MUST BE FLOAT
  32.  
  33. #define DELAY_COMMAND        5.0    //Delay between user /fps command. MUST BE FLOAT
  34. #define COLOR            0x03    //0x01 normal, 0x04 green, 0x03 other. MUST BE CHAR
  35.  
  36. #define MAX_PLAYERS        32 + 1
  37.  
  38. new g_iUserFPS[MAX_PLAYERS];
  39.  
  40. new g_irFPS;
  41. new g_irFPSAll;
  42. new g_irFPSVisual;
  43.  
  44. public plugin_init()
  45. {
  46.     register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
  47.     register_cvar(PLUGIN_NAME, PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY);
  48.    
  49.     g_irFPS        = register_cvar("cfps",        "1");
  50.     g_irFPSAll    = register_cvar("cfpsall",    "1");
  51.     g_irFPSVisual    = register_cvar("cfpsvisual",    "1");
  52.    
  53.     register_forward(FM_PlayerPreThink, "fwdPlayerPreThink");
  54.    
  55.     register_clcmd("say",            "sayHandle");
  56.     register_clcmd("say /fps",        "cmdAboutrFPS");
  57.     register_clcmd("say_team /fps",    "cmdAboutrFPS");
  58. }
  59.  
  60. public fwdPlayerPreThink(id)
  61. {
  62.     if ( !get_pcvar_num(g_irFPS) )
  63.         return FMRES_IGNORED;
  64.    
  65.     static Float:fGameTime, Float:fCountNext[MAX_PLAYERS], iCountFrames[MAX_PLAYERS];
  66.    
  67.     if ( fCountNext[id] >= (fGameTime = get_gametime()) )
  68.     {
  69.         iCountFrames[id]++;
  70.        
  71.         return FMRES_IGNORED;
  72.     }
  73.    
  74.     g_iUserFPS[id]        = iCountFrames[id];
  75.     iCountFrames[id]    = 0;
  76.    
  77.     fCountNext[id]        = fGameTime + DELAY_COUNT;
  78.    
  79.     return FMRES_IGNORED;
  80. }
  81.  
  82. public sayHandle(id)
  83. {
  84.     if ( !get_pcvar_num(g_irFPS) )
  85.         return PLUGIN_CONTINUE;
  86.    
  87.     new szArgs[64];
  88.     read_args(szArgs, charsmax(szArgs));
  89.     remove_quotes(szArgs);
  90.     trim(szArgs);
  91.    
  92.     if ( !szArgs[0] )
  93.         return PLUGIN_HANDLED;
  94.    
  95.     if ( szArgs[0] != '/' )
  96.         return PLUGIN_CONTINUE;
  97.    
  98.    
  99.     //Command
  100.     new szTarget[32];
  101.    
  102.     parse(szArgs,\
  103.     szArgs, charsmax(szArgs),\
  104.     szTarget, charsmax(szTarget));
  105.    
  106.     if ( !equali(szArgs, "/fps", 4) )
  107.         return PLUGIN_CONTINUE;
  108.     //Command
  109.    
  110.    
  111.     //Delay
  112.     new Float:fCommandDelay = DELAY_COMMAND;
  113.    
  114.     static Float:fCommandUsed[MAX_PLAYERS];
  115.    
  116.     if ( fCommandUsed[id] > get_gametime() )
  117.     {
  118.         printMessage(id, id, "^x01Kérlek várj^x04 %.0f^x03 másodpercet^x01 a parancsok között!", fCommandDelay);
  119.         return PLUGIN_HANDLED;
  120.     }
  121.     //Delay
  122.    
  123.    
  124.     //Display
  125.     trim(szTarget);
  126.    
  127.     if ( !szTarget[0] )
  128.         fCommandUsed[id] = displayFPS(id, id, fCommandDelay);
  129.     else {
  130.         new targetId = cmd_target(id, szTarget, 2);
  131.        
  132.         if ( targetId )
  133.             fCommandUsed[id] = displayFPS(id, targetId, fCommandDelay);
  134.         else {
  135.             printMessage(id, id, "Nem található vagy túl sok játékos található ezzel a névvel: ^x04 %s", szTarget);
  136.             return PLUGIN_HANDLED;
  137.         }
  138.     }
  139.     //Display
  140.    
  141.    
  142.     return get_pcvar_num(g_irFPSVisual) ? PLUGIN_CONTINUE : PLUGIN_HANDLED;
  143. }
  144.  
  145. Float:displayFPS(id, targetId, Float:fCommandDelay)  
  146. {
  147.     new szName[32];
  148.     get_user_name(targetId, szName, charsmax(szName));
  149.    
  150.     new szMsg[192];
  151.     formatex(szMsg, charsmax(szMsg), "^x04%s^x01-nak^x04 %d^x03 FPS^x01-e van.", szName, g_iUserFPS[targetId]);
  152.    
  153.     printMessage(id, get_pcvar_num(g_irFPSAll) ? 0 : id, szMsg);
  154.    
  155.     return get_gametime() + fCommandDelay;
  156. }
  157.  
  158. printMessage(id, targetId, const sMsg[], any:...)
  159. {
  160.     new szMessage[192];
  161.    
  162.     vformat(szMessage, charsmax(szMessage), sMsg, 4);
  163.     format(szMessage, charsmax(szMessage), "%c[FPS] %s", COLOR, szMessage);
  164.    
  165.     static iSayText;
  166.    
  167.     if ( !iSayText )
  168.         iSayText = get_user_msgid("SayText");
  169.    
  170.     message_begin(targetId ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, iSayText, {0, 0, 0}, targetId);
  171.     write_byte(id);
  172.     write_string(szMessage);
  173.     message_end();
  174. }
GeSHi © Codebox Plus

_________________
BiG TeamSzerverek aktivitásavéget ért.
Rendszereinkérdekel? Írj PM.


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Hozzászólások megjelenítése: Rendezés 
Új téma nyitása Hozzászólás a témához  Oldal: 1 / 1
  [2 hozzászólás ] 

» » » »


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 2 vendég

Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole