hlmod.hu

 
#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
#include <xs>
#include <cstrike>
#include <zombieplague>
 
enum
{
	anim_idle,
	anim_shoot1,
	anim_shoot2,
	anim_shoot_empty,
	anim_reload,
	anim_draw
}
 
#define ENG_NULLENT		-1
#define EV_INT_WEAPONKEY	EV_INT_impulse
#define infinityr_WEAPONKEY	1231
#define MAX_PLAYERS  			  32
#define IsValidUser(%1) (1 <= %1 <= g_MaxPlayers)
 
const USE_STOPPED = 0
const OFFSET_ACTIVE_ITEM = 373
const OFFSET_WEAPONOWNER = 41
const OFFSET_LINUX = 5
const OFFSET_LINUX_WEAPONS = 4
 
#define WEAP_LINUX_XTRA_OFF			4
#define m_fKnown				44
#define m_flNextPrimaryAttack 			46
#define m_flTimeWeaponIdle			48
#define m_iClip					51
#define m_fInReload				54
#define PLAYER_LINUX_XTRA_OFF			5
#define m_flNextAttack				83
 
#define infinityr_RELOAD_TIME 2.8
const PRIMARY_WEAPONS_BIT_SUM = (1<<CSW_ELITE)|(1<<CSW_P228)|(1<<CSW_USP)|(1<<CSW_GLOCK18)|(1<<CSW_DEAGLE)|(1<<CSW_FIVESEVEN)
new const WEAPONENTNAMES[][] = { "", "weapon_p228", "", "weapon_scout", "weapon_hegrenade", "weapon_xm1014", "weapon_c4", "weapon_mac10",
			"weapon_aug", "weapon_smokegrenade", "weapon_elite", "weapon_fiveseven", "weapon_ump45", "weapon_sg550",
			"weapon_galil", "weapon_famas", "weapon_usp", "weapon_glock18", "weapon_awp", "weapon_mp5navy", "weapon_m249",
			"weapon_m3", "weapon_m4a1", "weapon_tmp", "weapon_g3sg1", "weapon_flashbang", "weapon_deagle", "weapon_sg552",
			"weapon_ak47", "weapon_knife", "weapon_p90" }
new const Fire_Sounds[][] = { "weapons/infinitysr_shoot1.wav" }
new const GUNSHOT_DECALS[] = { 41, 42, 43, 44, 45 }
 
new infinityr_V_MODEL[64] = "models/cso_wpn/v_infinitysr.mdl"
new infinityr_P_MODEL[64] = "models/cso_wpn/p_infinitysr.mdl"
new infinityr_W_MODEL[64] = "models/cso_wpn/w_infinitysr.mdl"
new g_attack1[33]
new cvar_dmg_infinityr, cvar_recoil_infinityr, g_itemid_infinityr, cvar_clip_infinityr, cvar_infinityr_ammo, cvar_spd_infinityr
new g_has_infinityr[33]
new g_MaxPlayers, g_orig_event_infinityr, g_clip_ammo[33]
new Float:cl_pushangle[MAX_PLAYERS + 1][3], m_iBlood[2]
new g_infinityr_TmpClip[33]
new g_canshoot[33]
 
