hlmod.hu

/* Plugin generated by AMXX-Studio */
 
#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <engine>
#include <fun>
#include <hamsandwich>
#include <zombieplague>
 
////////// PLUGIN SETTINGS //////////
#define MODE 2
#define CHAT_PREFIX "[VIP]"
 
// (Only if MODE 1 is turrned OFF. Otherwise set flags in vips.ini.) //
#define VIPACCES ADMIN_LEVEL_H
#define MJACCES ADMIN_LEVEL_H
////////// SETTINGS END //////////
 
// Flags
#define FLAG_A (1<<0)
#define FLAG_B (1<<1)
#define FLAG_C (1<<2)
#define FLAG_D (1<<3)
#define FLAG_E (1<<4)
#define FLAG_K (1<<10)
 
#define VERSION "1.7.2"
 
#if cellbits == 32
const OFFSET_CLIPAMMO = 51
#else
const OFFSET_CLIPAMMO = 65
#endif
const OFFSET_LINUX_WEAPONS = 4
 
const DMG_HEGRENADE = (1<<24)
 
#define set_flood(%1,%2)    (%1 |= (1<<(%2&31)))
#define clear_flood(%1,%2)    (%1 &= ~(1<<(%2&31)))
#define get_flood(%1,%2)    (%1 & (1<<(%2&31)))
 
#if MODE & (1<<0) || MODE & (1<<1)
new amx_password_field_string[30]
#endif
#if MODE & (1<<0)
new g_user_privileges[33]
enum _:database_items
{
	auth[50],
	password[50],
	accessflags,
	flags
}
new vips_database[database_items]
new Array:database_holder
new g_hour_flags
new g_hour
#endif
#if MODE & (1<<1)
const ZV_PLUGIN_HANDLED = 97
enum _:items
{
	i_name[31],
	i_description[31],
	i_cost,
	i_team
}
new g_register_in_zp_extra
new g_zp_extra_item_number
new g_nonvip_tease
new g_menu_close
new extra_items[items]
new Array:items_database
new g_registered_items_count
new g_forward_return
new g_extra_item_selected
new g_team[33]
#endif
#if MODE == 3
new g_vip_buy_time
new g_vip_cost_ammo
new g_vip_buy_flags
#endif
new const MAXCLIP[] = { -1, 13, -1, 10, 1, 7, -1, 30, 30, 1, 30, 20, 25, 30, 35, 25, 12, 20, 10, 30, 100, 8, 30, 30, 20, 2, 7, 30, 30, -1, 50 }
static const CONTACT[] = ""
new g_jumps, g_allow_jump, g_armor, g_killammo, g_infectammo, g_infecthealth, g_nemhealth, g_show_vips,
g_unlimited_clip, g_fall_damage, g_damage_reward, g_damage_increase, g_happy_hour, g_happy_hour_frag, g_happy_hour_ammo
new happy_hour_on
new g_bit
new chache_g_jumps
new maxplayers, g_msgSayText
new jumpnum[33]
new bool:dojump[33]
new Float:g_damage[33]
 
public plugin_init() {
 
	register_plugin("ZM VIP", VERSION, "aaarnas")
	RegisterHam(Ham_Spawn, "player", "FwdHamPlayerSpawnPost", 1)
	RegisterHam(Ham_Killed, "player", "fw_PlayerKilled_Post", 1)
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	register_event("ResetHUD", "HUDReset", "be")
	register_event("HLTV", "chache_cvars", "a", "1=0", "2=0")
 
	maxplayers = get_maxplayers()
	g_msgSayText = get_user_msgid("SayText")
 
	register_message(get_user_msgid("CurWeapon"), "message_cur_weapon")
 
	g_jumps = register_cvar("zp_vip_jumps", "1")
	g_allow_jump = register_cvar("zp_vip_allow_jump", "ab")
	g_armor = register_cvar("zp_vip_armor", "65")
	g_killammo = register_cvar("zp_vip_killammo", "2")
	g_infectammo = register_cvar("zp_vip_infectammo", "2")
	g_infecthealth = register_cvar("zp_vip_infecthealth", "300")
	g_nemhealth = register_cvar("zp_vip_nemextra", "1")
	g_show_vips = register_cvar("zp_vip_show", "1")
	g_unlimited_clip = register_cvar("zp_vip_unlimited_ammo", "0")
	g_fall_damage = register_cvar("zp_vip_no_fall_damage", "1")
	g_damage_reward = register_cvar("zp_vip_damage_reward", "500")
	g_damage_increase = register_cvar("zp_vip_damage_increase", "1.5")
	g_happy_hour = register_cvar("zp_vip_happy_hour", "off")
	g_happy_hour_frag = register_cvar("zp_vip_happy_hour_frag", "1")
	g_happy_hour_ammo = register_cvar("zp_vip_happy_hour_ammo", "1")
	register_cvar("amx_contactinfo", CONTACT, FCVAR_SERVER)
	register_cvar("zp_vip_version", VERSION, FCVAR_SERVER|FCVAR_SPONLY)
	set_cvar_string("zp_vip_version", VERSION)
 
#if MODE & (1<<0) || MODE & (1<<1)
	get_cvar_string("amx_password_field", amx_password_field_string, charsmax(amx_password_field_string))
	register_dictionary("zm_vip.txt")
#endif
#if MODE & (1<<0) && MODE & (1<<1)
	g_vip_cost_ammo = register_cvar("zp_vip_cost_ammo", "0")
	g_vip_buy_time = register_cvar("zp_vip_buy_time", "7")
	g_vip_buy_flags = register_cvar("zp_vip_buy_flags", "abcd")
	set_task(5.0,"check_date",0)
#endif
#if MODE & (1<<0)
	register_concmd("amx_reloadvips", "reload_vips", ADMIN_CFG)
	g_hour = register_cvar("zp_vip_hour", "off")
	g_hour_flags = register_cvar("zp_vip_hour_flags", "abe")
	reload_vips()
#endif
#if MODE & (1<<1)
	register_clcmd("say /vm", "menu_open")
	g_nonvip_tease = register_cvar("zp_vip_nonvip_tease", "1")
	g_register_in_zp_extra = register_cvar("zp_vip_register_in_zp_extra", "1")
	g_menu_close = register_cvar("zp_vip_menu_close", "1")
 
	new temp[31]
	formatex(temp, 30, "%L", LANG_SERVER, "VIP_EXTRA_NAME")
	if(get_pcvar_num(g_register_in_zp_extra)) g_zp_extra_item_number = zp_register_extra_item(temp, 0, 0)
	g_extra_item_selected = CreateMultiForward("zv_extra_item_selected", ET_CONTINUE, FP_CELL, FP_CELL)
#endif
	register_clcmd("say /vips", "print_adminlist")
	register_clcmd("say /vip", "ShowMotd")
}
public plugin_cfg()
{
	new directory[31]
	get_configsdir(directory, 30)
	server_cmd("exec %s/zm_vip.cfg", directory)
}
 
public chache_cvars() {
 
	static string[5]
	get_pcvar_string(g_allow_jump, string, charsmax(string))
	g_bit = read_flags(string)
	chache_g_jumps = get_pcvar_num(g_jumps)
 
	static hours[6], hour1s[3], hour2s[3], hour1, hour2, h, m, s
	get_pcvar_string(g_happy_hour, hours, charsmax(hours))
 
	if(equal(hours, "off")) {happy_hour_on = false; return; }
 
	strtok(hours, hour1s, charsmax(hour1s), hour2s, charsmax(hour2s), '-')
	hour1 = str_to_num(hour1s)
	hour2 = str_to_num(hour2s)
 
	time(h, m, s)
	if(hour1 <= h <= hour2) happy_hour_on = true
	else happy_hour_on = false
}
#if MODE & (1<<1) || MODE & (1<<0)
public plugin_natives() {
#if MODE & (1<<1)
	register_native("zv_register_extra_item", "native_zv_register_extra_item", 1)
#endif
#if MODE & (1<<0)
	register_native("zv_get_user_flags", "native_zv_get_user_flags", 1)
#endif	
}
#endif
public FwdHamPlayerSpawnPost(id) {
 
	if(!is_user_alive(id)) return HAM_IGNORED;
#if MODE & (1<<0)
	if(!(g_user_privileges[id] & FLAG_A))
#else
	if(!(get_user_flags(id) & VIPACCES))
#endif
		return PLUGIN_HANDLED;
 
	if(pev(id, pev_armorvalue) < get_pcvar_num(g_armor))
	set_pev(id, pev_armorvalue, float(get_pcvar_num(g_armor)))
	return HAM_IGNORED;
}
 
