hlmod.hu

/* AMX Mod X Plugin
* 
* (c) Copyright 2008, ConnorMcLeod 
* This file is provided as is (no warranties). 
* 
*/ 
 
#include <amxmodx>
 
new g_szVictimSound[100], g_szKillerSound[100], g_szPlayersSound[100]
new g_iMaxPlayers
 
public plugin_precache()
{
	new szFile[64]
	get_localinfo("amxx_configsdir", szFile, 63)
	format(szFile, 63, "%s/headshots.ini", szFile)
 
	new File = fopen(szFile, "rt")
	if(!File)
	{
		pause("ad")
		return
	}
 
	new Text[128], Witch[8], Sound[100]
	while(!feof(File))
	{
		fgets(File, Text, 127)
		trim( Text )
		if(!Text[0] || Text[0] == ';' || (Text[0] == '/' && Text[1] == '/'))
			continue
 
		parse(Text, Witch, 7, Sound, 99)
		if(!g_szVictimSound[0] && equal(Witch, "victim"))
		{
			copy(g_szVictimSound, 99, Sound)
			precache_sound(g_szVictimSound)
		}
		else if(!g_szKillerSound[0] && equal(Witch, "killer"))
		{
			copy(g_szKillerSound, 99, Sound)
			precache_sound(g_szKillerSound)
		}
		else if(!g_szPlayersSound[0] && equal(Witch, "players"))
		{
			copy(g_szPlayersSound, 99, Sound)
			precache_sound(g_szPlayersSound)
		}
	}
	fclose(File)
}
 
public plugin_init()
{
	register_plugin("HeadShot Sounds", "0.2", "ConnorMcLeod")
	register_event("DeathMsg", "eDeathMsg_HeadShot", "a", "1>0", "3=1")
}
 
public plugin_cfg()
{
	g_iMaxPlayers = get_maxplayers()
}
 
public eDeathMsg_HeadShot()
{
	new iKiller = read_data(1)
 
	if(iKiller > g_iMaxPlayers)
		return
 
	new iVictim = read_data(2)
	if(iKiller == iVictim)
		return
 
	if(g_szKillerSound[0])
		emit_sound(iKiller, CHAN_VOICE, g_szKillerSound, VOL_NORM, ATTN_STATIC, 0, PITCH_NORM)
 
	if(g_szVictimSound[0])
		client_cmd(iVictim, "speak %s", g_szVictimSound)
 
	if(g_szPlayersSound[0])
	{
		for(new id = 1; id <= g_iMaxPlayers; id++)
		{
			if(!is_user_connected(id))
				continue
			if((g_szKillerSound[0] && id == iKiller) || (g_szVictimSound[0] && id == iVictim))
				continue
			client_cmd(id, "speak %s", g_szPlayersSound)
		}
	}
}

format(szFile, 63, "%s/headshots.ini", szFile)