public plugin_init()
{
	register_plugin("[ZP] Weapon: infinityr", "1.0", "Crock / =)")
	register_message(get_user_msgid("DeathMsg"), "message_DeathMsg")
	register_event("CurWeapon","CurrentWeapon","be","1=1")
	RegisterHam(Ham_Item_AddToPlayer, "weapon_deagle", "fw_infinityr_AddToPlayer")
	RegisterHam(Ham_Use, "func_tank", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tankmortar", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tankrocket", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tanklaser", "fw_UseStationary_Post", 1)
	for (new i = 1; i < sizeof WEAPONENTNAMES; i++)
		if (WEAPONENTNAMES[i][0]) RegisterHam(Ham_Item_Deploy, WEAPONENTNAMES[i], "fw_Item_Deploy_Post", 1)
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_deagle", "fw_infinityr_PrimaryAttack")
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_deagle", "fw_infinityr_PrimaryAttack_Post", 1)
	RegisterHam(Ham_Item_PostFrame, "weapon_deagle", "infinityr__ItemPostFrame");
	RegisterHam(Ham_Weapon_Reload, "weapon_deagle", "infinityr__Reload");
	RegisterHam(Ham_Weapon_Reload, "weapon_deagle", "infinityr__Reload_Post", 1);
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	register_forward(FM_CmdStart, "fw_CmdStart")
	register_forward(FM_SetModel, "fw_SetModel")
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
	register_forward(FM_PlaybackEvent, "fwPlaybackEvent")
 
	cvar_dmg_infinityr = register_cvar("infinityred_dmg", "1.5")
	cvar_recoil_infinityr = register_cvar("infinityred_recoil", "0.8")
	cvar_clip_infinityr = register_cvar("infinityred_clipammo", "8")
	cvar_infinityr_ammo = register_cvar("infinityred_bpammo", "40")
	cvar_spd_infinityr = register_cvar("infinityred_spd", "0.0000001")
 
	g_itemid_infinityr = zp_register_extra_item("\r[Pistol] \wInfinity", 8, ZP_TEAM_HUMAN)
	g_MaxPlayers = get_maxplayers()
}
 
public plugin_precache()
{
	precache_model(infinityr_V_MODEL)
	precache_model(infinityr_P_MODEL)
	precache_model(infinityr_W_MODEL)
	precache_sound("weapons/infis_clipin.wav")
	precache_sound("weapons/infis_clipout.wav")
	precache_sound("weapons/infis_draw.wav")
	precache_sound("weapons/infis_foley1.wav")
	precache_sound("weapons/infis_foley2.wav")
	for(new i = 0; i < sizeof Fire_Sounds; i++)
		precache_sound(Fire_Sounds[i])
	m_iBlood[0] = precache_model("sprites/blood.spr")
	m_iBlood[1] = precache_model("sprites/bloodspray.spr")
	precache_model("sprites/640hud5.spr")
	register_forward(FM_PrecacheEvent, "fwPrecacheEvent_Post", 1)
}
 
public fwPrecacheEvent_Post(type, const name[])
{
	if (equal("events/deagle.sc", name))
	{
		g_orig_event_infinityr = get_orig_retval()
		return FMRES_HANDLED
	}
 
	return FMRES_IGNORED
}
 
public client_connect(id)
{
	g_has_infinityr[id] = false
}
 
public fw_CmdStart(id, uc_handle, seed)
{
	if(!is_user_alive(id)) 
		return PLUGIN_HANDLED
 
	new Float:flNextAttack = get_pdata_float(id, m_flNextAttack, PLAYER_LINUX_XTRA_OFF)
 
	if((get_uc(uc_handle, UC_Buttons) & IN_ATTACK) && (pev(id, pev_oldbuttons) & IN_ATTACK))
	{
	g_canshoot[id] = 1
	}else if((get_uc(uc_handle, UC_Buttons) & IN_ATTACK) && !(pev(id, pev_oldbuttons) & IN_ATTACK) && flNextAttack <= 0.0){
	g_canshoot[id] = 0
	}else{
	g_canshoot[id] = 1
	}
 
	if(get_uc(uc_handle, UC_Buttons) & IN_ATTACK)
	{
	g_attack1[id] = 1
	}else{
	g_attack1[id] = 0
	}
 
	return PLUGIN_HANDLED
}
 
public client_disconnect(id)
{
	g_has_infinityr[id] = false
}
 
public zp_user_infected_post(id)
{
	if (zp_get_user_zombie(id))
	{
		g_has_infinityr[id] = false
	}
}
 
public fw_SetModel(entity, model[])
{
	if(!is_valid_ent(entity))
		return FMRES_IGNORED;
 
	static szClassName[33]
	entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName))
 
	if(!equal(szClassName, "weaponbox"))
		return FMRES_IGNORED;
 
	static iOwner
 
	iOwner = entity_get_edict(entity, EV_ENT_owner)
 
	if(equal(model, "models/w_deagle.mdl"))
	{
		static iStoredSVDID
 
		iStoredSVDID = find_ent_by_owner(ENG_NULLENT, "weapon_deagle", entity)
 
		if(!is_valid_ent(iStoredSVDID))
			return FMRES_IGNORED;
 
		if(g_has_infinityr[iOwner])
		{
			entity_set_int(iStoredSVDID, EV_INT_WEAPONKEY, infinityr_WEAPONKEY)
			g_has_infinityr[iOwner] = false
 
			entity_set_model(entity, infinityr_W_MODEL)
 
			return FMRES_SUPERCEDE;
		}
	}
 
 
	return FMRES_IGNORED;
}
 
public zp_extra_item_selected(id, itemid)
{
	if(itemid == g_itemid_infinityr)
	{
		drop_weapons(id, 1);
		new iWep2 = give_item(id,"weapon_deagle")
		if( iWep2 > 0 )
		{
			cs_set_weapon_ammo(iWep2, get_pcvar_num(cvar_clip_infinityr))
			cs_set_user_bpammo (id, CSW_DEAGLE, get_pcvar_num(cvar_infinityr_ammo))
		}
		g_has_infinityr[id] = true;
	}
}
 