public fw_PlayerKilled_Post(victim, attacker) {
#if MODE & (1<<0)
	if(1 <= attacker <= maxplayers && g_user_privileges[attacker] & FLAG_A) {
#else
	if(1 <= attacker <= maxplayers && get_user_flags(attacker) & VIPACCES) {
#endif	
		if(is_user_alive(attacker) && zp_get_user_zombie(attacker) && !(zp_get_user_nemesis(attacker) && get_pcvar_num(g_nemhealth))) set_user_health(attacker, (get_user_health(attacker) + get_pcvar_num(g_infecthealth)))
		zp_set_user_ammo_packs(attacker, zp_get_user_ammo_packs(attacker) + get_pcvar_num(g_killammo))
 
		if(happy_hour_on) {
 
			static frag, ammo
			frag = get_pcvar_num(g_happy_hour_frag)
			ammo = get_pcvar_num(g_happy_hour_ammo)
 
			if(frag) set_user_frags(attacker, get_user_frags(attacker)+frag)
			if(ammo) zp_set_user_ammo_packs(attacker, zp_get_user_ammo_packs(attacker)+ammo)
		}
 
	}
}
 
public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type) {
 
	if(victim == attacker)
		return HAM_IGNORED
 
	if(damage_type & DMG_HEGRENADE)
		return HAM_IGNORED
 
#if MODE & (1<<0)
	if(g_user_privileges[victim] & FLAG_A) {
#else
	if(get_user_flags(victim) & VIPACCES) {
#endif
		if(damage_type & DMG_FALL && get_pcvar_num(g_fall_damage))
			return HAM_SUPERCEDE;
	}
 
	if(!is_user_connected(attacker))
		return HAM_IGNORED
 
	if(zp_get_user_zombie(attacker) || zp_get_user_survivor(attacker))
		return HAM_IGNORED
 
#if MODE & (1<<0)
	if(g_user_privileges[attacker] & FLAG_D) {
#else
	if(get_user_flags(attacker) & VIPACCES) {
#endif
		damage *= get_pcvar_float(g_damage_increase)
		SetHamParamFloat(4, damage)
	}
 
#if MODE & (1<<0)
	if(g_user_privileges[attacker] & FLAG_D) {
#else
	if(get_user_flags(attacker) & VIPACCES) {
#endif
		if(get_pcvar_num(g_damage_reward) > 0) {
			g_damage[attacker]+=damage
			if(g_damage[attacker] > get_pcvar_float(g_damage_reward)) {
				zp_set_user_ammo_packs(attacker, zp_get_user_ammo_packs(attacker)+1)
				g_damage[attacker] -= get_pcvar_float(g_damage_reward)
			}
		}	
	}
 
	return HAM_IGNORED
}
 
public zp_user_infected_post(id, infector, nemesis) {
 
	setVip()
	if(!(1<=infector<=maxplayers)) return;
 
#if MODE & (1<<0)
	if(g_user_privileges[infector] & FLAG_A) {
#else
	if(get_user_flags(infector) & VIPACCES) {
#endif
		if(is_user_alive(infector)) set_user_health(infector, (get_user_health(infector) + get_pcvar_num(g_infecthealth)))
		zp_set_user_ammo_packs(infector, zp_get_user_ammo_packs(infector) + get_pcvar_num(g_infectammo))
 
		if(happy_hour_on) {
 
			static frag, ammo
			frag = get_pcvar_num(g_happy_hour_frag)
			ammo = get_pcvar_num(g_happy_hour_ammo)
 
			if(frag) set_user_frags(infector, get_user_frags(infector)+frag)
			if(ammo) zp_set_user_ammo_packs(infector, zp_get_user_ammo_packs(infector)+ammo)
		}
	}	
}
 
public client_connect(id) {
 
	jumpnum[id] = 0
	g_damage[id] = 0.0
	dojump[id] = false
#if MODE & (1<<0)
	set_flags(id)
	if(get_pcvar_num(g_show_vips) == 1 && g_user_privileges[id] & FLAG_A) {
#else
	if(get_pcvar_num(g_show_vips) == 1 && get_user_flags(id) & VIPACCES) {
#endif
		new name[100]
		get_user_name(id, name, 100)
		client_printcolor(0, "/g%L", LANG_PLAYER, "VIP_CONNECTED", name)
	}
#if MODE & (1<<0)
	else {
		static hours[6], hour1s[3], hour2s[3], hour1, hour2, h, m, s
		get_pcvar_string(g_hour, hours, charsmax(hours))
 
		if(equal(hours, "off")) return;
 
		strtok(hours, hour1s, charsmax(hour1s), hour2s, charsmax(hour2s), '-')
		hour1 = str_to_num(hour1s)
		hour2 = str_to_num(hour2s)
 
		time(h, m, s)
		if(hour1 <= h <= hour2) {
 
			new fflags[10]
			get_pcvar_string(g_hour_flags, fflags, charsmax(fflags))
			g_user_privileges[id] = read_flags(fflags)
		}
	}
#endif
}
#if MODE & (1<<1)
public zp_extra_item_selected(id, item_id)
	if(item_id == g_zp_extra_item_number)
		menu_open(id)
 
public menu_open(id) {
#if MODE & (1<<0)
	if(g_user_privileges[id] & FLAG_E)
		vip_menu(id)
#else
	if(get_user_flags(id) & VIPACCES)
		vip_menu(id)
#endif
#if MODE & (1<<0)
	else if(get_pcvar_num(g_vip_cost_ammo) != 0)
		get_pcvar_num(g_nonvip_tease) ? vip_menu(id) : buy_meniu(id)
#endif
	else client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "NOT_A_VIP")
	return ZP_PLUGIN_HANDLED
}
 
public vip_menu(id)
{
	if(g_registered_items_count == 0) {
		client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "OFF")
		return;
	}
	new holder[150], menu
	formatex(holder, charsmax(holder), "\r%L", id, "MENU_TOP")
	menu = menu_create(holder, "vip_menu_handler")
	new i, team_check, num[3], ammo_packs, check
	check = 0
	ammo_packs = zp_get_user_ammo_packs(id)
 
	switch(zp_get_user_zombie(id)) {
 
		case 0: {
			if(zp_get_user_survivor(id)) team_check = ZP_TEAM_SURVIVOR
			else team_check = ZP_TEAM_HUMAN
		}
		case 1: {
			if(zp_get_user_nemesis(id)) team_check = ZP_TEAM_NEMESIS
			else team_check = ZP_TEAM_ZOMBIE
		}
	}
 
	if(zp_get_user_zombie(id) && !zp_get_user_nemesis(id)) team_check |= FLAG_A
	else if(!zp_get_user_zombie(id)) team_check |= FLAG_B
	else if(zp_get_user_nemesis(id)) team_check |= FLAG_C
	else if(zp_get_user_survivor(id)) team_check |= FLAG_D
	g_team[id] = team_check
	for(i=0; i < g_registered_items_count; i++) {
		ArrayGetArray(items_database, i, extra_items)
		if(extra_items[i_team] == 0 || g_team[id] & extra_items[i_team]) {
			formatex(holder, charsmax(holder), "%s \r[%s] %s[%d %L]", extra_items[i_name], extra_items[i_description], ammo_packs < extra_items[i_cost] ? "\r" : "\y", extra_items[i_cost], id, "AMMO")
			formatex(num, 2, "%d", i)
			menu_additem(menu, holder, num, 0)
			check++
		}
	}
	if(check == 0) {
		client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "NO_ITEMS")
		return;
	}
	menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
	formatex(holder, charsmax(holder), "%L", id, "NEXT")
	menu_setprop(menu, MPROP_NEXTNAME, holder)
	formatex(holder, charsmax(holder), "%L", id, "BACK")
	menu_setprop(menu, MPROP_BACKNAME, holder)
	formatex(holder, charsmax(holder), "%L", id, "EXIT")
	menu_setprop(menu, MPROP_EXITNAME, holder)
	menu_display(id, menu, 0)
}
 
public vip_menu_handler(id, menu, item)
{
	if( item == MENU_EXIT )
	{
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
 
#if MODE & (1<<0)
	if(get_pcvar_num(g_nonvip_tease) && !(g_user_privileges[id] & FLAG_A)) {
#if MODE & (1<<0)
		buy_meniu(id)
#else
		client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "NOT_A_VIP")
#endif
		menu_destroy(menu)
		return PLUGIN_HANDLED;
	}
#else
	if(get_pcvar_num(g_nonvip_tease) && !(get_user_flags(id) & VIPACCES)) {
#if MODE & (1<<0)
		buy_meniu(id)
#else
		client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "NOT_A_VIP")
#endif
		menu_destroy(menu)
		return PLUGIN_HANDLED;
	}
#endif
	new team_check
	switch(zp_get_user_zombie(id)) {
 
		case 0: {
			if(zp_get_user_survivor(id)) team_check = ZP_TEAM_SURVIVOR
			else team_check = ZP_TEAM_HUMAN
		}
		case 1: {
			if(zp_get_user_nemesis(id)) team_check = ZP_TEAM_NEMESIS
			else team_check = ZP_TEAM_ZOMBIE
		}
	}
 
	if(g_team[id] != team_check) {
 
		menu_destroy(menu)
		vip_menu(id)
		return PLUGIN_HANDLED;
	}
 
	new data[6], iName[64], item_id, ammo_packs
	new aaccess, callback
	menu_item_getinfo(menu, item, aaccess, data,5, iName, 63, callback)
	item_id = str_to_num(data)
	ammo_packs = zp_get_user_ammo_packs(id)
	ArrayGetArray(items_database, item_id, extra_items)
	if(ammo_packs >= extra_items[i_cost]) zp_set_user_ammo_packs(id, ammo_packs - extra_items[i_cost])
	else {
		client_printcolor(id, "/g%s %L", CHAT_PREFIX, id, "MISSING_AMMO", extra_items[i_cost]-ammo_packs)
		if(g_menu_close) menu_destroy(menu)
		else vip_menu(id)
		return PLUGIN_HANDLED
	}
	item_id++
	ExecuteForward(g_extra_item_selected, g_forward_return, id, item_id)
	if (g_forward_return >= ZV_PLUGIN_HANDLED)
		zp_set_user_ammo_packs(id, ammo_packs)
 
	if(!g_menu_close) vip_menu(id)
 
	menu_destroy(menu)
	return PLUGIN_HANDLED
}
#endif
#if MODE & (1<<0) && MODE & (1<<1)
public buy_meniu(id)
{
	new holder[150], menu
	formatex(holder, charsmax(holder), "\r%L", id, "BUY_MENU_TOP", get_pcvar_num(g_vip_cost_ammo), get_pcvar_num(g_vip_buy_time))
	menu = menu_create(holder, "buy_menu_handler")
	new callback = menu_makecallback("_menu_callback")
	formatex(holder, charsmax(holder), "%L", id, "BUY_MENU_TYPE1")
	menu_additem(menu, holder)
	formatex(holder, charsmax(holder), "%L", id, "BUY_MENU_TYPE2")
	menu_additem(menu, holder, _, _, callback)
	formatex(holder, charsmax(holder), "%L", id, "BUY_MENU_TYPE3")
	menu_additem(menu, holder)
 
	menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
	formatex(holder, charsmax(holder), "%L", id, "EXIT")
	menu_setprop(menu, MPROP_EXITNAME, holder)
	menu_display(id, menu, 0)
}
 
public buy_menu_handler(id, menu, item)
{
	if( item == MENU_EXIT )
	{
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
 
	new ammo_packs = zp_get_user_ammo_packs(id)
	if(item > 0) {
		if(ammo_packs >= get_pcvar_num(g_vip_cost_ammo)) {
			amx_tempadmin(id, item)
			zp_set_user_ammo_packs(id, ammo_packs - get_pcvar_num(g_vip_cost_ammo))
			client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "BOUGHT_VIP", get_pcvar_num(g_vip_buy_time))
 
		}
		else client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "MISSING_AMMO", get_pcvar_num(g_vip_cost_ammo)-ammo_packs)
	}
	else {
		nick_buy_meniu(id)
		return PLUGIN_HANDLED
	}
 
	menu_destroy(menu)
	return PLUGIN_HANDLED
}
 
