hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.06.04. 14:36

Megválaszolatlan témák | Aktív témák



» » »


Navigáció
Jelenlévő felhasználók

Jelenleg 186 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 186 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  Oldal: 1 / 1
  [ 3 hozzászólás ] 
  Nyomtatóbarát verzió | Barát értesítése e-mailben Előző téma | Következő téma 
Szerző Üzenet
Markooo501
 Hozzászólás témája: Funny Sounds
HozzászólásElküldve: 2016.11.03. 23:21 
Offline
Tag
Avatar

Csatlakozott: 2016.04.24. 13:11
Hozzászólások: 48
Megköszönt másnak: 2 alkalommal
Megköszönték neki: 1 alkalommal
Ezt a hibát találja:
funny_sounds.sma(42) : error 001: expected token: ",", but found ";"
Mi lehet a baj? Valaki tudná javítani a hibát?
Kód: [Egész kijelölése] [Mutatás/Eltüntetés]
  1. #include <amxmodx>
  2. #include <colorchat>
  3.  
  4. new const PLUGIN[] = "Funny Sounds";
  5. new const VERSION[] = "1.0";
  6. new const AUTHOR[] = "mforce";
  7.  
  8.  
  9. new const PREFIX[] = "<<Expert>>";
  10.  
  11. // #define ACCESS_FLAG             ADMIN_KICK          // - Type // before # if you want it for all players.
  12. #define TIME_BETWEEN_SOUNDS     30                  // - in seconds
  13.  
  14.  
  15. new Trie:musiclist
  16. new g_iTime, bool:g_iSwitchOff[33];
  17.  
  18. public plugin_init() {
  19.     register_plugin(PLUGIN, VERSION, AUTHOR);
  20.     register_dictionary("funny_sounds.txt");
  21.    
  22.     register_clcmd("say", "sayhandler");
  23.     register_clcmd("say_team", "sayhandler");
  24.     register_clcmd("say /sounds", "sound_switchoff");
  25.     set_task(300.0, "toswitchoff", 0, .flags="b")
  26. }
  27.  
  28. public toswitchoff() {
  29.     ColorChat(0, NORMAL, "^4[%s]^1 %L ^3/sounds", PREFIX, LANG_SERVER, "TO_SWTICH_OFF");
  30. }
  31.  
  32. public plugin_precache() {
  33.     musiclist = TrieCreate()
  34.    
  35.     new sBuffer[256], sFile[64], sData[2][32], pFile;
  36.  
  37.     get_localinfo("amxx_configsdir", sFile, charsmax(sFile));
  38.     add((sFile, charsmax(sFile), "/funny_sounds.ini");
  39.  
  40.     pFile = fopen(sFile, "rt");
  41.  
  42.     if(pFile) {    
  43.         while(!feof(pFile)) {
  44.             fgets(pFile, sBuffer, charsmax(sBuffer));
  45.             trim(sBuffer);
  46.             if(sBuffer[0] == ';') continue;
  47.  
  48.             parse(sBuffer, sData[0], charsmax(sData[]), sData[1], charsmax(sData[]));
  49.  
  50.             if((containi(sData[1], ".mp3") != -1 || containi(sData[1], ".wav") != -1) && !TrieKeyExists(musiclist, sData[0])) {
  51.                 precache_sound(sData[1])
  52.                 TrieSetString(musiclist, sData[0], sData[1]);
  53.             }
  54.         }
  55.         fclose(pFile);
  56.     }
  57.     else write_file(sFile, ";^"anything^" ^"any_dir/anything.mp3^"^n");
  58. }
  59.  
  60. public sayhandler(id) {
  61.     #if defined ACCESS_FLAG
  62.     if(~get_user_flags(id) & ACCESS_FLAG) return;
  63.     #endif
  64.  
  65.     new message[190]; read_args(message, charsmax(message));
  66.     remove_quotes(message);
  67.    
  68.     if(TrieKeyExists(musiclist, message)) {
  69.         new srvtime = get_systime();
  70.        
  71.         if(srvtime >= g_iTime) {
  72.             new szSound[64];
  73.             TrieGetString(musiclist, message, szSound, charsmax(szSound));
  74.             playsound(szSound);
  75.             g_iTime = (srvtime + TIME_BETWEEN_SOUNDS);
  76.         }
  77.         else
  78.             ColorChat(id, NORMAL, "^4[%s]^1 %L", PREFIX, LANG_SERVER, "YOU_HAVE_TO_WAIT" , (g_iTime - srvtime));
  79.     }
  80. }
  81.  
  82. playsound(const szSound[]) {
  83.     new makesound[256];
  84.     if(containi(szSound, ".mp3") != -1)
  85.         formatex(makesound, charsmax(makesound), "mp3 play ^"sound/%s^"", szSound);
  86.     else
  87.         formatex(makesound, charsmax(makesound), "spk ^"%s^"", szSound);
  88.  
  89.  
  90.     new players[32], num, tempid;
  91.     get_players(players, num, "c");
  92.     for(new i; i<num; i++) {
  93.         tempid = players[i];
  94.         if(!g_iSwitchOff[tempid])
  95.             client_cmd(tempid, "%s", makesound);
  96.     }
  97. }
  98.  
  99. public sound_switchoff(id) {
  100.     switch(g_iSwitchOff[id]) {
  101.         case false: {
  102.             g_iSwitchOff[id] = true;
  103.             client_cmd(id, "setinfo _funnysoundsoff 1");
  104.             ColorChat(id, NORMAL, "^4[%s]^3 %L", PREFIX, LANG_SERVER, "SOUNDS_SWITCHED_OFF");
  105.         }
  106.         case true: {
  107.             g_iSwitchOff[id] = false;
  108.             client_cmd(id, "setinfo _funnysoundsoff 0");
  109.             ColorChat(id, NORMAL, "^4[%s]^3 %L", PREFIX, LANG_SERVER, "SOUNDS_SWITCHED_ON");
  110.         }
  111.     }
  112. }
  113.  
  114. public client_putinserver(id) {
  115.     if(is_user_sounds_off(id))
  116.         g_iSwitchOff[id] = true;
  117. }
  118.  
  119. public client_disconnect(id) {
  120.     g_iSwitchOff[id] = false;
  121. }
  122.  
  123. public plugin_end() {
  124.     TrieDestroy(musiclist);
  125. }
  126.  
  127. stock bool:is_user_sounds_off(id) {
  128.     new switcher[8];
  129.     get_user_info(id, "_funnysoundsoff", switcher, charsmax(switcher));
  130.     if(equal(switcher, "1")) return true;
  131.     return false;
  132. }
GeSHi © Codebox Plus


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
regener
 Hozzászólás témája: Re: Funny Sounds
HozzászólásElküldve: 2016.11.04. 00:20 
Offline
Őstag
Avatar

Csatlakozott: 2015.07.27. 22:56
Hozzászólások: 1367
Megköszönt másnak: 28 alkalommal
Megköszönték neki: 351 alkalommal
38. sor:
Kód: [Egész kijelölése] [Mutatás/Eltüntetés]
  1. add((sFile, charsmax(sFile), "/funny_sounds.ini");
GeSHi © Codebox Plus

->
Kód: [Egész kijelölése] [Mutatás/Eltüntetés]
  1. add(sFile, charsmax(sFile), "/funny_sounds.ini");
GeSHi © Codebox Plus


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
kengurumancs
 Hozzászólás témája: Re: Funny Sounds
HozzászólásElküldve: 2016.11.04. 01:40 
Offline
Félisten
Avatar

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal
Kicsit újabb. (csak egy elírást javítottam)
kengurumancs @ Funny Sounds

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  Oldal: 1 / 1
  [ 3 hozzászólás ] 

» » »


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 40 vendég

Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole