#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
 
#define PLUGIN "Kes menu"
#define VERSION "1.0"
#define AUTHOR "HunGamer"
 
#define MAX_KES 4//EZT ANNYIRA ALLITSD AMENNYI KESED VAN
 
new OnOff
 
new valasztott[33]
 
new const knife_name[MAX_KES+1][] =
{
	"",//IDE IRD A KESEK NEVEIT
	"Elso kes",
	"Masodik kes",
	"Harmadik kes",
	"Negyedik kes"
}
new const knife_p_model[MAX_KES+1][] =
{
	"",//IDE IRD A KESEK P_ MODELJEIT HA NINCS IRD ODA HOGY NINCS
	"models/p_elsokes.mdl",
	"models/p_masodik.mdl",
	"nincs",
	"models/p_negyedik_kes.mdl"
}
new const knife_v_model[MAX_KES+1][] =
{
	"",//IDE IRD A KESEK V_ MODELJEIT
	"models/v_elso.mdl",
	"models/v_masodik.mdl",
	"models/v_harmadik.mdl",
	"models/v_negyedik.mdl"
}
 
public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_event("CurWeapon", "Event_Change_Weapon", "be", "1=1")
	register_clcmd("say /kesmodel", "kesmodel")
	register_clcmd("say /kes", "kesmodel")
	register_clcmd("say /knife", "kesmodel")
	OnOff = register_cvar("kesmenu_on", "1")//PLUGIN BE/KI KAPCSOLASA
}
public plugin_precache() 
{
	for(new i=1; i<=MAX_KES; i++)
	{
		precache_model(knife_v_model[i])
		if(!(equali(knife_p_model[i], "nincs")))
		{
			precache_model(knife_p_model[i])
		}
	}
	return PLUGIN_CONTINUE
}
public kesmodel(id)
{
	if(get_pcvar_num(OnOff))
	{
		if(is_user_alive(id))
		{
			new szTempid[10]
			new Menu = menu_create("Kes model menu", "kesmodelh")
 
			for(new i=1; i<=MAX_KES; i++)
			{
				num_to_str(i, szTempid, 9)
				menu_additem(Menu, knife_name[i], szTempid)
			}
			menu_setprop(Menu, MPROP_EXIT, MEXIT_ALL)
			menu_display(id, Menu)
		}
		else
		{
			client_print(id, print_chat, "Halott nem hasznalhatja")
		}
	}
	else
	{
		client_print(id, print_chat, "A valasztas jelenleg ki van kapcsolva")
	}
	return PLUGIN_HANDLED
}
public client_connect(id)
{
	valasztott[id] = 0
}
public client_disconnect(id)
{
	valasztott[id] = 0
}
public kesmodelh(id, menu, item)
{
	if( item == MENU_EXIT )
	{
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	new data[6], iName[64]
	new access, callback
	menu_item_getinfo(menu, item, access, data,5, iName, 63, callback)
 
	new key = str_to_num(data)
 
	valasztott[id] = key
	set_pev(id, pev_viewmodel2, knife_v_model[key])
	if(!(equali(knife_v_model[key], "nincs")))
	{
		set_pev(id, pev_weaponmodel2, knife_p_model[key])
	}
 
	menu_destroy(menu)
	return PLUGIN_HANDLED
}
public Event_Change_Weapon(id)
{
	new weaponID = read_data(2) 
 
	if(weaponID == CSW_KNIFE && get_pcvar_num(OnOff) && valasztott[id])
	{
		set_pev(id, pev_viewmodel2, knife_v_model[valasztott[id]])
		if(!(equali(knife_p_model[valasztott[id]], "nincs")))
		{
			set_pev(id, pev_weaponmodel2, knife_p_model[valasztott[id]])
		}
	}
	return PLUGIN_CONTINUE 
}