public nick_buy_meniu(id)
{
	new buttons_string[16], menu_string[151], menu_item[81], menu, client_password[20]
	get_user_info(id, amx_password_field_string, client_password, charsmax(client_password))
	formatex(menu_string, 150, "\r%L", id, "NICK_BUY_MENU_TOP", client_password)
	menu = menu_create(menu_string, "nick_buy_menu_handler")
 
	formatex(menu_item, 80, "%L", id, "NICK_BUY_MENU_TYPE1")
	menu_additem(menu, menu_item)
	formatex(menu_item, 80, "%L", id, "NICK_BUY_MENU_TYPE2")
	menu_additem(menu, menu_item)
	formatex(menu_item, 80, "%L", id, "NICK_BUY_MENU_TYPE3", get_pcvar_num(g_vip_cost_ammo) ,get_pcvar_num(g_vip_buy_time))
	menu_additem(menu, menu_item)
 
	menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
	formatex(buttons_string, 15, "%L", id, "BACK")
	menu_setprop(menu, MPROP_EXITNAME, buttons_string)
	menu_display(id, menu, 0)
 
}
 
public nick_buy_menu_handler(id, menu, item)
{
	if( item == MENU_EXIT )
	{
		buy_meniu(id)
		return PLUGIN_HANDLED
	}
 
	switch(item) {
		case 0: {
			generate_password(id)
			set_task(0.2, "menu_delay", id)
		}
		case 1: nick_buy_meniu_sec(id)
		case 2: {
 
			new ammo_packs = zp_get_user_ammo_packs(id)
			if(ammo_packs >= get_pcvar_num(g_vip_cost_ammo)) {
				amx_tempadmin(id, 0)
				zp_set_user_ammo_packs(id, ammo_packs - get_pcvar_num(g_vip_cost_ammo))
				client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "BOUGHT_VIP", get_pcvar_num(g_vip_buy_time))
 
			}
			else client_printcolor(id, "/g%s /y%L", CHAT_PREFIX, id, "MISSING_AMMO", get_pcvar_num(g_vip_cost_ammo)-ammo_packs)
 
			menu_destroy(menu)
			return PLUGIN_HANDLED
		}
	}
 
	menu_destroy(menu)
	return PLUGIN_HANDLED
}
public nick_buy_meniu_sec(id)
{
	new holder[150], menu
	formatex(holder, charsmax(holder), "\r%L", id, "NICK_BUY_MENU_SEC_TOP")
	menu = menu_create(holder, "nick_buy_menu_sec_handler")
 
	formatex(holder, charsmax(holder), "%L", id, "BACK")
	menu_additem(menu, holder)
 
	menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER)
	menu_display(id, menu, 0)
}
 
public nick_buy_menu_sec_handler(id, menu, item)
{
	nick_buy_meniu(id)
	menu_destroy(menu)
	return PLUGIN_HANDLED;
}
 
public _menu_callback(id, menu, item) {
 
	if(item == 1) {
		new authid[30]
		get_user_authid(id, authid, charsmax(authid))
		if(equal(authid, "STEAM_0", 7)) return ITEM_ENABLED
		else return ITEM_DISABLED
	}
 
	return ITEM_ENABLED
}
 
public menu_delay(id) nick_buy_meniu(id)
#endif
public message_cur_weapon(msg_id, msg_dest, msg_entity)
{
	if (!get_pcvar_num(g_unlimited_clip)) return
#if MODE & (1<<0)
	if (!(g_user_privileges[msg_entity] & FLAG_C)) return
#else
	if (!(get_user_flags(msg_entity) & VIPACCES)) return
#endif
	if (!is_user_alive(msg_entity) || get_msg_arg_int(1) != 1) return
 
	static weapon, clip
	weapon = get_msg_arg_int(2)
	clip = get_msg_arg_int(3)
 
	if (MAXCLIP[weapon] > 2)
	{
		set_msg_arg_int(3, get_msg_argtype(3), MAXCLIP[weapon])
 
		if (clip < 2)
		{
			static wname[32], weapon_ent
			get_weaponname(weapon, wname, sizeof wname - 1)
			weapon_ent = find_ent_by_owner(-1, wname, msg_entity)
			fm_set_weapon_ammo(weapon_ent, MAXCLIP[weapon])
		}
	}
}
 
public HUDReset()
	setVip()
 
public setVip()
{
	new players[32], pNum
	get_players(players, pNum, "a")
 
	for (new i = 0; i < pNum; i++)
	{
		new id = players[i]
#if MODE & (1<<0)	
		if (g_user_privileges[id] & FLAG_A)
#else
		if (get_user_flags(id) & VIPACCES)
#endif
		{
			message_begin(MSG_ALL, get_user_msgid("ScoreAttrib"))
			write_byte(id)
			write_byte(4)
			message_end()
		}
	}
	return PLUGIN_HANDLED
}
 
public print_adminlist(user) 
{
	new adminnames[33][32]
	new message[256]
	new contactinfo[256], contact[112]
	new id, count, x, len
 
	for(id = 1 ; id <= maxplayers ; id++)
		if(is_user_connected(id))
#if MODE & (1<<0)
			if(g_user_privileges[id] & FLAG_A)
#else
			if(get_user_flags(id) & VIPACCES)
#endif
				get_user_name(id, adminnames[count++], 31)
 
	len = format(message, 255, "%L ", id, "VIP_STATUS")
	if(count > 0) {
		for(x = 0 ; x < count ; x++) {
			len += format(message[len], 255-len, "%s%s ", adminnames[x], x < (count-1) ? ", ":"")
			if(len > 96 ) {
				client_printcolor(user, "/g%s", message)
				len = format(message, 255, "")
			}
		}
		client_printcolor(user, "/g%s", message)
	}
	else {
		len += format(message[len], 255-len, "%L ", id, "VIP_STATUS_N")
		client_printcolor(user, "/g%s", message)
	}
 
	get_cvar_string("amx_contactinfo", contact, 63)
	if(contact[0])  {
		format(contactinfo, 111, "%L ", id, "VIP_STATUS_CON", contact)
		client_printcolor(user, "/g%s", contactinfo)
	}
 
}
 
public client_disconnect(id)
{
	jumpnum[id] = 0
	g_damage[id] = 0.0
	dojump[id] = false
}
 
public client_PreThink(id)
{
#if MODE & (1<<0)
	if(!is_user_alive(id) || !g_jumps || (!(g_user_privileges[id] & FLAG_B))) return PLUGIN_CONTINUE
#else
	if(!is_user_alive(id) || !g_jumps || (!(get_user_flags(id) & MJACCES))) return PLUGIN_CONTINUE
#endif
	static nbut, obut, fflags
	nbut= get_user_button(id)
	obut = get_user_oldbutton(id)
	fflags = get_entity_flags(id)
 
	if((nbut & IN_JUMP) && !(fflags & FL_ONGROUND) && !(obut & IN_JUMP))
	{
		if(jumpnum[id] < chache_g_jumps && 
		((g_bit & FLAG_D && zp_get_user_nemesis(id)) || 
		(g_bit & FLAG_C && zp_get_user_survivor(id)) || 
		(g_bit & FLAG_A && !zp_get_user_zombie(id)) ||
		(g_bit & FLAG_B && zp_get_user_zombie(id) && !zp_get_user_nemesis(id))))
		{
			dojump[id] = true
			jumpnum[id]++
			return PLUGIN_CONTINUE
		}
	}
	if((nbut & IN_JUMP) && (fflags & FL_ONGROUND))
	{
		jumpnum[id] = 0
		return PLUGIN_CONTINUE
	}
 
	return PLUGIN_CONTINUE
}
 
public client_PostThink(id)
{
#if MODE & (1<<0)
	if(!is_user_alive(id) || !get_pcvar_num(g_jumps) || (!(g_user_privileges[id] & FLAG_B))) return PLUGIN_CONTINUE
#else
	if(!is_user_alive(id) || !get_pcvar_num(g_jumps) || (!(get_user_flags(id) & MJACCES))) return PLUGIN_CONTINUE
#endif
	if(dojump[id] == true)
	{
		static Float:velocity[3]	
		entity_get_vector(id,EV_VEC_velocity,velocity)
		velocity[2] = random_float(265.0,285.0)
		entity_set_vector(id,EV_VEC_velocity,velocity)
		dojump[id] = false
		return PLUGIN_CONTINUE
	}
	return PLUGIN_CONTINUE
}	
 
