hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2025.11.04. 01:59

Megválaszolatlan témák | Aktív témák



» » »


Navigáció
Jelenlévő felhasználók

Jelenleg 279 felhasználó van jelen :: 1 regisztrált, 0 rejtett és 278 vendég

A legtöbb felhasználó (2883 fő) 2025.07.30. 16:00-kor tartózkodott itt.

Regisztrált felhasználók: Bing [Bot]az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása Hozzászólás a témához  Oldal: 1 / 1
  [9 hozzászólás ] 
 Nyomtatóbarát verzió |Barát értesítése e-mailben Előző téma | Következő téma 
Szerző Üzenet
expert
HozzászólásElküldve:2013.07.21. 20:59 
Offline
Őstag
Avatar

Csatlakozott:2010.04.16. 16:50
Hozzászólások:1342
Megköszönt másnak: 42 alkalommal
Megköszönték neki: 58 alkalommal
Sziasztok, van a c4 plugin amivel meglehet határozni hogy hova lehessen rakni a bombát, na és ez a plugin leáll ha nem bombás map van vagy ha nincs az ini fájlba beleirva a bomba lerakok stb.
Na és ez a rész érdekelne engemet hogy hogy állítja le ?(nem pause hanem stop) a kodot néztem de én nem tudtam kibogarászni belőle
SMA Forráskód: [ Mindet kijelol ]
  1. c4 management           NotBombMap  ConnorMcLeod      c4_management.a  stopped

SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <amxmisc>
  3. #include <fakemeta>
  4. #include <hamsandwich>
  5.  
  6. #define VERSION "0.2.7"
  7.  
  8. #define MAX_PLAYERS 32
  9.  
  10. enum _:BombSites_Datas {
  11. 	iBsIndex,
  12. 	szBsModel[5]
  13. }
  14.  
  15. enum _:BombSites_States {
  16. 	AllSites,
  17. 	MainSite,
  18. 	NoSite
  19. }
  20.  
  21. #define StatusIconDontShow 0
  22. #define StatusIconShow 1
  23.  
  24. new const func_bomb_target[] = "func_bomb_target"
  25. new const info_bomb_target[] = "info_bomb_target"
  26.  
  27. new const classname[] = "classname"
  28.  
  29. #define FIND_ENT_BY_CLASSNAME(%1,%2)	engfunc(EngFunc_FindEntityByString, %1, classname, %2)
  30.  
  31. #define XTRA_OFS_PLAYER 5
  32. #define m_iTeam 114
  33. #define cs_get_user_team_index(%1)		get_pdata_int(%1, m_iTeam, XTRA_OFS_PLAYER)
  34. #define CS_TEAM_CT 2
  35.  
  36. new g_iMaxPlayers
  37.  
  38. new g_pCvarMinCts, g_pCvarMidCts
  39. new g_pCvarStartRoundText, g_pCvarPlanterText
  40.  
  41. new bool:g_bMainSiteSet
  42.  
  43. new szConfigFile[64], g_szMapName[32]
  44. new g_mMainBombSite[BombSites_Datas]
  45. new g_szBombSiteName[16]
  46. new Array:g_aBombSites
  47.  
  48. new Float:g_flCountUntilGameTime
  49. new bool:g_bCountNewSpawns
  50.  
  51. new g_iSyncHud
  52.  
  53. new mp_buytime
  54.  
  55. new gmsgStatusIcon
  56.  
  57. new g_iBombSites_State
  58.  
  59. new g_iC4Carrier
  60.  
  61. public plugin_init()
  62. {
  63. 	new iEnt, mDatas[BombSites_Datas]
  64. 	while( (iEnt = FIND_ENT_BY_CLASSNAME(iEnt, func_bomb_target)) )
  65. 	{
  66. 		if( g_aBombSites == Invalid_Array )
  67. 		{
  68. 			g_aBombSites = ArrayCreate(BombSites_Datas)
  69. 		}
  70.  
  71. 		mDatas[iBsIndex] = iEnt
  72. 		pev(iEnt, pev_model, mDatas[szBsModel], charsmax(mDatas[szBsModel]))
  73. 		ArrayPushString(g_aBombSites, mDatas)
  74. 	}
  75. 	while( (iEnt = FIND_ENT_BY_CLASSNAME(iEnt, info_bomb_target)) )
  76. 	{
  77. 		if( g_aBombSites == Invalid_Array )
  78. 		{
  79. 			g_aBombSites = ArrayCreate(BombSites_Datas)
  80. 		}
  81.  
  82. 		mDatas[iBsIndex] = iEnt
  83. 		pev(iEnt, pev_model, mDatas[szBsModel], charsmax(mDatas[szBsModel]))
  84. 		ArrayPushString(g_aBombSites, mDatas)
  85. 	}
  86.  
  87. 	if( g_aBombSites == Invalid_Array )
  88. 	{
  89. 		register_plugin("c4 management", "NotBombMap", "ConnorMcLeod")
  90. 		pause("ad")
  91. 		return
  92. 	}
  93.  
  94. 	register_plugin("c4 management", VERSION, "ConnorMcLeod")
  95. 	register_dictionary("c4management.txt")
  96.  
  97. 	g_pCvarMinCts = register_cvar("bm_minct", "0")
  98. 	g_pCvarMidCts = register_cvar("bm_midct", "5")
  99. 	g_pCvarStartRoundText = register_cvar("bm_roundstart_text", "2")
  100. 	g_pCvarPlanterText = register_cvar("bm_planter_text", "1")
  101.  
  102. 	get_mapname(g_szMapName, charsmax(g_szMapName))
  103.  
  104. 	get_localinfo("amxx_configsdir", szConfigFile, charsmax(szConfigFile))
  105. 	format(szConfigFile, charsmax(szConfigFile), "%s/bombsites.ini", szConfigFile)
  106. 	if( !file_exists(szConfigFile) )
  107. 	{
  108. 		new iFile = fopen(szConfigFile, "at")
  109. 		fprintf(iFile, "; c4 management configuration file^n")
  110. 		fclose(iFile)
  111. 	}
  112.  
  113. 	g_iMaxPlayers = get_maxplayers()
  114.  
  115. 	GetMainBombSiteByFile()
  116.  
  117. 	register_event("HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0")
  118. 	register_logevent("LogEvent_RoundStart", 2, "1=Round_Start")
  119. 	register_logevent("Logevent_Round_End", 2, "1=Round_End")
  120. 	RegisterHam(Ham_Spawn, "player", "Player_Spawn_Post", 1)
  121.  
  122. 	register_event("WeapPickup", "Event_WeapPickup_c4", "be", "1=6")
  123. 	register_message(get_user_msgid("StatusIcon"), "Message_StatusIcon")
  124.  
  125. 	register_event("BombDrop", "Event_BombDrop", "bc")
  126.  
  127. 	register_event("TextMsg", "Event_TextMsg_C4PlantAtBombSpot", "be", "1=4", "2=#C4_Plant_At_Bomb_Spot")
  128.  
  129. 	register_clcmd("bm_mark_bs", "AdminCommand_MarkBombSite", ADMIN_CFG, " <BombSite Name>")
  130.  
  131. 	g_iSyncHud = CreateHudSyncObj()
  132. 	mp_buytime = get_cvar_pointer("mp_buytime")
  133. 	gmsgStatusIcon = get_user_msgid("StatusIcon")
  134. }
  135.  
  136. GetMainBombSiteByFile()
  137. {
  138. 	new iFile = fopen(szConfigFile, "rt")
  139. 	if( iFile )
  140. 	{
  141. 		new szData[64], szMapname[32], szModel[5], szBombSiteName[16]
  142. 		while( fgets(iFile, szData, charsmax(szData)) )
  143. 		{
  144. 			if( !szData[0] || szData[0] == '/' || szData[0] == ';' || szData[0] == '#' )
  145. 			{
  146. 				continue
  147. 			}
  148.  
  149. 			trim(szData)
  150. 			parse(szData, szMapname, charsmax(szMapname), 
  151. 						szModel, charsmax(szModel), 
  152. 						szBombSiteName, charsmax(szBombSiteName))
  153.  
  154. 			if( equali(szMapname, g_szMapName) )
  155. 			{
  156. 				new iEnt
  157. 				// less efficient than engine but used only at map start
  158. 				iEnt = FIND_ENT_BY_MODELNAME(g_iMaxPlayers, func_bomb_target, szModel)
  159.  
  160. 				if( !iEnt )
  161. 				{
  162. 					iEnt = FIND_ENT_BY_MODELNAME(g_iMaxPlayers, info_bomb_target, szModel)
  163. 				}
  164.  
  165. 				if( iEnt )
  166. 				{
  167. 					g_mMainBombSite[iBsIndex] = iEnt
  168. 					g_mMainBombSite[szBsModel] = szModel
  169. 					remove_quotes(szBombSiteName)
  170. 					g_szBombSiteName = szBombSiteName
  171.  
  172. 					g_bMainSiteSet = true
  173. 				}				
  174. 				break
  175. 			}
  176. 		}
  177. 		fclose(iFile)
  178. 	}
  179. }
  180.  
  181. public plugin_pause()
  182. {
  183. 	new iBombSiteNum = ArraySize(g_aBombSites)
  184. 	new mBombSiteDatas[BombSites_Datas]
  185.  
  186. 	for(new i; i<iBombSiteNum; i++)
  187. 	{
  188. 		ArrayGetArray(g_aBombSites, i, mBombSiteDatas)
  189. 		SetBombSite(mBombSiteDatas[iBsIndex], true)
  190. 	}
  191. }
  192.  
  193. public plugin_end()
  194. {
  195. 	if( g_aBombSites != Invalid_Array )
  196. 	{
  197. 		ArrayDestroy(g_aBombSites)
  198. 	}
  199. }
  200.  
  201. public Event_HLTV_New_Round()
  202. {
  203. 	g_iC4Carrier = 0
  204. 	g_bCountNewSpawns = false
  205. 	g_iBombSites_State = AllSites
  206. }
  207.  
  208. public Event_BombDrop()
  209. {
  210. 	g_iC4Carrier = 0
  211.  
  212. 	if( read_data(4) ) // Bomb Planted
  213. 	{
  214. 		g_bCountNewSpawns = false
  215. 	}
  216. }
  217.  
  218. public Logevent_Round_End()
  219. {
  220. 	g_bCountNewSpawns = false
  221. }
  222.  
  223. public LogEvent_RoundStart()
  224. {
  225. 	g_bCountNewSpawns = true
  226. 	g_flCountUntilGameTime = get_gametime() + get_pcvar_float(mp_buytime) * 60.0
  227.  
  228. 	if(!g_bMainSiteSet)
  229. 	{
  230. 		return
  231. 	}
  232.  
  233. 	CountCounterTerrorists()
  234. }
  235.  
  236. public AdminCommand_MarkBombSite(id, level, cid)
  237. {
  238. 	if( !cmd_access(id, level, cid, 2) )
  239. 	{
  240. 		return PLUGIN_HANDLED
  241. 	}
  242.  
  243. 	if(g_bMainSiteSet)
  244. 	{
  245. 		client_print(id, print_console, "%L", id, "BM_ALREADY")
  246. 		client_cmd(id, "spk buttons/latchlocked1")
  247. 		return PLUGIN_HANDLED
  248. 	}
  249.  
  250. 	new iBombSiteNum = ArraySize(g_aBombSites)
  251.  
  252. 	new mBombSiteDatas[BombSites_Datas], iEnt
  253. 	new Float:fVecOrigin[3], Float:fVecAbsMin[3], Float:fVecAbsMax[3]
  254.  
  255. 	for(new i=0; i<iBombSiteNum; i++)
  256. 	{
  257. 		ArrayGetArray(g_aBombSites, i, mBombSiteDatas)
  258. 		iEnt = mBombSiteDatas[iBsIndex]
  259.  
  260. 		pev(id, pev_origin, fVecOrigin)
  261. 		pev(iEnt, pev_absmin, fVecAbsMin)
  262. 		pev(iEnt, pev_absmax, fVecAbsMax)
  263.  
  264. 		if(	(fVecAbsMin[0] <= fVecOrigin[0] <= fVecAbsMax[0])
  265. 		&&	(fVecAbsMin[1] <= fVecOrigin[1] <= fVecAbsMax[1])
  266. 		&&	(-72.0 <= (((fVecAbsMax[2] + fVecAbsMin[2]) / 2.0) - fVecOrigin[2]) <= 72.0)	)
  267. 		{
  268. 			read_argv(1, g_szBombSiteName, charsmax(g_szBombSiteName))
  269. 			new iFile = fopen(szConfigFile, "at")
  270. 			fprintf(iFile, "^n%s %s ^"%s^"", g_szMapName, mBombSiteDatas[szBsModel], g_szBombSiteName)
  271. 			fclose(iFile)
  272.  
  273. 			g_mMainBombSite = mBombSiteDatas
  274. 			g_bMainSiteSet = true
  275.  
  276. 			client_print(id, print_console, "%L", id, "BM_DEFINED")
  277. 			client_cmd(id, "spk events/task_complete")
  278. 			return PLUGIN_HANDLED
  279. 		}
  280. 	}
  281.  
  282. 	client_print(id, print_console, "%L", id, "BM_NOTBOMBSITE")
  283. 	client_cmd(id, "spk events/friend_died")
  284. 	return PLUGIN_HANDLED
  285. }
  286.  
  287. public Event_WeapPickup_c4( id )
  288. {
  289. 	g_iC4Carrier = id
  290. }
  291.  
  292. public Message_StatusIcon(/*iMsgId, iMsgDest, id*/)
  293. {
  294. 	if( g_iBombSites_State != AllSites && get_msg_arg_int(1) == StatusIconShow )
  295. 	{
  296. 		new szIcon[4]
  297. 		get_msg_arg_string(2, szIcon, charsmax(szIcon))
  298. 		if(	get_msg_arg_string(2, szIcon, charsmax(szIcon)) == 2 // check "c4" length first
  299. 		&&	equal(szIcon, "c4")	)
  300. 		{
  301. 			switch( g_iBombSites_State )
  302. 			{
  303. 				case NoSite:
  304. 				{
  305. 					set_msg_arg_int(1, ARG_BYTE, 0)
  306. 				}
  307. 				case MainSite:
  308. 				{
  309. 					set_msg_arg_int(3, ARG_BYTE, 200)
  310. 					set_msg_arg_int(4, ARG_BYTE, 100)
  311. 				}
  312. 			}
  313. 		}
  314. 	}
  315. }
  316.  
  317. public Event_TextMsg_C4PlantAtBombSpot(id)
  318. {
  319. 	if( !get_pcvar_num(g_pCvarPlanterText) )
  320. 	{
  321. 		return
  322. 	}
  323.  
  324. 	new iBombSiteNum = ArraySize(g_aBombSites)
  325.  
  326. 	new mBombSiteDatas[BombSites_Datas], iEnt
  327. 	new Float:fVecOrigin[3], Float:fVecAbsMin[3], Float:fVecAbsMax[3]
  328.  
  329. 	for(new i=0; i<iBombSiteNum; i++)
  330. 	{
  331. 		ArrayGetArray(g_aBombSites, i, mBombSiteDatas)
  332. 		iEnt = mBombSiteDatas[iBsIndex]
  333.  
  334. 		pev(id, pev_origin, fVecOrigin)
  335. 		pev(iEnt, pev_absmin, fVecAbsMin)
  336. 		pev(iEnt, pev_absmax, fVecAbsMax)
  337.  
  338. 		if(	(fVecAbsMin[0] <= fVecOrigin[0] <= fVecAbsMax[0])
  339. 		&&	(fVecAbsMin[1] <= fVecOrigin[1] <= fVecAbsMax[1])
  340. 		&&	(-72.0 <= (((fVecAbsMax[2] + fVecAbsMin[2]) / 2.0) - fVecOrigin[2]) <= 72.0)	)
  341. 		{
  342. 			switch( g_iBombSites_State )
  343. 			{
  344. 				case NoSite:
  345. 				{
  346. 					client_print(id, print_center, "%L", id, "BM_AD_NOPLANT", get_pcvar_num(g_pCvarMinCts))
  347. 				}
  348. 				case MainSite:
  349. 				{
  350. 					client_print(id, print_center, "%L", id, "BM_AD_ONLYMAIN", 
  351. 											get_pcvar_num(g_pCvarMidCts), g_szBombSiteName)
  352. 				}
  353. 			}
  354.  
  355. 			break
  356. 		}
  357. 	}
  358. }
  359.  
  360. public Player_Spawn_Post(id)
  361. {
  362. 	if(	g_bMainSiteSet
  363. 	&&	g_bCountNewSpawns
  364. 	&&	is_user_alive(id)
  365. 	&&	cs_get_user_team_index(id) == CS_TEAM_CT	)
  366. 	{
  367. 		if( g_flCountUntilGameTime < get_gametime() )
  368. 		{
  369. 			g_bCountNewSpawns = false
  370. 			return
  371. 		}
  372. 		CountCounterTerrorists()
  373. 	}
  374. }
  375.  
  376. CountCounterTerrorists()
  377. {
  378. 	new iPlayers[MAX_PLAYERS], iNum, iCtNum
  379. 	get_players(iPlayers, iNum, "h")
  380.  
  381. 	for(new i; i<iNum; i++)
  382. 	{
  383. 		if( cs_get_user_team_index(iPlayers[i]) == CS_TEAM_CT )
  384. 		{
  385. 			iCtNum++
  386. 		}
  387. 	}
  388.  
  389. 	new iMinCts = get_pcvar_num(g_pCvarMinCts)
  390. 	new iMidCts = get_pcvar_num(g_pCvarMidCts)
  391.  
  392. 	new const szTag[] = "C4 Management"
  393.  
  394. 	new iBombSiteNum = ArraySize(g_aBombSites)
  395. 	new mBombSiteDatas[BombSites_Datas]
  396.  
  397. 	if( iCtNum < iMinCts)
  398. 	{
  399. 		switch( get_pcvar_num(g_pCvarStartRoundText) )
  400. 		{
  401. 			case 1:
  402. 			{
  403. 				client_print(0, print_chat, "* [%s] %L", szTag, LANG_PLAYER, "BM_AD_NOPLANT", iMinCts)
  404. 			}
  405. 			case 2:
  406. 			{
  407. 				set_hudmessage(200, 50, 50, -1.0, 0.15, .holdtime=8.0, .channel=-1)
  408. 				ShowSyncHudMsg(0, g_iSyncHud, "%s : %L", szTag, LANG_PLAYER, "BM_AD_NOPLANT", iMinCts)
  409. 			}
  410. 		}
  411.  
  412. 		for(new i; i<iBombSiteNum; i++)
  413. 		{
  414. 			ArrayGetArray(g_aBombSites, i, mBombSiteDatas)
  415. 			SetBombSite(mBombSiteDatas[iBsIndex], false)
  416. 		}
  417.  
  418. 		g_iBombSites_State = NoSite
  419. 		if( g_iC4Carrier )
  420. 		{
  421. 			Send_StatusIcon_c4(g_iC4Carrier)
  422. 		}
  423. 	}
  424. 	else if( iCtNum < iMidCts)
  425. 	{
  426. 		switch( get_pcvar_num(g_pCvarStartRoundText) )
  427. 		{
  428. 			case 1:
  429. 			{
  430. 				client_print(0, print_chat, "* [%s] %L", szTag, LANG_PLAYER, "BM_AD_ONLYMAIN", iMidCts, g_szBombSiteName)
  431. 			}
  432. 			case 2:
  433. 			{
  434. 				set_hudmessage(0, 255, 0, -1.0, 0.15, .holdtime=8.0, .channel=-1)
  435. 				ShowSyncHudMsg(0, g_iSyncHud, "%s : %L", szTag, LANG_PLAYER, "BM_AD_ONLYMAIN", iMidCts, g_szBombSiteName)
  436. 			}
  437. 		}
  438.  
  439. 		new iEnt
  440. 		for(new i; i<iBombSiteNum; i++)
  441. 		{
  442. 			ArrayGetArray(g_aBombSites, i, mBombSiteDatas)
  443. 			iEnt = mBombSiteDatas[iBsIndex]
  444. 			SetBombSite(iEnt, iEnt == g_mMainBombSite[iBsIndex] ? true : false)
  445. 		}
  446.  
  447. 		g_iBombSites_State = MainSite
  448. 		if( g_iC4Carrier )
  449. 		{
  450. 			Send_StatusIcon_c4(g_iC4Carrier, StatusIconShow, 200, 100, 0)
  451. 		}
  452. 	}
  453. 	else
  454. 	{
  455. 		switch( get_pcvar_num(g_pCvarStartRoundText) )
  456. 		{
  457. 			case 1:
  458. 			{
  459. 				client_print(0, print_chat, "* [%s] %L", szTag, LANG_PLAYER, "BM_AD_ALLSITES")
  460. 			}
  461. 			case 2:
  462. 			{
  463. 				set_hudmessage(50, 200, 50, -1.0, 0.15, .holdtime=8.0, .channel=-1)
  464. 				ShowSyncHudMsg(0, g_iSyncHud, "%s : %L", szTag, LANG_PLAYER, "BM_AD_ALLSITES")
  465. 			}
  466. 		}
  467.  
  468. 		for(new i; i<iBombSiteNum; i++)
  469. 		{
  470. 			ArrayGetArray(g_aBombSites, i, mBombSiteDatas)
  471. 			SetBombSite(mBombSiteDatas[iBsIndex], true)
  472. 		}
  473.  
  474. 		g_iBombSites_State = AllSites
  475. 		if( g_iC4Carrier )
  476. 		{
  477. 			Send_StatusIcon_c4(g_iC4Carrier, StatusIconShow, 0, 160, 0)
  478. 		}
  479. 	}
  480. }
  481.  
  482. SetBombSite(iEnt, bool:bActive)
  483. {
  484. 	set_pev(iEnt, pev_solid, bActive ? SOLID_TRIGGER : SOLID_NOT)
  485. }
  486.  
  487. Send_StatusIcon_c4(id, Mode=StatusIconDontShow, r=0, g=0, b=0)
  488. {
  489. 	message_begin(MSG_ONE_UNRELIABLE, gmsgStatusIcon, .player=id)
  490. 	write_byte(Mode)
  491. 	write_string("c4")
  492. 	if( Mode )
  493. 	{
  494. 		write_byte(r)
  495. 		write_byte(g)
  496. 		write_byte(b)
  497. 	}
  498. 	message_end()
  499. }
  500.  
  501. FIND_ENT_BY_MODELNAME(const iStartEnt, const szClassName[], const szModel[])
  502. {
  503. 	new iEnt = iStartEnt
  504. 	new szMdl[72]
  505. 	while( (iEnt = FIND_ENT_BY_CLASSNAME(iEnt, szClassName)) )
  506. 	{
  507. 		pev(iEnt, pev_model, szMdl, charsmax(szMdl))
  508. 		if( equal(szMdl, szModel) )
  509. 		{
  510. 			return iEnt
  511. 		}
  512. 	}
  513. 	return 0
  514. }

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Nandee
HozzászólásElküldve:2013.07.22. 00:08 
Offline
Félisten
Avatar