public fw_infinityr_AddToPlayer(infinityr, id)
{
	if(!is_valid_ent(infinityr) || !is_user_connected(id))
		return HAM_IGNORED;
 
	if(entity_get_int(infinityr, EV_INT_WEAPONKEY) == infinityr_WEAPONKEY)
	{
		g_has_infinityr[id] = true
 
		entity_set_int(infinityr, EV_INT_WEAPONKEY, 0)
 
		return HAM_HANDLED;
	}
 
	return HAM_IGNORED;
}
 
public fw_UseStationary_Post(entity, caller, activator, use_type)
{
	if (use_type == USE_STOPPED && is_user_connected(caller))
		replace_weapon_models(caller, get_user_weapon(caller))
}
 
public fw_Item_Deploy_Post(weapon_ent)
{
	static owner
	owner = fm_cs_get_weapon_ent_owner(weapon_ent)
 
	static weaponid
	weaponid = cs_get_weapon_id(weapon_ent)
 
	replace_weapon_models(owner, weaponid)
}
 
public CurrentWeapon(id)
{
	static iWeapon; iWeapon = read_data(2)
 
	replace_weapon_models(id, read_data(2))
 
	static weapon[32], iEnt
	get_weaponname(iWeapon, weapon, 31)
	iEnt = find_ent_by_owner(-1, weapon, id)
	if(iEnt)
	{
		static Float:Delay, Float:M_Delay
		static Float:iSpeed
		iSpeed = 0.0
		if(iWeapon == CSW_DEAGLE && g_has_infinityr[id])
			iSpeed = get_pcvar_float(cvar_spd_infinityr)
 
		Delay = get_pdata_float(iEnt, 46, 4) * iSpeed
		M_Delay = get_pdata_float(iEnt, 47, 4) * iSpeed
		if (Delay > 0.0)
		{
			set_pdata_float(iEnt, 46, Delay, 4)
			set_pdata_float(iEnt, 47, M_Delay, 4)
		}
	}
 
}
 
replace_weapon_models(id, weaponid)
{
	switch (weaponid)
	{
		case CSW_DEAGLE:
		{
			if (zp_get_user_zombie(id) || zp_get_user_survivor(id))
				return;
 
			if(g_has_infinityr[id])
			{
				set_pev(id, pev_viewmodel2, infinityr_V_MODEL)
				set_pev(id, pev_weaponmodel2, infinityr_P_MODEL)
			}
		}
	}
}
 
public fw_UpdateClientData_Post(Player, SendWeapons, CD_Handle)
{
        if(!is_user_alive(Player) || (get_user_weapon(Player) != CSW_DEAGLE) || !g_has_infinityr[Player])
        return FMRES_IGNORED
 
	set_cd(CD_Handle, CD_flNextAttack, halflife_time () + 0.001)
	return FMRES_HANDLED
}
 
public fw_infinityr_PrimaryAttack(Weapon)
{
	new Player = get_pdata_cbase(Weapon, 41, 4)
 
	if (!g_has_infinityr[Player])
		return;
 
	pev(Player,pev_punchangle,cl_pushangle[Player])
 
	g_clip_ammo[Player] = cs_get_weapon_ammo(Weapon)
}
 
public fwPlaybackEvent(flags, invoker, eventid, Float:delay, Float:origin[3], Float:angles[3], Float:fparam1, Float:fparam2, iParam1, iParam2, bParam1, bParam2)
{
	if ((eventid != g_orig_event_infinityr))
		return FMRES_IGNORED
	if (!(1 <= invoker <= g_MaxPlayers))
		return FMRES_IGNORED
 
	playback_event(flags | FEV_HOSTONLY, invoker, eventid, delay, origin, angles, fparam1, fparam2, iParam1, iParam2, bParam1, bParam2)
	return FMRES_SUPERCEDE
}
 