public ShowMotd(id)
	show_motd(id, "vip.txt")
#if MODE & (1<<0)
public reload_vips() {
 
	if(database_holder) ArrayDestroy(database_holder)
	database_holder = ArrayCreate(database_items)
	new configsDir[64]
	get_configsdir(configsDir, 63)
	format(configsDir, 63, "%s/vips.ini", configsDir)
 
	new File=fopen(configsDir,"r");
 
	if (File)
	{
		static Text[512], Flags[32], AuthData[50], Privileges_Flags[32], Password[50]
		while (!feof(File))
		{
			fgets(File,Text,sizeof(Text)-1);
 
			trim(Text);
 
			// comment
			if (Text[0]==';') 
			{
				continue;
			}
 
			Flags[0]=0;
			AuthData[0]=0;
			Privileges_Flags[0]=0;
			Password[0]=0;
 
			// not enough parameters
			if (parse(Text,AuthData,sizeof(AuthData)-1,Password,sizeof(Password)-1,Privileges_Flags,sizeof(Privileges_Flags)-1,Flags,sizeof(Flags)-1) < 2)
			{
				continue;
			}
 
			vips_database[auth] = AuthData
			vips_database[password] = Password
			vips_database[accessflags] = read_flags(Privileges_Flags)
			vips_database[flags] = read_flags(Flags)
			ArrayPushArray(database_holder, vips_database)
		}
 
		fclose(File);
	}
	else log_amx("Error: vips.ini file doesn't exist")
}
#endif
#if MODE & (1<<0) && MODE & (1<<1)
public check_date()
{
	new holder[20]
	new y, m ,d
	date(y, m, d)
	format(holder, charsmax(holder), "m%dd%dy%d", m, d, y)
 
	new configdir[200]
	get_configsdir(configdir,199)
 
	new configfile1[200]
 
	format(configfile1,199,"%s/vips.ini",configdir)
 
	new text[512], len
	new pnum = file_size(configfile1,1)
	for(new i = 1; i < pnum; i++)
	{
		read_file(configfile1, i, text, 511, len)
		if ( contain(text, holder) != -1 ) 
		{
			DeleteLine(configfile1, i)
		}
	}
	return PLUGIN_HANDLED
}
 
public amx_tempadmin(id, type)
{	
	new authid[31], ip[31], name[51], client_password[20], p_flags[21], sdate[20]
	get_pcvar_string(g_vip_buy_flags, p_flags, charsmax(p_flags))
	get_user_authid(id, authid, charsmax(authid))
	get_user_ip(id, ip, charsmax(ip), 1)
	get_user_name(id, name, charsmax(name))
	get_user_info(id, amx_password_field_string, client_password, charsmax(client_password))
 
	get_date(get_pcvar_num(g_vip_buy_time), sdate, charsmax(sdate))
 
	new holder[200]
	switch(type) {
		case 0: formatex(holder, charsmax(holder), "^"%s^" ^"%s^" ^"%s^" ^"b^"; Exp: %s", name, client_password, p_flags, sdate)
		case 1: formatex(holder, charsmax(holder), "^"%s^" ^"^" ^"%s^" ^"ce^"; Exp: %s", authid, p_flags, sdate)
		case 2: formatex(holder, charsmax(holder), "^"%s^" ^"^" ^"%s^" ^"de^"; Exp: %s", ip, p_flags, sdate)
	}
 
	new configdir[200]
	get_configsdir(configdir, 199)
	new configfile1[200]
	format(configfile1,199,"%s/vips.ini",configdir)
	write_file(configfile1, holder, -1)
	server_cmd("amx_reloadvips")
	set_task(1.0, "set_flags", id)
 
}
 
DeleteLine( const szFilename[ ], const iLine )
{
	new iFile = fopen( szFilename, "rt" );
	if( !iFile )
	{
		return;
	}
	static const szTempFilename[ ] = "delete_line.txt";
	new iTempFile = fopen( szTempFilename, "wt" );
 
	new szData[ 256 ], iLineCount, bool:bReplaced = false;
	while( !feof( iFile ) )
	{
		fgets( iFile, szData, 255 );
 
		if( iLineCount++ == iLine )
		{
			bReplaced = true;
		}
		else
		{
			fputs( iTempFile, szData );
		}
	}
 
	fclose( iFile );
	fclose( iTempFile );
 
	if( bReplaced )
	{
		delete_file( szFilename );
 
		while( !rename_file( szTempFilename, szFilename, 1 ) ) { }
	}
	else
	{
		delete_file( szTempFilename );
	}
}
 
stock get_date(days, string[], chars) {
 
	new y, m, d
	date(y, m ,d)
 
	d+=days
 
	new go = true
	while(go) {
		switch(m) {
			case 1,3, 5, 7, 8, 10: {
				if(d>31) { d=d-31; m++; }
				else go = false
			}
			case 2: {
				if(d>28) { d=d-28; m++; }
				else go = false
			}
			case 4, 6, 9, 11: {
				if(d>30) { d=d-30; m++; }
				else go = false
			}
			case 12: {
				if(d>31) { d=d-31; y++; m=1; }
				else go = false
			}
		}
	}
	formatex(string, chars, "m%dd%dy%d", m, d ,y)
}
#endif
 
stock client_printcolor(id, const message[], any:...)
{
	static buffer[512], argscount
	argscount = numargs()
 
	if (!id) {
 
		static players[32], num, player, i, i2
		get_players(players, num , "ch")
 
		for (i = 0; i < num; i++) {
 
			player = players[i]
 
			static changed[5], changedcount
			changedcount = 0
 
			for (i2 = 2; i2 < argscount; i2++)
			{
				if (getarg(i2) == LANG_PLAYER)
				{
					setarg(i2, 0, player)
					changed[changedcount] = i2
					changedcount++
				}
			}
 
			vformat(buffer, charsmax(buffer), message, 3)
 
			replace_all(buffer, charsmax(buffer), "/g", "^4")
			replace_all(buffer, charsmax(buffer), "/y", "^1")
 
			message_begin(MSG_ONE_UNRELIABLE, g_msgSayText, _, player)
			write_byte(player)
			write_string(buffer)
			message_end()
 
			for (i2 = 0; i2 < changedcount; i2++)
				setarg(changed[i2], 0, LANG_PLAYER)
		}
	}
	else {
 
		vformat(buffer, charsmax(buffer), message, 3)
 
		replace_all(buffer, charsmax(buffer), "/g", "^4")
		replace_all(buffer, charsmax(buffer), "/y", "^1")
 
		message_begin(MSG_ONE_UNRELIABLE, g_msgSayText, _, id)
		write_byte(id)
		write_string(buffer)
		message_end()
	}
}
 
stock fm_find_ent_by_owner(entity, const classname[], owner)
{
	while ((entity = engfunc(EngFunc_FindEntityByString, entity, "classname", classname)) && pev(entity, pev_owner) != owner) {}
 
	return entity;
}
 
stock fm_set_weapon_ammo(entity, amount)
{
	set_pdata_int(entity, OFFSET_CLIPAMMO, amount, OFFSET_LINUX_WEAPONS);
}
#if MODE & (1<<0)
public set_flags(id) {
 
	static authid[31], ip[31], name[51], index, client_password[30], size, log_flags[11]
	get_user_authid(id, authid, 30)
	get_user_ip(id, ip, 30, 1)
	get_user_name(id, name, 50)
	get_user_info(id, amx_password_field_string, client_password, charsmax(client_password))
 
	g_user_privileges[id] = 0
	size = ArraySize(database_holder)
	for(index=0; index < size ; index++) {
		ArrayGetArray(database_holder, index, vips_database)
		if(vips_database[flags] & FLAG_D) {
			if(equal(ip, vips_database[auth])) {
				if(!(vips_database[flags] & FLAG_E)) {
					if(equal(client_password, vips_database[password]))
						g_user_privileges[id] = vips_database[accessflags]
					else if(vips_database[flags] & FLAG_A) {
						server_cmd("kick #%d ^"%L^"", get_user_userid(id), id, "INV_PAS")
						break
					}
				}
				else g_user_privileges[id] = vips_database[accessflags]
				get_flags(vips_database[accessflags], log_flags, 10)
				log_amx("%L",LANG_PLAYER, "AUTHORISED", name, authid, ip, log_flags)
				break
			}
		}
		else if(vips_database[flags] & FLAG_C) {
			if(equal(authid, vips_database[auth])) {
				if(!(vips_database[flags] & FLAG_E)) {
					if(equal(client_password, vips_database[password]))
						g_user_privileges[id] = vips_database[accessflags]
					else if(vips_database[flags] & FLAG_A) {
						server_cmd("kick #%d ^"%L^"", get_user_userid(id), id, "INV_PAS")
						break
					}
				}
				else g_user_privileges[id] = vips_database[accessflags]
				get_flags(vips_database[accessflags], log_flags, 10)
				log_amx("%L",LANG_PLAYER, "AUTHORISED", name, authid, ip, log_flags)
				break
			}
		}
		else {
			if(vips_database[flags] & FLAG_K) {
				if((vips_database[flags] & FLAG_B && contain(name, vips_database[auth]) != -1) || equal(name, vips_database[auth])) {
					if(!(vips_database[flags] & FLAG_E)) {
						if(equal(client_password, vips_database[password]))
							g_user_privileges[id] = vips_database[accessflags]
						else if(vips_database[flags] & FLAG_A) {
							server_cmd("kick #%d ^"%L^"", get_user_userid(id), id, "INV_PAS")
							break
						}
					}
					else g_user_privileges[id] = vips_database[accessflags]
					get_flags(vips_database[accessflags], log_flags, 10)
					log_amx("%L",LANG_PLAYER, "AUTHORISED", name, authid, ip, log_flags)
					break
				}
			}
			else {
				if((vips_database[flags] & FLAG_B && containi(name, vips_database[auth]) != -1) || equali(name, vips_database[auth])) {
					if(!(vips_database[flags] & FLAG_E)) {
						if(equal(client_password, vips_database[password]))
							g_user_privileges[id] = vips_database[accessflags]
						else if(vips_database[flags] & FLAG_A) {
							server_cmd("kick #%d ^"%L^"", get_user_userid(id), id, "INV_PAS")
							break
						}
					}
					else g_user_privileges[id] = vips_database[accessflags]
					get_flags(vips_database[accessflags], log_flags, 10)
					log_amx("%L",LANG_PLAYER, "AUTHORISED", name, authid, ip, log_flags)
					break
				}
			}
		}
	}
}
#endif
#if MODE & (1<<0) && MODE & (1<<1)
stock generate_password(id) {
 
	new password_holder[30]
	formatex(password_holder, charsmax(password_holder), "%d%d%d%d%d", random(10), random(10), random(10), random(10), random(10))
	client_cmd(id, "setinfo %s %s", amx_password_field_string, password_holder)
}
#endif
#if MODE & (1<<0)
public native_zv_get_user_flags(id)
	return g_user_privileges[id]