Csatlakozott:2010.09.16. 20:57
Hozzászólások:950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
SMA Forráskód: [ Mindet kijelol ]
  1. set_fail_state("Itt meglehet adni hibaüzenetet")

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
expert
HozzászólásElküldve:2013.07.22. 06:01 
Offline
Őstag
Avatar

Csatlakozott:2010.04.16. 16:50
Hozzászólások:1342
Megköszönt másnak: 42 alkalommal
Megköszönték neki: 58 alkalommal
Nandee írta:
SMA Forráskód: [ Mindet kijelol ]
  1. set_fail_state("Itt meglehet adni hibaüzenetet")

Bocsi de ha nem igy van javíts ki de ez a parancs s zervert állitja le nem a plugint nem ? csak mert silverss plugin megvédése tutorial ban is ez a parancs van és az a szervertt állítja le :-) na meg a másik az, hogy én ebben a kodban nem l.átnám hogy benne lenne ez

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
kiki
HozzászólásElküldve:2013.07.22. 08:11 
Offline
Developer
Avatar

Csatlakozott:2011.06.01. 21:11
Hozzászólások:7966
Megköszönt másnak: 295 alkalommal
Megköszönték neki: 537 alkalommal
Nem, ez nincs benne a kódba, a plugint az elején állítja le, miután ellenőrizte hogy van e bombalerakó.