public fw_infinityr_PrimaryAttack_Post(Weapon)
{
	new Player = get_pdata_cbase(Weapon, 41, 4)
 
	if(g_has_infinityr[Player] && g_canshoot[Player] == 0)
	{
		if (!g_clip_ammo[Player])
			return
 
		new Float:push[3]
		pev(Player,pev_punchangle,push)
		xs_vec_sub(push,cl_pushangle[Player],push)
 
		xs_vec_mul_scalar(push,get_pcvar_float(cvar_recoil_infinityr),push)
		xs_vec_add(push,cl_pushangle[Player],push)
		set_pev(Player,pev_punchangle,push)
 
		emit_sound(Player, CHAN_WEAPON, Fire_Sounds[0], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
		UTIL_PlayWeaponAnimation(Player, anim_shoot1)
 
		make_blood_and_bulletholes(Player)
		set_pdata_float(Player, m_flNextAttack,0.001, PLAYER_LINUX_XTRA_OFF)
 
	}
 
}
 
public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if (victim != attacker && is_user_connected(attacker))
	{
		if(get_user_weapon(attacker) == CSW_DEAGLE)
		{
			if(g_has_infinityr[attacker])
				SetHamParamFloat(4, damage * get_pcvar_float(cvar_dmg_infinityr))
		}
	}
}
 
public message_DeathMsg(msg_id, msg_dest, id)
{
	static szTruncatedWeapon[33], iAttacker, iVictim
 
	get_msg_arg_string(4, szTruncatedWeapon, charsmax(szTruncatedWeapon))
 
	iAttacker = get_msg_arg_int(1)
	iVictim = get_msg_arg_int(2)
 
	if(!is_user_connected(iAttacker) || iAttacker == iVictim)
		return PLUGIN_CONTINUE
 
	if(equal(szTruncatedWeapon, "deagle") && get_user_weapon(iAttacker) == CSW_DEAGLE)
	{
		if(g_has_infinityr[iAttacker])
			set_msg_arg_string(4, "deagle")
	}
 
	return PLUGIN_CONTINUE
}
 
stock fm_cs_get_current_weapon_ent(id)
{
	return get_pdata_cbase(id, OFFSET_ACTIVE_ITEM, OFFSET_LINUX);
}
 
stock fm_cs_get_weapon_ent_owner(ent)
{
	return get_pdata_cbase(ent, OFFSET_WEAPONOWNER, OFFSET_LINUX_WEAPONS);
}
 
stock UTIL_PlayWeaponAnimation(const Player, const Sequence)
{
	set_pev(Player, pev_weaponanim, Sequence)
 
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, .player = Player)
	write_byte(Sequence)
	write_byte(pev(Player, pev_body))
	message_end()
}
 
stock make_blood_and_bulletholes(id)
{
	new aimOrigin[3], target, body
	get_user_origin(id, aimOrigin, 3)
	get_user_aiming(id, target, body)
 
	if(target > 0 && target <= g_MaxPlayers && zp_get_user_zombie(target))
	{
		new Float:fStart[3], Float:fEnd[3], Float:fRes[3], Float:fVel[3]
		pev(id, pev_origin, fStart)
 
		velocity_by_aim(id, 64, fVel)
 
		fStart[0] = float(aimOrigin[0])
		fStart[1] = float(aimOrigin[1])
		fStart[2] = float(aimOrigin[2])
		fEnd[0] = fStart[0]+fVel[0]
		fEnd[1] = fStart[1]+fVel[1]
		fEnd[2] = fStart[2]+fVel[2]
 
		new res
		engfunc(EngFunc_TraceLine, fStart, fEnd, 0, target, res)
		get_tr2(res, TR_vecEndPos, fRes)
 
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY) 
		write_byte(TE_BLOODSPRITE)
		write_coord(floatround(fStart[0])) 
		write_coord(floatround(fStart[1])) 
		write_coord(floatround(fStart[2])) 
		write_short( m_iBlood [ 1 ])
		write_short( m_iBlood [ 0 ] )
		write_byte(70)
		write_byte(random_num(1,2))
		message_end()
 
 
	} 
	else if(!is_user_connected(target))
	{
		if(target)
		{
			message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
			write_byte(TE_DECAL)
			write_coord(aimOrigin[0])
			write_coord(aimOrigin[1])
			write_coord(aimOrigin[2])
			write_byte(GUNSHOT_DECALS[random_num ( 0, sizeof GUNSHOT_DECALS -1 ) ] )
			write_short(target)
			message_end()
		} 
		else 
		{
			message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
			write_byte(TE_WORLDDECAL)
			write_coord(aimOrigin[0])
			write_coord(aimOrigin[1])
			write_coord(aimOrigin[2])
			write_byte(GUNSHOT_DECALS[random_num ( 0, sizeof GUNSHOT_DECALS -1 ) ] )
			message_end()
		}
 
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
		write_byte(TE_GUNSHOTDECAL)
		write_coord(aimOrigin[0])
		write_coord(aimOrigin[1])
		write_coord(aimOrigin[2])
		write_short(id)
		write_byte(GUNSHOT_DECALS[random_num ( 0, sizeof GUNSHOT_DECALS -1 ) ] )
		message_end()
	}
}
 
