#include <amxmodx>

#define PLUGIN "Bomb Countdown HUD Timer"
#define VERSION "0.2"
#define AUTHOR "SAMURAI"
 
new g_c4timer, pointnum;
new bool:b_planted = false;

new g_msgsync;
 
public plugin_init()
{
   register_plugin(PLUGIN,VERSION,AUTHOR);
 
   pointnum = get_cvar_pointer("mp_c4timer");
 
   register_logevent("bomb_planted" , 3 , "2=Planted_The_Bomb");
   register_logevent("bomb_defused" , 3 , "2=Defused_The_Bomb");
   register_logevent("bomb_explode" , 6 , "3=Target_Bombed");
    
   register_logevent("newRound", 2, "1=Round_Start");
   register_logevent("endRound", 2, "1=Round_End");
   register_logevent("endRound", 2, "1&Restart_Round_");
 
   g_msgsync = CreateHudSyncObj();
}
 
public newRound()
{
   g_c4timer = -1;
   remove_task(652450);
   b_planted = false;
}
 
public endRound()
{
   g_c4timer = -1;
   remove_task(652450);
}
 
public bomb_planted()
{
   b_planted = true;
   g_c4timer = get_pcvar_num(pointnum);
   dispTime()
   set_task(1.0, "dispTime", 652450, "", 0, "b");
}
 
public bomb_defused()
{
   if(b_planted)
   {
      remove_task(652450);
      b_planted = false;
   }
    
}
 
public bomb_explode()
{
   if(b_planted)
   {
      remove_task(652450);
      b_planted = false;
   }
   
}
 
public dispTime()
{   
   if(!b_planted)
   {
      remove_task(652450);
      return;
   }
        
 
   if(g_c4timer >= 0)
   {
      if(g_c4timer > 13) set_hudmessage(0, 150, 0, -1.0, 0.80, 0, 1.0, 1.0, 0.01, 0.01, -1);
      else if(g_c4timer > 7) set_hudmessage(150, 150, 0, -1.0, 0.80, 0, 1.0, 1.0, 0.01, 0.01, -1);
      else set_hudmessage(150, 0, 0, -1.0, 0.80, 0, 1.0, 1.0, 0.01, 0.01, -1);
 
      ShowSyncHudMsg(0, g_msgsync, "C4: %d", g_c4timer);
 
      --g_c4timer;
   }
  
} 

#include <amxmodx>

#define PLUGIN    "c4 timer"
#define VERSION "1.1"
#define AUTHOR    "cheap_suit"

new g_c4timer
new mp_c4timer

new cvar_showteam
new cvar_flash
new cvar_sprite
new cvar_msg

new g_msg_showtimer
new g_msg_roundtime
new g_msg_scenario

#define MAX_SPRITES   2
new const g_timersprite[MAX_SPRITES][] = { "bombticking", "bombticking1" }
new const g_message[] = "Detonation time intiallized....."

public plugin_init() 
{
   register_plugin(PLUGIN, VERSION, AUTHOR)
   register_cvar(PLUGIN, VERSION, FCVAR_SPONLY|FCVAR_SERVER)

   cvar_showteam    = register_cvar("amx_showc4timer", "3")
   cvar_flash    = register_cvar("amx_showc4flash", "1")
   cvar_sprite    = register_cvar("amx_showc4sprite", "1")
   cvar_msg    = register_cvar("amx_showc4msg", "0")
   mp_c4timer    = get_cvar_pointer("mp_c4timer")

   g_msg_showtimer   = get_user_msgid("ShowTimer")
   g_msg_roundtime   = get_user_msgid("RoundTime")
   g_msg_scenario   = get_user_msgid("Scenario")
   
   register_event("HLTV", "event_hltv", "a", "1=0", "2=0")
   register_logevent("logevent_plantedthebomb", 3, "2=Planted_The_Bomb")
}

public event_hltv()
   g_c4timer = get_pcvar_num(mp_c4timer)

public logevent_plantedthebomb()
{
   new showtteam = get_pcvar_num(cvar_showteam)
   
   static players[32], num, i
   switch(showtteam)
   {
      case 1: get_players(players, num, "ace", "TERRORIST")
      case 2: get_players(players, num, "ace", "CT")
      case 3: get_players(players, num, "ac")
      default: return
   }
   for(i = 0; i < num; ++i) set_task(1.0, "update_timer", players[i])
}

public update_timer(id)
{
   message_begin(MSG_ONE_UNRELIABLE, g_msg_showtimer, _, id)
   message_end()
   
   message_begin(MSG_ONE_UNRELIABLE, g_msg_roundtime, _, id)
   write_short(g_c4timer)
   message_end()
   
   message_begin(MSG_ONE_UNRELIABLE, g_msg_scenario, _, id)
   write_byte(1)
   write_string(g_timersprite[clamp(get_pcvar_num(cvar_sprite), 0, (MAX_SPRITES - 1))])
   write_byte(150)
   write_short(get_pcvar_num(cvar_flash) ? 20 : 0)
   message_end()
   
   if(get_pcvar_num(cvar_msg))
   {
      set_hudmessage(255, 180, 0, 0.44, 0.87, 2, 6.0, 6.0)
      show_hudmessage(id, g_message)
   }
}