#endif
#if MODE & (1<<1)
public native_zv_register_extra_item(const item_name[], const item_discription[], item_cost, item_team)
{
		if(!items_database) items_database = ArrayCreate(items)
 
		param_convert(1)
		param_convert(2)
		copy(extra_items[i_name], 30, item_name)
		copy(extra_items[i_description], 30, item_discription)
		extra_items[i_cost] = item_cost
		extra_items[i_team] = item_team
		ArrayPushArray(items_database, extra_items)
		g_registered_items_count++
 
		return g_registered_items_count
}
 
public plugin_end() if(items_database) ArrayDestroy(items_database)
#endif
 

/*================================================================================
 
	[ZP] Extra Item: Advanced Antidote Gun
	Copyright (C) 2010 by meTaLiCroSS, Vińa del Mar, Chile
 
	This program is free software: you can redistribute it and/or modify
	it under the terms of the GNU General Public License as published by
	the Free Software Foundation, either version 3 of the License, or
	(at your option) any later version.
 
	This program is distributed in the hope that it will be useful,
	but WITHOUT ANY WARRANTY; without even the implied warranty of
	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
	GNU General Public License for more details.
 
	You should have received a copy of the GNU General Public License
	along with this program.  If not, see <http://www.gnu.org/licenses/>.
 
	In addition, as a special exception, the author gives permission to
	link the code of this program with the Half-Life Game Engine ("HL
	Engine") and Modified Game Libraries ("MODs") developed by Valve,
	L.L.C ("Valve"). You must obey the GNU General Public License in all
	respects for all of the code used other than the HL Engine and MODs
	from Valve. If you modify this file, you may extend this exception
	to your version of the file, but you are not obligated to do so. If
	you do not wish to do so, delete this exception statement from your
	version.
 
	** Credits:
 
	- ConnorMcLeod: His MaxClip and Reload Speed plugin
	- KCE: His "Blocking weapon fire" tutorial
	- XxAvalanchexX: His "Beampoints from a player's weapon tip" tutorial
 
=================================================================================*/
 
#include <amxmodx>
#include <hamsandwich>
#include <fun>
#include <engine>
#include <cstrike>
#include <fakemeta>
#include <xs>
#include <zombieplague>
#include <zmvip>
 
/*================================================================================
 [Customizations]
=================================================================================*/
 
// Item Cost
const antidotegun_ap_cost = 30
 
// Sprites
new const antidotegun_sprite_beam[] = "sprites/zbeam6.spr"
new const antidotegun_sprite_ring[] = "sprites/shockwave.spr"
 
// Weapon Fire Sound, you can add more than 1
new const antidotegun_firesound[][] = { "weapons/gauss2.wav" }
 
// Hit Sound, you can add more than 1
new const antidotegun_hitsound[][] = { "warcraft3/frostnova.wav" }
 
// Ammo bought Sound, you can add more than 1
new const antidotegun_ammopickupsound[][] = { "items/9mmclip1.wav" }
 
// Weaponbox Glow RGB Colors	R	G	B
new antidotegun_wb_color[] = {	0, 	255, 	255 	}
 
// Uncomment this line if you want to add support to old ZP versions
// Use if it's necessary, from version 4.2 to below
// If you uncomment this line, this item can be buyed only in infection
// rounds, because the main disinfect native in old versions works
// only on infection rounds.
//#define OLD_VERSION_SUPPORT
 
/*================================================================================
 Customization ends here! Yes, that's it. Editing anything beyond
 here is not officially supported. Proceed at your own risk...
=================================================================================*/
 
// Booleans
new bool:g_bHasAntidoteGun[33], bool:g_bIsConnected[33], bool:g_bIsAlive[33]
 
// Cvar pointers
new cvar_enable, cvar_oneround, cvar_firerate, cvar_maxclip, cvar_maxbpammo, cvar_wboxglow, 
cvar_buyindelay, cvar_reloadspeed, cvar_hitslowdown
 
// Arrays
new g_iCurrentWeapon[33], Float:g_flLastFireTime[33]
 
// Variables
new g_iItemID, g_iMaxPlayers, g_msgSayText, g_msgDeathMsg, g_msgCurWeapon, g_msgAmmoX, 
g_msgAmmoPickup, g_msgScreenFade, g_sprBeam, g_sprRing, HamHook:g_iHhPostFrame_fw
 
// Offsets
const m_pPlayer = 		41
const m_fInReload =		54
const m_pActiveItem = 		373
const m_flNextAttack = 		83
const m_flTimeWeaponIdle = 	48
const m_flNextPrimaryAttack = 	46
const m_flNextSecondaryAttack =	47
 
// Some constants
const FFADE_IN = 		0x0000
const ENG_NULLENT = 		-1
const UNIT_SECOND =		(1<<12)
const AMMOID_GALIL = 		4
const GALIL_DFT_MAXCLIP =	35
const V_GAUSS_ANIM_FIRE = 	6
const V_GAUSS_ANIM_DRAW = 	8
const V_GAUSS_ANIM_RELOAD = 	2
const EV_INT_WEAPONKEY = 	EV_INT_impulse
const ANTIDOTEGUN_WPNKEY = 	2816
 
// Buy in delay cvar it's disabled 
// for old versions
#if defined OLD_VERSION_SUPPORT
	#pragma unused cvar_buyindelay
#endif
 
// Cached cvars
new bool:g_bCvar_Enabled, bool:g_bCvar_BuyUntilMode, Float:g_flCvar_FireRate,
Float:g_flCvar_ReloadSpeed, Float:g_flCvar_HitSlowdown, g_iCvar_MaxClip, g_iCvar_MaxBPAmmo
 
// Plug info.
#define PLUG_VERSION "0.6"
#define PLUG_AUTH "meTaLiCroSS"
 
// Macros
#define is_user_valid_alive(%1) 	(1 <= %1 <= g_iMaxPlayers && g_bIsAlive[%1])
#define is_user_valid_connected(%1) 	(1 <= %1 <= g_iMaxPlayers && g_bIsConnected[%1])
 
/*================================================================================
 [Init and Precache]
=================================================================================*/
 
public plugin_init() 
{
	// Plugin info
	register_plugin("[ZP] Extra Item: Advanced Antidote Gun", PLUG_VERSION, PLUG_AUTH)
 
	// Events
	register_event("CurWeapon", "event_CurWeapon", "b", "1=1")	
	register_event("HLTV", "event_RoundStart", "a", "1=0", "2=0")
 
	// Fakemeta Forwards
	register_forward(FM_SetModel, "fw_SetModel")
	register_forward(FM_CmdStart, "fw_CmdStart")
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
 
	// Hamsandwich Forwards
	RegisterHam(Ham_Killed, "player", "fw_PlayerKilled")
	RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1)
	RegisterHam(Ham_Item_Deploy, "weapon_galil", "fw_Galil_Deploy_Post", 1)
	RegisterHam(Ham_Item_AddToPlayer, "weapon_galil", "fw_Galil_AddToPlayer")
	RegisterHam(Ham_Weapon_Reload, "weapon_galil", "fw_Galil_Reload_Post", 1)
	g_iHhPostFrame_fw = RegisterHam(Ham_Item_PostFrame, "weapon_galil", "fw_Galil_PostFrame")
 
	// Cvars
	cvar_enable = register_cvar("zp_antidotegun_enable", "1")
	cvar_oneround = register_cvar("zp_antidotegun_oneround", "0")
	cvar_firerate = register_cvar("zp_antidotegun_fire_rate", "0.6")
	cvar_maxclip = register_cvar("zp_antidotegun_max_clip", "3")
	cvar_maxbpammo = register_cvar("zp_antidotegun_max_bpammo", "25")
	cvar_reloadspeed = register_cvar("zp_antidotegun_reload_speed", "2.5")
	cvar_wboxglow = register_cvar("zp_antidotegun_wbox_glow", "1")
	cvar_buyindelay = register_cvar("zp_antidotegun_buy_before_modestart", "0")
	cvar_hitslowdown = register_cvar("zp_antidotegun_hit_slowdown", "0.4")
 
	static szCvar[30]
	formatex(szCvar, charsmax(szCvar), "v%s by %s", PLUG_VERSION, PLUG_AUTH)
	register_cvar("zp_extra_adv_antidotegun", szCvar, FCVAR_SERVER|FCVAR_SPONLY)
 
	// Variables
	g_iMaxPlayers = get_maxplayers()
	g_msgAmmoX = get_user_msgid("AmmoX")
	g_msgSayText = get_user_msgid("SayText")
	g_msgDeathMsg = get_user_msgid("DeathMsg")
	g_msgCurWeapon = get_user_msgid("CurWeapon")
	g_msgAmmoPickup = get_user_msgid("AmmoPickup")
	g_msgScreenFade = get_user_msgid("ScreenFade")
	g_iItemID = zv_register_extra_item("Antidote Gun", "Desinfecting people", antidotegun_ap_cost, ZV_TEAM_HUMAN)
}
 
public plugin_precache()
{
	// Models
	precache_model("models/v_gauss.mdl")
	precache_model("models/p_gauss.mdl")
	precache_model("models/w_gauss.mdl")
 
	// Sprites
	g_sprBeam = precache_model(antidotegun_sprite_beam)
	g_sprRing = precache_model(antidotegun_sprite_ring)
 
	// Sounds
	static i
	for(i = 0; i < sizeof antidotegun_firesound; i++)
		precache_sound(antidotegun_firesound[i])
	for(i = 0; i < sizeof antidotegun_ammopickupsound; i++)
		precache_sound(antidotegun_ammopickupsound[i])
	for(i = 0; i < sizeof antidotegun_hitsound; i++)
		precache_sound(antidotegun_hitsound[i])
 
 
}
 
public plugin_cfg()
{
	// Cache some cvars after init is called
	cache_cvars()
 
	// Check the max clip cvar
	if(g_iCvar_MaxClip && g_iCvar_MaxClip != GALIL_DFT_MAXCLIP)
	{
		EnableHamForward(g_iHhPostFrame_fw)
	}
	else
	{
		// Should disable it if isn't necesary to check
		DisableHamForward(g_iHhPostFrame_fw)
	}
}
 
/*================================================================================
 [Main Events]
=================================================================================*/
 
public event_CurWeapon(id)
{
	// Not alive...
	if(!g_bIsAlive[id])
		return PLUGIN_CONTINUE
 
	// Updating weapon array
	g_iCurrentWeapon[id] = read_data(2)
 
	// Zombie or Survivor
	if(zp_get_user_zombie(id) || zp_get_user_survivor(id))
		return PLUGIN_CONTINUE
 
	// Doesn't has an Antidote Gun and weapon isn't Galil
	if(!g_bHasAntidoteGun[id] || g_iCurrentWeapon[id] != CSW_GALIL) 
		return PLUGIN_CONTINUE
 
	// Change his models
	entity_set_string(id, EV_SZ_viewmodel, "models/v_gauss.mdl")
	entity_set_string(id, EV_SZ_weaponmodel, "models/p_gauss.mdl")
 
	return PLUGIN_CONTINUE
}
 
public event_RoundStart()
{
	// Some cvars cache on round start
	cache_cvars()
}
 
/*================================================================================
 [Zombie Plague Forwards]
=================================================================================*/
 
public zp_user_humanized_pre(id)
{
	// Update bool when was buyed an antidote
	g_bHasAntidoteGun[id] = false
}
 
public zp_user_infected_post(id)
{
	// Update bool when was infected
	g_bHasAntidoteGun[id] = false
}
 
public zv_extra_item_selected(id, itemid)
{
	// It's an antidote gun itemid
	if(itemid == g_iItemID)
	{
		// Should be enabled
		if(g_bCvar_Enabled)
		{
			// Buy until round starts?
			if (!zp_has_round_started() && !g_bCvar_BuyUntilMode)
			{
				client_printcolor(id, "/g[ZP]/y You must wait until the round starts")
 
				#if defined OLD_VERSION_SUPPORT
				zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + antidotegun_ap_cost)
				return PLUGIN_CONTINUE
				#else
				return ZV_PLUGIN_HANDLED
				#endif
			}
 
			#if defined OLD_VERSION_SUPPORT
			// Check actual mode id
			if(zp_is_plague_round() || zp_is_swarm_round() || zp_is_nemesis_round() || zp_is_survivor_round())
			{
				client_printcolor(id, "/g[ZP]/y You can't buy this gun in this round")
				zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + antidotegun_ap_cost)
				return PLUGIN_CONTINUE
			}
			#endif
 
			// Some vars with info
			new iWpnID, iAmmo, iBPAmmo, bool:bAlreadyHasGalil = bool:user_has_weapon(id, CSW_GALIL)
 
			// Already has this gun
			if(g_bHasAntidoteGun[id] && bAlreadyHasGalil)
			{
				// Update the current backpack ammo
				iBPAmmo = cs_get_user_bpammo(id, CSW_GALIL)
 
				// We can't give more ammo
				if(iBPAmmo >= g_iCvar_MaxBPAmmo)
				{
					client_printcolor(id, "/g[ZP]/y Your Antidote Gun backpack ammo it's full")
 
					#if defined OLD_VERSION_SUPPORT
					zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + antidotegun_ap_cost)
					return PLUGIN_CONTINUE
					#else
					return ZV_PLUGIN_HANDLED
					#endif
				}
 
				// Get the new ammo it are going to be used by the player
				static iNewAmmo
				iNewAmmo = g_iCvar_MaxBPAmmo - iBPAmmo
 
				// Give the new amount of ammo
				cs_set_user_bpammo(id, CSW_GALIL, iBPAmmo + iNewAmmo)
 
				// Flash ammo in hud
				message_begin(MSG_ONE_UNRELIABLE, g_msgAmmoPickup, _, id)
				write_byte(AMMOID_GALIL) // ammo id
				write_byte(iNewAmmo) // ammo amount
				message_end()
 
				// Play clip purchase sound
				emit_sound(id, CHAN_ITEM, antidotegun_ammopickupsound[random_num(0, sizeof antidotegun_ammopickupsound - 1)], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
			}
			else
			{	
				// We need to get if has an ordinary galil
				if(bAlreadyHasGalil)
					ham_strip_weapon(id, "weapon_galil")
 
				// Update player bool
				g_bHasAntidoteGun[id] = true
 
				// Give and store the weapon id
				iWpnID = give_item(id, "weapon_galil")
 
				// Set the normal weapon ammo
				if(g_iCvar_MaxClip && g_iCvar_MaxClip != GALIL_DFT_MAXCLIP)
					cs_set_weapon_ammo(iWpnID, g_iCvar_MaxClip)
 
				// Set the max bpammo
				cs_set_user_bpammo(id, CSW_GALIL, g_iCvar_MaxBPAmmo)
			}
 
			// We should update this var if isn't info into.
			if(!iWpnID) iWpnID = find_ent_by_owner(ENG_NULLENT, "weapon_galil", id)
 
			// Yes or yes we need to update this vars with the current ammo amount
			iAmmo = cs_get_weapon_ammo(iWpnID)
			iBPAmmo = cs_get_user_bpammo(id, CSW_GALIL)
 
			// Force to change his gun
			engclient_cmd(id, "weapon_galil")
 
			// Update the player ammo
			update_ammo_hud(id, iAmmo, iBPAmmo)
		}
		else
		{
			// A message
			client_printcolor(id, "/g[ZP]/y Antidote Gun item has been disabled. /gContact Admin")
 
			#if defined OLD_VERSION_SUPPORT
			zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + antidotegun_ap_cost)
			return PLUGIN_CONTINUE
			#else
			return ZV_PLUGIN_HANDLED
			#endif
		}
	}
 
	return PLUGIN_CONTINUE
}
 
/*================================================================================
 [Main Forwards]
=================================================================================*/
 
public client_putinserver(id)
{
	// Updating bools
	g_bIsConnected[id] = true
	g_bHasAntidoteGun[id] = false
}
 
public client_disconnect(id)
{
	// Updating bools
	g_bIsAlive[id] = false
	g_bIsConnected[id] = false
	g_bHasAntidoteGun[id] = false
}
 
public fw_PlayerSpawn_Post(id)
{
	// Not alive...
	if(!is_user_alive(id))
		return HAM_IGNORED
 
	// Player is alive
	g_bIsAlive[id] = true
 
	// Remove Weapon
	if(get_pcvar_num(cvar_oneround) || !g_bCvar_Enabled)
	{
		if(g_bHasAntidoteGun[id])
		{
			// Reset player vars
			g_bHasAntidoteGun[id] = false
 
			// Strip his galil
			ham_strip_weapon(id, "weapon_galil")
		}
	}
 
	return HAM_IGNORED
}
 
public fw_PlayerKilled(victim, attacker, shouldgib)
{
	// Player victim
	if(is_user_valid_connected(victim))
	{
		// Victim is not alive
		g_bIsAlive[victim] = false
 
		// Reset player vars
		g_bHasAntidoteGun[victim] = false
 
		return HAM_HANDLED
	}
 
	return HAM_IGNORED
}
 
public fw_CmdStart(id, handle, seed)
{
	// Skip not alive users
	if(!is_user_valid_alive(id))
		return FMRES_IGNORED
 
	// Without an antidote gun
	if(!g_bHasAntidoteGun[id])
		return FMRES_IGNORED
 
	// Not human
	if(zp_get_user_zombie(id) || zp_get_user_survivor(id))
		return FMRES_IGNORED
 
	// Isn't holding a Galil
	if(g_iCurrentWeapon[id] != CSW_GALIL)
		return FMRES_IGNORED
 
	// Get Buttons
	static iButton
	iButton = get_uc(handle, UC_Buttons)
 
	// User pressing +attack Button
	if(iButton & IN_ATTACK)
	{
		// Buttons
		set_uc(handle, UC_Buttons, iButton & ~IN_ATTACK)
 
		// Some vars
		static Float:flCurrentTime
		flCurrentTime = halflife_time()
 
		// Fire rate not over yet
		if (flCurrentTime - g_flLastFireTime[id] < g_flCvar_FireRate)
			return FMRES_IGNORED
 
		// Another vars with info
		static iWpnID, iClip
		iWpnID = get_pdata_cbase(id, m_pActiveItem, 5)
		iClip = cs_get_weapon_ammo(iWpnID)
 
		// Skip if is in reload
		if(get_pdata_int(iWpnID, m_fInReload, 4))
			return FMRES_IGNORED
 
		// To don't reload instantly (bugfix)
		set_pdata_float(iWpnID, m_flNextPrimaryAttack, g_flCvar_FireRate, 4)
		set_pdata_float(iWpnID, m_flNextSecondaryAttack, g_flCvar_FireRate, 4)
		set_pdata_float(iWpnID, m_flTimeWeaponIdle, g_flCvar_FireRate, 4)
 
		// Update last fire time array
		g_flLastFireTime[id] = flCurrentTime
 
		// 0 bullets
		if(iClip <= 0)
		{
			// Play empty clip sound
			ExecuteHamB(Ham_Weapon_PlayEmptySound, iWpnID)
 
			return FMRES_IGNORED
		}
 
		// Process fire
		primary_attack(id)
 
		// Real fire push knockback
		launch_push(id, 40)
 
		// Update Ammo
		cs_set_weapon_ammo(iWpnID, --iClip)
		update_ammo_hud(id, iClip, cs_get_user_bpammo(id, CSW_GALIL))
 
		return FMRES_IGNORED
	}
 
	return FMRES_IGNORED
}
 
public fw_SetModel(entity, model[])
{
	// Entity is not valid
	if(!is_valid_ent(entity))
		return FMRES_IGNORED;
 
	// Entity model is not w_galil
	if(!equal(model, "models/w_galil.mdl")) 
		return FMRES_IGNORED;
 
	// Get classname
	static szClassName[33]
	entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName))
 
	// Not a Weapon box
	if(!equal(szClassName, "weaponbox"))
		return FMRES_IGNORED
 
	// Some vars
	static iOwner, iStoredGalilID
 
	// Get owner
	iOwner = entity_get_edict(entity, EV_ENT_owner)
 
	// Get drop weapon index (galil) to use in fw_Galil_AddToPlayer forward
	iStoredGalilID = find_ent_by_owner(ENG_NULLENT, "weapon_galil", entity)
 
	// Entity classname is weaponbox, and galil has founded
	if(g_bHasAntidoteGun[iOwner] && is_valid_ent(iStoredGalilID))
	{
		// Setting weapon options
		entity_set_int(iStoredGalilID, EV_INT_WEAPONKEY, ANTIDOTEGUN_WPNKEY)
 
		// Reset user vars
		g_bHasAntidoteGun[iOwner] = false
 
		// Set weaponbox new model
		entity_set_model(entity, "models/w_gauss.mdl")
 
		// Glow
		if(get_pcvar_num(cvar_wboxglow))
			set_rendering(entity, kRenderFxGlowShell, antidotegun_wb_color[0], antidotegun_wb_color[1], antidotegun_wb_color[2], kRenderNormal, 25)
 
		return FMRES_SUPERCEDE
	}
 
	return FMRES_IGNORED
}
 
public fw_UpdateClientData_Post(id, sendweapons, handle)
{
	// Skip not alive users
	if(!is_user_valid_alive(id))
		return FMRES_IGNORED
 
	// Without an antidote gun
	if(!g_bHasAntidoteGun[id])
		return FMRES_IGNORED
 
	// Not human
	if(zp_get_user_zombie(id) || zp_get_user_survivor(id))
		return FMRES_IGNORED
 
	// Isn't holding a Galil
	if(g_iCurrentWeapon[id] != CSW_GALIL)
		return FMRES_IGNORED
 
	// Player can't attack with the AG
	set_cd(handle, CD_flNextAttack, halflife_time() + 0.001)
 
	return FMRES_HANDLED
}
 
public fw_Galil_Deploy_Post(galil)
{
	// Get galil owner
	static id
	id = get_pdata_cbase(galil, m_pPlayer, 4)
 
	// The current galil owner has an antidote gun?
	if(is_user_valid_connected(id) && g_bHasAntidoteGun[id])
	{
		// Update the current ammo
		update_ammo_hud(id, cs_get_weapon_ammo(galil), cs_get_user_bpammo(id, CSW_GALIL))
 
		// Send the draw animation
		set_user_weaponanim(id, V_GAUSS_ANIM_DRAW)
	}
 
	return HAM_IGNORED
}
 
public fw_Galil_AddToPlayer(galil, player)
{
	// Is an antidote gun?
	if(is_valid_ent(galil) && is_user_valid_connected(player) && entity_get_int(galil, EV_INT_WEAPONKEY) == ANTIDOTEGUN_WPNKEY)
	{
		// Set vars
		g_bHasAntidoteGun[player] = true
 
		// Reset weapon options
		entity_set_int(galil, EV_INT_WEAPONKEY, 0)
 
		return HAM_HANDLED
	}
 
	return HAM_IGNORED
}
 
public fw_Galil_PostFrame(galil)
{
	// Get galil owner
	static id
	id = get_pdata_cbase(galil, m_pPlayer, 4)
 
	// His owner has an antidote gun?
	if(is_user_valid_alive(id) && g_bHasAntidoteGun[id])
	{
		// Some vars
		static Float:flNextAttack, iBpAmmo, iClip, iInReload
 
		// Weapon is on middle reload
		iInReload = get_pdata_int(galil, m_fInReload, 4)
 
		// Next player attack
		flNextAttack = get_pdata_float(id, m_flNextAttack, 5)
 
		// Player back pack ammo
		iBpAmmo = cs_get_user_bpammo(id, CSW_GALIL)
 
		// Current weapon clip
		iClip = cs_get_weapon_ammo(galil)
 
		// End of reload
		if(iInReload && flNextAttack <= 0.0)
		{
			// Get the minimun amount between maxclip sub. current clip 
			// and the player backpack ammo
			new j = min(g_iCvar_MaxClip - iClip, iBpAmmo)
 
			// Set the new weapon clip
			cs_set_weapon_ammo(galil, iClip + j)
 
			// Set the new player backpack ammo
			cs_set_user_bpammo(id, CSW_GALIL, iBpAmmo-j)
 
			// Update the weapon offset "inreload" to 0 ("false")
			iInReload = 0
			set_pdata_int(galil, m_fInReload, 0, 4)
		}
 
		// Get the current player buttons
		static iButton
		iButton = get_user_button(id)
 
		// The player stills pressing the fire button
		if((iButton & IN_ATTACK2 && get_pdata_float(galil, m_flNextSecondaryAttack, 4) <= 0.0) || (iButton & IN_ATTACK && get_pdata_float(galil, m_flNextPrimaryAttack, 4) <= 0.0))
			return
 
		// Trying to reload pressing the reload button when isn't it
		if(iButton & IN_RELOAD && !iInReload)
		{
			// The current weapon clip exceed the new max clip
			if(iClip >= g_iCvar_MaxClip)
			{
				// Retrieve player reload button
				entity_set_int(id, EV_INT_button, iButton & ~IN_RELOAD)
 
				// Send idle animation
				set_user_weaponanim(id, 0)
			}
			// The current weapon clip it's the same like the old max weapon clip
			else if(iClip == GALIL_DFT_MAXCLIP)
			{
				// Has an amount of bpammo?
				if(iBpAmmo)
				{
					// Should make a reload
					antidotegun_reload(id, galil, 1)
				}
			}
		}
	}
 
	// Credits and thanks to ConnorMcLeod for his Weapon MaxClip plugin!
}
 
public fw_Galil_Reload_Post(galil)
{
	// Get galil owner
	static id
	id = get_pdata_cbase(galil, m_pPlayer, 4)
 
	// It's in reload and his owner has an antidote gun?
	if(is_user_valid_alive(id) && g_bHasAntidoteGun[id] && get_pdata_int(galil, m_fInReload, 4))
	{	
		// Change normal reload options
		antidotegun_reload(id, galil)
	}
}
 
/*================================================================================
 [Internal Functions]
=================================================================================*/
 
cache_cvars()
{
	// Some cvars
	g_bCvar_Enabled = bool:get_pcvar_num(cvar_enable)
	g_flCvar_FireRate = get_pcvar_float(cvar_firerate)
	g_flCvar_ReloadSpeed = get_pcvar_float(cvar_reloadspeed)
	g_flCvar_HitSlowdown = get_pcvar_float(cvar_hitslowdown)
	g_iCvar_MaxClip = clamp(get_pcvar_num(cvar_maxclip), 0, 120)
	g_iCvar_MaxBPAmmo = clamp(get_pcvar_num(cvar_maxbpammo), 1, 90)
 
	#if defined OLD_VERSION_SUPPORT
	g_bCvar_BuyUntilMode = false
	#else
	g_bCvar_BuyUntilMode = bool:get_pcvar_num(cvar_buyindelay)
	#endif
}
 