SMA Forráskód: [ Mindet kijelol ]
  1. 	if( g_aBombSites == Invalid_Array )
  2. 	{
  3. 		register_plugin("c4 management", "NotBombMap", "ConnorMcLeod")
  4. 		pause("ad")
  5. 		return
  6.                //Jól látható hogy itt más "verziót" kap a plugin, ha megnézed akkor ha a:
  7. }


Plugin fut:
Kód:
c4 management           0.2.7  ConnorMcLeod      c4_management.a  running


Plugin nem fut
Kód:
c4 management           NotBombMap  ConnorMcLeod      c4_management.a  stopped


Egyszóval ha már el sem indul a plugin, más verziószámmal regisztrálja.

_________________
http://www.easyrankup.eu


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Nandee
HozzászólásElküldve:2013.07.22. 10:10 
Offline
Félisten
Avatar

Csatlakozott:2010.09.16. 20:57
Hozzászólások:950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
expert írta:
Nandee írta:
SMA Forráskód: [ Mindet kijelol ]
  1. set_fail_state("Itt meglehet adni hibaüzenetet")

Bocsi de ha nem igy van javíts ki de ez a parancs s zervert állitja le nem a plugint nem ? csak mert silverss plugin megvédése tutorial ban is ez a parancs van és az a szervertt állítja le :-) na meg a másik az, hogy én ebben a kodban nem l.átnám hogy benne lenne ez

A c4-es plugint azt csak példának írtad, a plugin megállításra kerestél megoldást ha jól értelmeztem :)

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
expert
HozzászólásElküldve:2013.07.22. 18:33 
Offline
Őstag
Avatar

Csatlakozott:2010.04.16. 16:50
Hozzászólások:1342
Megköszönt másnak: 42 alkalommal
Megköszönték neki: 58 alkalommal
értem kiki és köszi.
Nandee: De még mindíg nem jót adtál akkor mivel a parancs az az egész szervert leállítja nem ??
ebből is gondolom meg tudom--> Hogyan védd meg a pluginodat/mododat?

ui: szóval ha én pl egy maphoz szeretném használni akkor szerinted jó lessz kiki ?
Így gondoltam valahogy (az alltalk csak példa):
SMA Forráskód: [ Mindet kijelol ]
  1. 	public plugin_init() 
  2. {
  3. 	if(get_cvar_num("sv_alltalk")==1)
  4. 	{
  5. 		pause("ad")
  6. 		return
  7.     }
  8. }

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Nandee
HozzászólásElküldve:2013.07.23. 04:44 
Offline
Félisten
Avatar

Csatlakozott:2010.09.16. 20:57
Hozzászólások:950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
expert írta:
értem kiki és köszi.
Nandee: De még mindíg nem jót adtál akkor mivel a parancs az az egész szervert leállítja nem ??
ebből is gondolom meg tudom--> Hogyan védd meg a pluginodat/mododat?