public infinityr__ItemPostFrame(weapon_entity) {
	new id = pev(weapon_entity, pev_owner)
	if (!is_user_connected(id))
		return HAM_IGNORED;
 
	if (!g_has_infinityr[id])
		return HAM_IGNORED;
 
	new Float:flNextAttack = get_pdata_float(id, m_flNextAttack, PLAYER_LINUX_XTRA_OFF)
 
	new iBpAmmo = cs_get_user_bpammo(id, CSW_DEAGLE);
	new iClip = get_pdata_int(weapon_entity, m_iClip, WEAP_LINUX_XTRA_OFF)
 
	new fInReload = get_pdata_int(weapon_entity, m_fInReload, WEAP_LINUX_XTRA_OFF) 
 
	if( fInReload && flNextAttack <= 0.0 )
	{
		new Player = id
		new j = min(get_pcvar_num(cvar_clip_infinityr) - iClip, iBpAmmo)
 
		set_pdata_int(weapon_entity, m_iClip, iClip + j, WEAP_LINUX_XTRA_OFF)
		cs_set_user_bpammo(id, CSW_DEAGLE, iBpAmmo-j);
 
		if(g_attack1[id] == 1)
		{
		new Float:push[3]
		pev(Player,pev_punchangle,push)
		xs_vec_sub(push,cl_pushangle[Player],push)
 
		xs_vec_mul_scalar(push,get_pcvar_float(cvar_recoil_infinityr),push)
		xs_vec_add(push,cl_pushangle[Player],push)
		set_pev(Player,pev_punchangle,push)
 
		emit_sound(Player, CHAN_WEAPON, Fire_Sounds[0], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
		UTIL_PlayWeaponAnimation(Player, anim_shoot1)
 
		make_blood_and_bulletholes(Player)
		set_pdata_float(Player, m_flNextAttack,0.2, PLAYER_LINUX_XTRA_OFF)
		}
 
		set_pdata_int(weapon_entity, m_fInReload, 0, WEAP_LINUX_XTRA_OFF)
		fInReload = 0
	}
 
	return HAM_IGNORED;
}
 
public infinityr__Reload(weapon_entity) {
	new id = pev(weapon_entity, pev_owner)
	if (!is_user_connected(id))
		return HAM_IGNORED;
 
	if (!g_has_infinityr[id])
		return HAM_IGNORED;
 
	g_infinityr_TmpClip[id] = -1;
 
	new iBpAmmo = cs_get_user_bpammo(id, CSW_DEAGLE);
	new iClip = get_pdata_int(weapon_entity, m_iClip, WEAP_LINUX_XTRA_OFF)
 
	if (iBpAmmo <= 0)
		return HAM_SUPERCEDE;
 
	if (iClip >= get_pcvar_num(cvar_clip_infinityr))
		return HAM_SUPERCEDE;
 
 
	g_infinityr_TmpClip[id] = iClip;
 
	return HAM_IGNORED;
}
 
public infinityr__Reload_Post(weapon_entity) {
	new id = pev(weapon_entity, pev_owner)
	if (!is_user_connected(id))
		return HAM_IGNORED;
 
	if (!g_has_infinityr[id])
		return HAM_IGNORED;
 
	if (g_infinityr_TmpClip[id] == -1)
		return HAM_IGNORED;
 
	set_pdata_int(weapon_entity, m_iClip, g_infinityr_TmpClip[id], WEAP_LINUX_XTRA_OFF)
 
	set_pdata_float(weapon_entity, m_flTimeWeaponIdle, infinityr_RELOAD_TIME, WEAP_LINUX_XTRA_OFF)
 
	set_pdata_float(id, m_flNextAttack, infinityr_RELOAD_TIME, PLAYER_LINUX_XTRA_OFF)
 
	set_pdata_int(weapon_entity, m_fInReload, 1, WEAP_LINUX_XTRA_OFF)
 
	// relaod animation
	UTIL_PlayWeaponAnimation(id, 4)
 
	return HAM_IGNORED;
}
 
stock drop_weapons(id, dropwhat)
{
     static weapons[32], num, i, weaponid
     num = 0
     get_user_weapons(id, weapons, num)
 
     for (i = 0; i < num; i++)
     {
          weaponid = weapons[i]
 
          if (dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM))
          {
               static wname[32]
               get_weaponname(weaponid, wname, sizeof wname - 1)
               engclient_cmd(id, "drop", wname)
          }
     }
}