primary_attack(id)
{
	// Fire Effect
	set_user_weaponanim(id, V_GAUSS_ANIM_FIRE)
	entity_set_vector(id, EV_VEC_punchangle, Float:{ -1.5, 0.0, 0.0 })
	emit_sound(id, CHAN_WEAPON, antidotegun_firesound[random_num(0, sizeof antidotegun_firesound - 1)], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
 
	// Some vars
	static iTarget, iBody, iEndOrigin[3]
 
	// Get end origin from eyes
	get_user_origin(id, iEndOrigin, 3)
 
	// Make gun beam
	beam_from_gun(id, iEndOrigin)
 
	// Get user aiming
	get_user_aiming(id, iTarget, iBody)
 
	// Do sound by a new entity
	new iEnt = create_entity("info_target")
 
	// Integer vector into a Float vector
	static Float:flOrigin[3]
	IVecFVec(iEndOrigin, flOrigin)
 
	// Set entity origin
	entity_set_origin(iEnt, flOrigin)
 
	// Sound
	emit_sound(iEnt, CHAN_WEAPON, antidotegun_hitsound[random_num(0, sizeof antidotegun_firesound - 1)], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
 
	// Remove entity
	remove_entity(iEnt)
 
	// Aim target it's a player
	if(is_user_valid_alive(iTarget))
	{	
		// Hit slowdown, first should be enabled
		if(g_flCvar_HitSlowdown > 0.0)
		{
			// Get his current velocity vector
			static Float:flVelocity[3]
			get_user_velocity(iTarget, flVelocity)
 
			// Multiply his velocity by a number
			xs_vec_mul_scalar(flVelocity, g_flCvar_HitSlowdown, flVelocity)
 
			// Set his new velocity vector
			set_user_velocity(iTarget, flVelocity)	
		}
 
		// It's allowed to be disinfected
		if(zp_get_user_zombie(iTarget) && !zp_get_user_nemesis(iTarget) && !zp_get_user_last_zombie(iTarget))
		{
			// Disinfect user
			#if defined OLD_VERSION_SUPPORT
			zp_disinfect_user(iTarget)
			#else
			zp_disinfect_user(iTarget, 1)
			#endif
 
			// Death message
			message_begin(MSG_BROADCAST, g_msgDeathMsg)
			write_byte(id) // killer
			write_byte(iTarget) // victim
			write_byte(iBody == HIT_HEAD ? 1 : 0) // headshot flag
			write_string("antidote gun") // killer's weapon
			message_end()
 
			// Screen fade fx
			message_begin(MSG_ONE_UNRELIABLE, g_msgScreenFade, _, iTarget)
			write_short(UNIT_SECOND*1) // duration
			write_short(UNIT_SECOND/2) // hold time
			write_short(FFADE_IN) // fade type
			write_byte(0) // r
			write_byte(255) // g
			write_byte(255) // b
			write_byte(227) // alpha
			message_end()
 
			// Beam Cylinder fx
			message_begin(MSG_PVS, SVC_TEMPENTITY, iEndOrigin)
			write_byte(TE_BEAMCYLINDER) // TE id
			write_coord(iEndOrigin[0]) // position.x
			write_coord(iEndOrigin[1]) // position.y
			write_coord(iEndOrigin[2]) // position.z
			write_coord(iEndOrigin[0]) // x axis
			write_coord(iEndOrigin[1]) // y axis
			write_coord(iEndOrigin[2] + 385) // z axis
			write_short(g_sprRing) // sprite
			write_byte(0) // startframe
			write_byte(0) // framerate
			write_byte(4) // life
			write_byte(30) // width
			write_byte(0) // noise
			write_byte(0) // red
			write_byte(255) // green
			write_byte(255) // blue
			write_byte(200) // brightness
			write_byte(0) // speed
			message_end()
		}
		// Can't be disinfected
		else
		{
			// Faster particles
			message_begin(MSG_PVS, SVC_TEMPENTITY, iEndOrigin)
			write_byte(TE_PARTICLEBURST) // TE id
			write_coord(iEndOrigin[0]) // position.x
			write_coord(iEndOrigin[1]) // position.y
			write_coord(iEndOrigin[2]) // position.z
			write_short(45) // radius
			write_byte(208) // particle color
			write_byte(10) // duration * 10 will be randomized a bit
			message_end()
		}
	}
	else
	{
		// Aim target entity it's valid and isn't worldspawn?
		if((iTarget > 0) && is_valid_ent(iTarget))
		{
			// Get aim target classname
			static szClassname[32]
			entity_get_string(iTarget, EV_SZ_classname, szClassname, charsmax(szClassname))
 
			// It's a breakable entity
			if(equal(szClassname, "func_breakable"))
			{
				// Get destroy this ent
				force_use(id, iTarget)
			}
		}
	}
}
 
antidotegun_reload(id, galil, force_reload = 0)
{
	// Next player attack time
	set_pdata_float(id, m_flNextAttack, g_flCvar_ReloadSpeed, 5)
 
	// Send to the player the reload animation
	set_user_weaponanim(id, V_GAUSS_ANIM_RELOAD)
 
	// Update the weapon offset "inreload" to 1 ("true")
	if(force_reload)
		set_pdata_int(galil, m_fInReload, 1, 4)
 
	// Next idle weapon time, soonest time ItemPostFrame will call WeaponIdle.
	set_pdata_float(galil, m_flTimeWeaponIdle, g_flCvar_ReloadSpeed + 0.5, 4)
 
	// I'll be honest, i don't know what do this.
	entity_set_float(id, EV_FL_frame, 200.0)
}
 
update_ammo_hud(id, iAmmoAmount, iBPAmmoAmount)
{
	// Display the new antidotegun bullets
	if(iAmmoAmount != -1)
	{
		message_begin(MSG_ONE_UNRELIABLE, g_msgCurWeapon, _, id)
		write_byte(1) // active
		write_byte(CSW_GALIL) // weapon
		write_byte(iAmmoAmount) // clip
		message_end()
	}
 
	// Display the new amount of BPAmmo
	if(iBPAmmoAmount != -1)
	{
		message_begin(MSG_ONE_UNRELIABLE, g_msgAmmoX, _, id)
		write_byte(AMMOID_GALIL) // ammoid
		write_byte(iBPAmmoAmount) // ammo amount
		message_end()
	}
}
 
beam_from_gun(id, iEndOrigin[3])
{
	// Make a cool beam
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_BEAMENTPOINT) // TE id
	write_short(id | 0x1000) // start entity
	write_coord(iEndOrigin[0]) // endposition.x
	write_coord(iEndOrigin[1]) // endposition.y
	write_coord(iEndOrigin[2]) // endposition.z
	write_short(g_sprBeam)    // sprite index
	write_byte(1)	// framestart
	write_byte(1)	// framerate
	write_byte(1)	// life in 0.1's
	write_byte(10)	// width
	write_byte(0)	// noise
	write_byte(0)	// r
	write_byte(255)	// g
	write_byte(255)	// b
	write_byte(200)	// brightness
	write_byte(0)	// speed
	message_end()
 
	// Dynamic Light
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY, iEndOrigin)
	write_byte(TE_DLIGHT) // TE id
	write_coord(iEndOrigin[0]) // position.x
	write_coord(iEndOrigin[1]) // position.y
	write_coord(iEndOrigin[2]) // position.z
	write_byte(30) // radius
	write_byte(0) // red
	write_byte(255) // green
	write_byte(255) // blue
	write_byte(10) // life
	write_byte(45) // decay rate
	message_end()
 
	// Sparks
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY, iEndOrigin)
	write_byte(TE_SPARKS) // TE id
	write_coord(iEndOrigin[0]) // position.x
	write_coord(iEndOrigin[1]) // position.y
	write_coord(iEndOrigin[2]) // position.z
	message_end()
}
 
/*================================================================================
 [Stocks]
=================================================================================*/
 
stock set_user_weaponanim(id, anim)
{
	entity_set_int(id, EV_INT_weaponanim, anim)
	message_begin(MSG_ONE, SVC_WEAPONANIM, {0, 0, 0}, id)
	write_byte(anim)
	write_byte(entity_get_int(id, EV_INT_body))
	message_end()
}
 
stock launch_push(id, velamount) // from my Nemesis Rocket Launcher plugin.
{
	static Float:flNewVelocity[3], Float:flCurrentVelocity[3]
 
	velocity_by_aim(id, -velamount, flNewVelocity)
 
	get_user_velocity(id, flCurrentVelocity)
	xs_vec_add(flNewVelocity, flCurrentVelocity, flNewVelocity)
 
	set_user_velocity(id, flNewVelocity)	
}
 
stock ham_strip_weapon(id, weapon[])
{
	if(!equal(weapon,"weapon_",7)) 
		return 0
 
	new wId = get_weaponid(weapon)
 
	if(!wId) return 0
 
	new wEnt
 
	while((wEnt = find_ent_by_class(wEnt, weapon)) && entity_get_edict(wEnt, EV_ENT_owner) != id) {}
 
	if(!wEnt) return 0
 
	if(get_user_weapon(id) == wId) 
		ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt);
 
	if(!ExecuteHamB(Ham_RemovePlayerItem,id,wEnt)) 
		return 0
 
	ExecuteHamB(Ham_Item_Kill, wEnt)
 
	entity_set_int(id, EV_INT_weapons, entity_get_int(id, EV_INT_weapons) & ~(1<<wId))
 
	return 1
}
 
stock client_printcolor(id, const input[], any:...)
{
	static iPlayersNum[32], iCount; iCount = 1
	static szMsg[191]
 
	vformat(szMsg, charsmax(szMsg), input, 3)
 
	replace_all(szMsg, 190, "/g", "^4") // green txt
	replace_all(szMsg, 190, "/y", "^1") // orange txt
	replace_all(szMsg, 190, "/ctr", "^3") // team txt
	replace_all(szMsg, 190, "/w", "^0") // team txt
 
	if(id) iPlayersNum[0] = id
	else get_players(iPlayersNum, iCount, "ch")
 
	for (new i = 0; i < iCount; i++)
	{
		if (g_bIsConnected[iPlayersNum[i]])
		{
			message_begin(MSG_ONE_UNRELIABLE, g_msgSayText, _, iPlayersNum[i])
			write_byte(iPlayersNum[i])
			write_string(szMsg)
			message_end()
		}
	}
}