ui: szóval ha én pl egy maphoz szeretném használni akkor szerinted jó lessz kiki ?
Így gondoltam valahogy (az alltalk csak példa):
SMA Forráskód: [ Mindet kijelol ]
  1. 	public plugin_init() 
  2. {
  3. 	if(get_cvar_num("sv_alltalk")==1)
  4. 	{
  5. 		pause("ad")
  6. 		return
  7.     }
  8. }

hidd el hogy arra való, ott sem a szervert állítja le csak a plugin-t, szerintem a kód az jó ha így nem menne akkor hasznlj get_cvar_pointer-t (valószínű így is jó lesz).

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
kiki
HozzászólásElküldve:2013.07.23. 07:56 
Offline
Developer
Avatar

Csatlakozott:2011.06.01. 21:11
Hozzászólások:7966
Megköszönt másnak: 295 alkalommal
Megköszönték neki: 537 alkalommal
Ha csak egy mapon akarod használni, akkor jobb a mapot leellenőrizni. Mellesleg a set_fail_state-t én egyszer használtam, de nekem sem állította le a szervert.

_________________
http://www.easyrankup.eu


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
expert
HozzászólásElküldve:2013.07.23. 08:23 
Offline
Őstag
Avatar

Csatlakozott:2010.04.16. 16:50
Hozzászólások:1342
Megköszönt másnak: 42 alkalommal
Megköszönték neki: 58 alkalommal
persze ha mapra akarom használni akkor lekérem a mapot majd, kipróbálom akkor és majd kiderűl :-)

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólás az előzmény idézésével  
Hozzászólások megjelenítése: Rendezés 
Új téma nyitása Hozzászólás a témához  Oldal: 1 / 1
  [9 hozzászólás ] 

» » »


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 10 vendég

Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole