hlmod.hu

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fakemeta_util>
#include <hamsandwich>
#include <cstrike>
 
 
#define PLUGIN "[ZP] Extra Item: AT4CS"
#define VERSION "1.0"
#define AUTHOR "Dias"
 
#define weapon_at4cs "weapon_m249"
#define CSW_AT4CS CSW_M249
 
#define TASK_CHECKRELOAD 111112
#define TASK_RELOAD 111113
 
 
new g_had_at4cs[33], Float:g_lastfire[33], Float:g_lastaim[33], g_aiming[33],
g_smoke_id, g_spr_trail, g_spr_exp, is_reloading[33],
cvar_radius, cvar_maxdamage
 
new const v_model[] = "models/zombie_plague/v_at4ex.mdl"
new const p_model[] = "models/zombie_plague/p_at4ex.mdl"
new const w_model[] = "models/zombie_plague/w_at4ex.mdl"
new const s_model[] = "models/zombie_plague/s_rocket.mdl"
 
new const at4cs_sound[5][] = {
	"weapons/at4-1.wav", // Fire Sound
	"weapons/at4_clipin1.wav", // Clip in 1
	"weapons/at4_clipin2.wav", // Clip in 2
	"weapons/at4_clipin3.wav", // Clip in 3
	"weapons/at4_draw.wav"  // Draw
}
 
public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
 
	register_event("CurWeapon", "event_curweapon", "be", "1=1")
	register_event("HLTV", "event_newround", "a", "1=0", "2=0")
 
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
	register_forward(FM_CmdStart, "fw_CmdStart")
	register_forward(FM_SetModel, "fw_SetModel")
 
	register_think("at4ex_rocket", "fw_rocket_think")
	register_touch("at4ex_rocket", "*", "fw_rocket_touch")
 
	RegisterHam(Ham_Weapon_Reload, weapon_at4cs, "fw_WeaponReload")
	RegisterHam(Ham_Item_AddToPlayer, weapon_at4cs, "fw_AddToPlayer", 1)
 
	cvar_radius = register_cvar("zp_at4cs_radius", "400.0")
	cvar_maxdamage = register_cvar("zp_at4cs_maxdamage", "1250.0")
	register_clcmd("say /fegyver", "addweap")
	register_clcmd("weapon_at4cs", "hook_weapon")
}
 
public hook_weapon(id)
{
	engclient_cmd(id, weapon_at4cs)
	return PLUGIN_HANDLED
}
 
public plugin_precache()
{
	engfunc(EngFunc_PrecacheModel, v_model)
	engfunc(EngFunc_PrecacheModel, p_model)
	engfunc(EngFunc_PrecacheModel, w_model)
	engfunc(EngFunc_PrecacheModel, s_model)
 
	engfunc(EngFunc_PrecacheGeneric, "sprites/weapon_at4cs.txt")
	engfunc(EngFunc_PrecacheGeneric, "sprites/at4cs.spr")	
 
	g_smoke_id = engfunc(EngFunc_PrecacheModel, "sprites/effects/rainsplash.spr")
	g_spr_trail = engfunc(EngFunc_PrecacheModel,"sprites/xbeam3.spr")
	g_spr_exp = engfunc(EngFunc_PrecacheModel,"sprites/zerogxplode.spr")
 
	for(new i = 0; i < sizeof(at4cs_sound); i++)
		engfunc(EngFunc_PrecacheSound, at4cs_sound[i])
}
 
public addweap(id)
{
 
	g_had_at4cs[id] = 1
	is_reloading[id] = 0
	g_aiming[id] = 0
 
	fm_give_item(id, weapon_at4cs)
 
	static at4cs
	at4cs = fm_get_user_weapon_entity(id, CSW_AT4CS)
 
	cs_set_weapon_ammo(at4cs, 1)
	cs_set_user_bpammo(id, CSW_AT4CS, 10)
 
	return PLUGIN_CONTINUE
}
public event_newround()
{
	remove_entity_name("at4ex_rocket")
 
	for(new i = 0; i < get_maxplayers(); i++)
	{
		if(is_user_alive(i) && is_user_connected(i))
		{
			remove_task(i+TASK_CHECKRELOAD)
			remove_task(i+TASK_RELOAD)	
		}
	}
}
 
public event_curweapon(id)
{
	if(!is_user_alive(id) || !is_user_connected(id))
		return PLUGIN_HANDLED
 
	set_pev(id, pev_viewmodel2, v_model)
	set_pev(id, pev_weaponmodel2, p_model)
 
	return PLUGIN_CONTINUE
}
 
public fw_UpdateClientData_Post(id, sendweapons, cd_handle)
{
	if(!is_user_alive(id) || !is_user_connected(id))
		return FMRES_IGNORED
 
	if(get_user_weapon(id) != CSW_AT4CS || !g_had_at4cs[id])
		return FMRES_IGNORED
 
	set_cd(cd_handle, CD_flNextAttack, halflife_time() + 0.001)  
 
	return FMRES_HANDLED
}
 
public fw_AddToPlayer(ent, id)
{
	if(!is_valid_ent(ent) || !is_user_alive(id))
		return HAM_IGNORED
 
	if(entity_get_int(ent, EV_INT_impulse) == 61296)
	{
		g_had_at4cs[id] = 1
		entity_set_int(id, EV_INT_impulse, 0)
 
		return HAM_HANDLED
	}		
 
	if(g_had_at4cs[id])
	{
		message_begin(MSG_ONE, get_user_msgid("WeaponList"), _, id)
		write_string("weapon_at4cs");    // WeaponName
		write_byte(3)                  // PrimaryAmmoID
		write_byte(1)                  // PrimaryAmmoMaxAmount
		write_byte(-1)                   // SecondaryAmmoID
		write_byte(-1)                   // SecondaryAmmoMaxAmount
		write_byte(0)                    // SlotID (0...N)
		write_byte(4)                    // NumberInSlot (1...N)
		write_byte(CSW_AT4CS)            // WeaponID
		write_byte(0)                   // Flags
		message_end()
	}
 
	return HAM_HANDLED	
}
 
public fw_CmdStart(id, uc_handle, seed)
{
	if(!is_user_alive(id) || !is_user_connected(id))
		return FMRES_IGNORED
 
	if(get_user_weapon(id) != CSW_AT4CS || !g_had_at4cs[id])
		return FMRES_IGNORED
 
 
	static CurButton
	CurButton = get_uc(uc_handle, UC_Buttons)
 
	if(CurButton & IN_ATTACK)
	{
		static Float:CurTime
		CurTime = get_gametime()
 
		static at4cs
		at4cs = fm_find_ent_by_owner(-1, weapon_at4cs, id)		
 
		if(cs_get_weapon_ammo(at4cs) > 0 && !is_reloading[id])
		{
			if(CurTime - 4.5 > g_lastfire[id])
			{
				set_weapon_anim(id, 1)
				emit_sound(id, CHAN_WEAPON, at4cs_sound[0], 1.0, ATTN_NORM, 0, PITCH_NORM)
 
				create_rocket(id)
 
				static Float:Punch_Angles[3]
 
				Punch_Angles[0] = -20.0
				Punch_Angles[1] = 0.0
				Punch_Angles[2] = 0.0
 
				set_pev(id, pev_punchangle, Punch_Angles)
				cs_set_weapon_ammo(at4cs, cs_get_weapon_ammo(at4cs) - 1)
 
				if(cs_get_weapon_ammo(at4cs) <= 0 && !is_reloading[id])
				{
					if(cs_get_user_bpammo(id, CSW_AT4CS) > 0)
					{
						set_task(1.0, "at4cs_reload", id)
					}
				}
 
				if(cs_get_user_zoom(id))
					cs_set_user_zoom(id, CS_RESET_ZOOM, 1)
 
				g_lastfire[id] = CurTime
			}
		} else {
			if(!is_reloading[id])
			{
				if(cs_get_user_bpammo(id, CSW_AT4CS) > 0)
				{
					if(CurTime - 1.0 > g_lastfire[id])
					{
						at4cs_reload(id)
						g_lastfire[id] = CurTime
					}
				}
			}
		}
	}
 
	if(CurButton & IN_ATTACK2)
	{
		static Float:CurTime
		CurTime = get_gametime()
 
		if((CurTime - 0.5 > g_lastaim[id]) && !is_reloading[id])
		{
			if(!g_aiming[id])
			{
				cs_set_user_zoom(id, CS_SET_FIRST_ZOOM, 1)
				g_aiming[id] = 1
			} else {
				cs_set_user_zoom(id, CS_RESET_ZOOM, 1)
				g_aiming[id] = 0
			}
 
			g_lastaim[id] = CurTime
		}
	}
 
	CurButton &= ~IN_ATTACK
	set_uc(uc_handle, UC_Buttons, CurButton)
 
	CurButton &= ~IN_RELOAD
	set_uc(uc_handle, UC_Buttons, CurButton)
 
	return FMRES_HANDLED
}
 
public fw_SetModel(ent, const model[])
{
	if(!is_valid_ent(ent))
		return FMRES_IGNORED
 
	static szClassName[33]
	entity_get_string(ent, EV_SZ_classname, szClassName, charsmax(szClassName))
 
	if(!equal(szClassName, "weaponbox"))
		return FMRES_IGNORED
 
	static iOwner
	iOwner = entity_get_edict(ent, EV_ENT_owner)
 
	if(equal(model, "models/w_m249.mdl"))
	{
		static at4cs
		at4cs = find_ent_by_owner(-1, "weapon_m249", ent)
 
		if(!is_valid_ent(at4cs))
			return FMRES_IGNORED;
 
		if(g_had_at4cs[iOwner])
		{
			entity_set_int(at4cs, EV_INT_impulse, 61296)
			g_had_at4cs[iOwner] = 0
			entity_set_model(ent, w_model)
 
			return FMRES_SUPERCEDE
		}
	}
 
	return FMRES_IGNORED
}
 
public at4cs_reload(id)
{
	if(is_reloading[id])
		return
 
	is_reloading[id] = 1
	set_weapon_anim(id, 3)
 
	set_task(0.1, "checking_reload", id+TASK_CHECKRELOAD, _, _, "b")
	set_task(4.0, "reload_complete", id+TASK_RELOAD)
}
 
public checking_reload(id)
{
	id -= TASK_CHECKRELOAD
 
	if(cs_get_user_zoom(id))
		cs_set_user_zoom(id, CS_RESET_ZOOM, 1)	
 
	if(get_user_weapon(id) != CSW_AT4CS || !g_had_at4cs[id])
	{
		remove_task(id+TASK_CHECKRELOAD)
		remove_task(id+TASK_RELOAD)
 
		is_reloading[id] = 0
	}
}
 
public reload_complete(id)
{
	id -= TASK_RELOAD
 
	if(!is_reloading[id])
		return
 
	remove_task(id+TASK_CHECKRELOAD)	
 
	static at4cs
	at4cs = fm_find_ent_by_owner(-1, weapon_at4cs, id)	
 
	cs_set_weapon_ammo(at4cs, 1)
	cs_set_user_bpammo(id, CSW_AT4CS, cs_get_user_bpammo(id, CSW_AT4CS) - 1)
	is_reloading[id] = 0
}
 
public fw_WeaponReload(ent)
{
	static id
	id = pev(ent, pev_owner)
 
	if(!is_user_alive(id) || !is_user_connected(id))
		return HAM_IGNORED
 
	if(get_user_weapon(id) != CSW_AT4CS || !g_had_at4cs[id])
		return HAM_IGNORED
 
	static Float:CurTime
	CurTime = get_gametime()		
 
	if(!is_reloading[id])
	{
		if(cs_get_user_bpammo(id, CSW_AT4CS) > 0)
		{
			if(CurTime - 1.0 > g_lastfire[id])
			{
				at4cs_reload(id)
				g_lastfire[id] = CurTime
			}
		}
	}	
 
	return HAM_SUPERCEDE
}
 
public create_rocket(id)
{
	new ent, Float:Origin[3], Float:Angles[3], Float:Velocity[3]
 
	ent = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))
	engfunc(EngFunc_GetAttachment, id, 0, Origin, Angles)
	pev(id, pev_angles, Angles)
 
	set_pev(ent, pev_origin, Origin)
	set_pev(ent, pev_angles, Angles)
	set_pev(ent, pev_solid, 2)
	set_pev(ent, pev_movetype, 5)
	set_pev(ent, pev_classname, "at4ex_rocket")
	set_pev(ent, pev_owner, id)
	engfunc(EngFunc_SetModel, ent, s_model)
 
	set_pev(ent, pev_mins, {-1.0, -1.0, -1.0})
	set_pev(ent, pev_maxs, {1.0, 1.0, 1.0})
 
	velocity_by_aim(id, 1750, Velocity)
	set_pev(ent, pev_velocity, Velocity)
 
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_BEAMFOLLOW) // TE id
	write_short(ent) // entity:attachment to follow
	write_short(g_spr_trail) // sprite index
	write_byte(25) // life in 0.1's
	write_byte(2) // line width in 0.1's
	write_byte(255) // r
	write_byte(255) // g
	write_byte(255) // b
	write_byte(200) // brightness
	message_end()	
 
	set_pev(ent, pev_iuser4, 0)
	set_pev(ent, pev_nextthink, halflife_time() + 0.1)
}
 
public fw_rocket_think(ent)
{
	if(!pev_valid(ent))
		return
 
	static Float:Origin[3]
	pev(ent, pev_origin, Origin)
 
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_SPRITE)
	engfunc(EngFunc_WriteCoord, Origin[0])
	engfunc(EngFunc_WriteCoord, Origin[1])
	engfunc(EngFunc_WriteCoord, Origin[2])
	write_short(g_smoke_id) 
	write_byte(2) 
	write_byte(200)
	message_end()
 
	if(pev(ent, pev_iuser4) == 0)
	{
		static Victim
		Victim = FindClosesEnemy(ent)
 
		if(is_user_alive(Victim))
		{
			set_pev(ent, pev_iuser4, Victim)
		}
	} else {
		static Victim
		Victim = pev(ent, pev_iuser4)
 
		if(is_user_alive(Victim))
		{
			static Float:VicOrigin[3]
			pev(Victim, pev_origin, VicOrigin)
 
			turn_to_target(ent, Origin, Victim, VicOrigin)
			hook_ent(ent, Victim, 500.0)
		} else {
			set_pev(ent, pev_iuser4, 0)
		}
	}
 
	set_pev(ent, pev_nextthink, halflife_time() + 0.075)
}
 
public fw_rocket_touch(rocket, touch)
{
	if(!pev_valid(rocket))
		return	
 
	if(is_user_alive(touch) && pev(rocket, pev_owner) == touch)
		return
 
	static Float:Origin[3]
	pev(rocket, pev_origin, Origin)		
 
	message_begin(MSG_BROADCAST ,SVC_TEMPENTITY)
	write_byte(TE_EXPLOSION)
	engfunc(EngFunc_WriteCoord, Origin[0])
	engfunc(EngFunc_WriteCoord, Origin[1])
	engfunc(EngFunc_WriteCoord, Origin[2])
	write_short(g_spr_exp)	// sprite index
	write_byte(20)	// scale in 0.1's
	write_byte(30)	// framerate
	write_byte(0)	// flags
	message_end()
 
	static owner, iVictim
 
	iVictim = -1
	owner = pev(rocket, pev_owner)	
 
	while((iVictim = find_ent_in_sphere(iVictim, Origin, get_pcvar_float(cvar_radius))) != 0)
	{
		if((0 < iVictim < 32) && is_user_alive(iVictim)
		&& iVictim != owner)
		{
			new Float:MaxDamage, Float:Damage
 
			MaxDamage = get_pcvar_float(cvar_maxdamage)
			Damage = random_float(MaxDamage - random_float(0.0, 100.0), MaxDamage + random_float(0.0, 100.0))
 
			ExecuteHam(Ham_TakeDamage, iVictim, 0, owner, 0, DMG_BULLET)
 
			static health
			health = get_user_health(iVictim)
 
			if(health - Damage >= 1)
			{
				fm_set_user_health(iVictim, health - floatround(Damage))
			}
			else
			{
				death_message(owner, iVictim, 1)
			}			
		}
	}	
 
	engfunc(EngFunc_RemoveEntity, rocket)
}
 
stock set_weapon_anim(id, anim)
{
	set_pev(id, pev_weaponanim, anim)
 
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, _, id)
	write_byte(anim)
	write_byte(pev(id,pev_body))
	message_end()
}
 
stock death_message(Killer, Victim, ScoreBoard)
{
	// Block death msg
	set_msg_block(get_user_msgid("DeathMsg"), BLOCK_SET)
	ExecuteHamB(Ham_Killed, Victim, Killer, 2)
	set_msg_block(get_user_msgid("DeathMsg"), BLOCK_NOT)
 
	// Death
	make_deathmsg(Killer, Victim, 0, "")
 
	// Update score board
	if (ScoreBoard)
	{
		message_begin(MSG_BROADCAST, get_user_msgid("ScoreInfo"))
		write_byte(Killer) // id
		write_short(pev(Killer, pev_frags)) // frags
		write_short(cs_get_user_deaths(Killer)) // deaths
		write_short(0) // class?
		write_short(get_user_team(Killer)) // team
		message_end()
 
		message_begin(MSG_BROADCAST, get_user_msgid("ScoreInfo"))
		write_byte(Victim) // id
		write_short(pev(Victim, pev_frags)) // frags
		write_short(cs_get_user_deaths(Victim)) // deaths
		write_short(0) // class?
		write_short(get_user_team(Victim)) // team
		message_end()
	}
}
 
stock FindClosesEnemy(entid)
{
	new Float:Dist
	new Float:maxdistance=300.0
	new indexid=0	
	for(new i=1;i<=get_maxplayers();i++){
		if(is_user_alive(i) && is_valid_ent(i) && can_see_fm(entid, i)
		&& pev(entid, pev_owner) != i && cs_get_user_team(pev(entid, pev_owner)) != cs_get_user_team(i))
		{
			Dist = entity_range(entid, i)
			if(Dist <= maxdistance)
			{
				maxdistance=Dist
				indexid=i
 
				return indexid
			}
		}	
	}	
	return 0
}
 
stock bool:can_see_fm(entindex1, entindex2)
{
	if (!entindex1 || !entindex2)
		return false
 
	if (pev_valid(entindex1) && pev_valid(entindex1))
	{
		new flags = pev(entindex1, pev_flags)
		if (flags & EF_NODRAW || flags & FL_NOTARGET)
		{
			return false
		}
 
		new Float:lookerOrig[3]
		new Float:targetBaseOrig[3]
		new Float:targetOrig[3]
		new Float:temp[3]
 
		pev(entindex1, pev_origin, lookerOrig)
		pev(entindex1, pev_view_ofs, temp)
		lookerOrig[0] += temp[0]
		lookerOrig[1] += temp[1]
		lookerOrig[2] += temp[2]
 
		pev(entindex2, pev_origin, targetBaseOrig)
		pev(entindex2, pev_view_ofs, temp)
		targetOrig[0] = targetBaseOrig [0] + temp[0]
		targetOrig[1] = targetBaseOrig [1] + temp[1]
		targetOrig[2] = targetBaseOrig [2] + temp[2]
 
		engfunc(EngFunc_TraceLine, lookerOrig, targetOrig, 0, entindex1, 0) //  checks the had of seen player
		if (get_tr2(0, TraceResult:TR_InOpen) && get_tr2(0, TraceResult:TR_InWater))
		{
			return false
		} 
		else 
		{
			new Float:flFraction
			get_tr2(0, TraceResult:TR_flFraction, flFraction)
			if (flFraction == 1.0 || (get_tr2(0, TraceResult:TR_pHit) == entindex2))
			{
				return true
			}
			else
			{
				targetOrig[0] = targetBaseOrig [0]
				targetOrig[1] = targetBaseOrig [1]
				targetOrig[2] = targetBaseOrig [2]
				engfunc(EngFunc_TraceLine, lookerOrig, targetOrig, 0, entindex1, 0) //  checks the body of seen player
				get_tr2(0, TraceResult:TR_flFraction, flFraction)
				if (flFraction == 1.0 || (get_tr2(0, TraceResult:TR_pHit) == entindex2))
				{
					return true
				}
				else
				{
					targetOrig[0] = targetBaseOrig [0]
					targetOrig[1] = targetBaseOrig [1]
					targetOrig[2] = targetBaseOrig [2] - 17.0
					engfunc(EngFunc_TraceLine, lookerOrig, targetOrig, 0, entindex1, 0) //  checks the legs of seen player
					get_tr2(0, TraceResult:TR_flFraction, flFraction)
					if (flFraction == 1.0 || (get_tr2(0, TraceResult:TR_pHit) == entindex2))
					{
						return true
					}
				}
			}
		}
	}
	return false
}
 
stock turn_to_target(ent, Float:Ent_Origin[3], target, Float:Vic_Origin[3]) 
{
	if(target) 
	{
		new Float:newAngle[3]
		entity_get_vector(ent, EV_VEC_angles, newAngle)
		new Float:x = Vic_Origin[0] - Ent_Origin[0]
		new Float:z = Vic_Origin[1] - Ent_Origin[1]
 
		new Float:radians = floatatan(z/x, radian)
		newAngle[1] = radians * (180 / 3.14)
		if (Vic_Origin[0] < Ent_Origin[0])
			newAngle[1] -= 180.0
 
		entity_set_vector(ent, EV_VEC_angles, newAngle)
	}
}
 
stock hook_ent(ent, victim, Float:speed)
{
	static Float:fl_Velocity[3]
	static Float:VicOrigin[3], Float:EntOrigin[3]
 
	pev(ent, pev_origin, EntOrigin)
	pev(victim, pev_origin, VicOrigin)
 
	static Float:distance_f
	distance_f = get_distance_f(EntOrigin, VicOrigin)
 
	if (distance_f > 10.0)
	{
		new Float:fl_Time = distance_f / speed
 
		fl_Velocity[0] = (VicOrigin[0] - EntOrigin[0]) / fl_Time
		fl_Velocity[1] = (VicOrigin[1] - EntOrigin[1]) / fl_Time
		fl_Velocity[2] = (VicOrigin[2] - EntOrigin[2]) / fl_Time
	} else
	{
		fl_Velocity[0] = 0.0
		fl_Velocity[1] = 0.0
		fl_Velocity[2] = 0.0
	}
 
	entity_set_vector(ent, EV_VEC_velocity, fl_Velocity)
}
 

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
#include <xs>
#include <cstrike>
 
 
enum
{
	anim_idle,
	anim_reload,
	anim_draw,
	anim_shoot1,
	anim_shoot2,
	anim_shoot3
}
 
#define ENG_NULLENT		-1
#define EV_INT_WEAPONKEY	EV_INT_impulse
 
#define guitar_WEAPONKEY	700
 
#define MAX_PLAYERS  			  32
const USE_STOPPED = 0
const OFFSET_ACTIVE_ITEM = 373
const OFFSET_WEAPONOWNER = 41
const OFFSET_LINUX = 5
const OFFSET_LINUX_WEAPONS = 4
#define WEAP_LINUX_XTRA_OFF			4
#define m_fKnown				44
#define m_flNextPrimaryAttack 			46
#define m_flTimeWeaponIdle			48
#define m_iClip					51
#define m_fInReload				54
#define PLAYER_LINUX_XTRA_OFF			5
#define m_flNextAttack				83
 
#define guitar_RELOAD_TIME 3.0
 
const PRIMARY_WEAPONS_BIT_SUM = (1<<CSW_SCOUT)|(1<<CSW_XM1014)|(1<<CSW_MAC10)|(1<<CSW_AUG)|(1<<CSW_UMP45)|(1<<CSW_GALIL)|(1<<CSW_GALIL)|(1<<CSW_FAMAS)|(1<<CSW_AWP)|(1<<CSW_MP5NAVY)|(1<<CSW_M249)|(1<<CSW_M3)|(1<<CSW_M4A1)|(1<<CSW_TMP)|(1<<CSW_G3SG1)|(1<<CSW_SG552)|(1<<CSW_AK47)|(1<<CSW_GALIL)
new const WEAPONENTNAMES[][] = { "", "weapon_p228", "", "weapon_scout", "weapon_hegrenade", "weapon_xm1014", "weapon_c4", "weapon_mac10",
			"weapon_aug", "weapon_smokegrenade", "weapon_elite", "weapon_fiveseven", "weapon_ump45", "weapon_galil",
			"weapon_galil", "weapon_famas", "weapon_usp", "weapon_glock18", "weapon_awp", "weapon_mp5navy", "weapon_m249",
			"weapon_m3", "weapon_m4a1", "weapon_tmp", "weapon_g3sg1", "weapon_flashbang", "weapon_deagle", "weapon_sg552",
			"weapon_ak47", "weapon_knife", "weapon_galil" }
 
new const Sound_Fire[][] = { "cso_wpn/gt-1.wav" }
new const GUNSHOT_DECALS[] = { 41, 42, 43, 44, 45 }
new guitar_V_MODEL[64] = "models/v_guitar.mdl"
new guitar_P_MODEL[64] = "models/p_guitar.mdl"
new guitar_W_MODEL[64] = "models/w_guitar.mdl"
 
new cvar_dmg_guitar, cvar_recoil_guitar, cvar_spd_guitar, cvar_guitar_ammo, cvar_clip_guitar
 
new g_has_guitar[33], g_MaxPlayers, Float:cl_pushangle[MAX_PLAYERS + 1][3], m_iBlood[2], g_orig_event_m249, g_IsInPrimaryAttack, g_clip_ammo[33], g_guitar_TmpClip[33]
 
public plugin_init()
{
	register_plugin("Weapon >Guitar<", "1.0", "Crock")
	register_message(get_user_msgid("DeathMsg"), "message_DeathMsg")
	register_event("CurWeapon","CurrentWeapon","be","1=1")
	RegisterHam(Ham_Item_AddToPlayer, "weapon_galil", "fw_Aug_AddToPlayer")
	RegisterHam(Ham_Use, "func_tank", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tankmortar", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tankrocket", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tanklaser", "fw_UseStationary_Post", 1)
	for (new i = 1; i < sizeof WEAPONENTNAMES; i++)
		if (WEAPONENTNAMES[i][0]) RegisterHam(Ham_Item_Deploy, WEAPONENTNAMES[i], "fw_Item_Deploy_Post", 1)
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_galil", "fw_Aug_PrimaryAttack")
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_galil", "fw_Aug_PrimaryAttack_Post", 1)
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	RegisterHam(Ham_Item_PostFrame, "weapon_galil", "guitar__ItemPostFrame");
	RegisterHam(Ham_Weapon_Reload, "weapon_galil", "guitar__Reload");
	RegisterHam(Ham_Weapon_Reload, "weapon_galil", "guitar__Reload_Post", 1);
	register_forward(FM_SetModel, "fw_SetModel")
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
	register_forward(FM_PlaybackEvent, "fwPlaybackEvent")
 
	cvar_dmg_guitar = register_cvar("guitar_damage", "2.67")
	cvar_recoil_guitar = register_cvar("guitar_recoil", "0.78")
	cvar_spd_guitar = register_cvar("guitar_speed", "0.87")
	cvar_clip_guitar = register_cvar("guitar_clip", "40")
	cvar_guitar_ammo = register_cvar("guitar_ammo", "180")
 
	register_clcmd("say /fegyo", "addweap")
	register_logevent("logevent_round_start", 2, "1=Round_Start") 
 
	g_MaxPlayers = get_maxplayers()
}
 
public plugin_precache()
{
    precache_sound("weapons/gt-1.wav")
    precache_sound("weapons/gt_clipon.wav")
    precache_sound("weapons/gt_dr.wav")
    precache_sound("weapons/gt_in.wav")
    precache_sound("weapons/gt_clipout.wav")
    precache_model(guitar_V_MODEL)
    precache_model(guitar_P_MODEL)
    precache_model(guitar_W_MODEL)
    for(new i = 0; i < sizeof Sound_Fire; i++)
            precache_sound(Sound_Fire[i])	
    m_iBlood[0] = precache_model("sprites/blood.spr")
    m_iBlood[1] = precache_model("sprites/bloodspray.spr")
 
    register_forward(FM_PrecacheEvent, "fwPrecacheEvent_Post", 1)
}
 
public logevent_round_start(id)
{
	g_has_guitar[id] = false
}
 
public fwPrecacheEvent_Post(type, const name[])
{
	if (equal("events/galil.sc", name))
	{
		g_orig_event_m249 = get_orig_retval()
		return FMRES_HANDLED
	}
 
	return FMRES_IGNORED
}
 
public client_connect(id)
{
	g_has_guitar[id] = false
}
 
public client_disconnect(id)
{
	g_has_guitar[id] = false
}
public fw_SetModel(entity, model[])
{
	if(!is_valid_ent(entity))
		return FMRES_IGNORED;
 
	static szClassName[33]
	entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName))
 
	if(!equal(szClassName, "weaponbox"))
		return FMRES_IGNORED;
 
	static iOwner
 
	iOwner = entity_get_edict(entity, EV_ENT_owner)
 
	if(equal(model, "models/w_galil.mdl"))
	{
		static iStoredAugID
 
		iStoredAugID = find_ent_by_owner(ENG_NULLENT, "weapon_galil", entity)
 
		if(!is_valid_ent(iStoredAugID))
			return FMRES_IGNORED;
 
		if(g_has_guitar[iOwner])
		{
			entity_set_int(iStoredAugID, EV_INT_WEAPONKEY, guitar_WEAPONKEY)
 
			g_has_guitar[iOwner] = false
 
			entity_set_model(entity, guitar_W_MODEL)
 
			return FMRES_SUPERCEDE;
		}
	}
 
	return FMRES_IGNORED;
}
 
public addweap(id)
{
		drop_weapons(id, 1);
		new iWep2 = give_item(id,"weapon_galil")
		if( iWep2 > 0 )
		{
			cs_set_weapon_ammo( iWep2, get_pcvar_num(cvar_clip_guitar) )
			cs_set_user_bpammo (id, CSW_GALIL, get_pcvar_num(cvar_guitar_ammo))
		}
		g_has_guitar[id] = true;
 
}
 
public fw_Aug_AddToPlayer(Aug, id)
{
	if(!is_valid_ent(Aug) || !is_user_connected(id))
		return HAM_IGNORED;
 
	if(entity_get_int(Aug, EV_INT_WEAPONKEY) == guitar_WEAPONKEY)
	{
		g_has_guitar[id] = true
 
		entity_set_int(Aug, EV_INT_WEAPONKEY, 0)
 
		return HAM_HANDLED;
	}		
	return HAM_IGNORED;
}
 
public fw_UseStationary_Post(entity, caller, activator, use_type)
{
	if (use_type == USE_STOPPED && is_user_connected(caller))
		replace_weapon_models(caller, get_user_weapon(caller))
}
 
public fw_Item_Deploy_Post(weapon_ent)
{
	static owner
	owner = fm_cs_get_weapon_ent_owner(weapon_ent)
 
	static weaponid
	weaponid = cs_get_weapon_id(weapon_ent)
 
	replace_weapon_models(owner, weaponid)
}
 
public CurrentWeapon(id)
{
     replace_weapon_models(id, read_data(2))
 
     if(read_data(2) != CSW_GALIL || !g_has_guitar[id])
          return
 
     static Float:iSpeed
     if(g_has_guitar[id])
          iSpeed = get_pcvar_float(cvar_spd_guitar)
 
     static weapon[32],Ent
     get_weaponname(read_data(2),weapon,31)
     Ent = find_ent_by_owner(-1,weapon,id)
     if(Ent)
     {
          static Float:Delay, Float:M_Delay
          Delay = get_pdata_float( Ent, 46, 4) * iSpeed
          M_Delay = get_pdata_float( Ent, 47, 4) * iSpeed
          if (Delay > 0.0)
          {
               set_pdata_float(Ent, 46, Delay, 4)
               set_pdata_float(Ent, 47, M_Delay, 4)
          }
     }
}
 
replace_weapon_models(id, weaponid)
{
	switch (weaponid)
	{
		case CSW_GALIL:
		{
 
			if(g_has_guitar[id])
			{
				set_pev(id, pev_viewmodel2, guitar_V_MODEL)
				set_pev(id, pev_weaponmodel2, guitar_P_MODEL)
			}			
		}
	}
}
 
public fw_UpdateClientData_Post(Player, SendWeapons, CD_Handle)
{
	if(!is_user_alive(Player) || (get_user_weapon(Player) != CSW_GALIL || !g_has_guitar[Player]))
 
		return FMRES_IGNORED
 
	set_cd(CD_Handle, CD_flNextAttack, halflife_time () + 0.001)
	return FMRES_HANDLED
}
 
public fw_Aug_PrimaryAttack(Weapon)
{
	new Player = get_pdata_cbase(Weapon, 41, 5)
 
	if (!g_has_guitar[Player])
		return;
 
	g_IsInPrimaryAttack = 1
	pev(Player,pev_punchangle,cl_pushangle[Player])
 
	g_clip_ammo[Player] = cs_get_weapon_ammo(Weapon)
}
 
public fwPlaybackEvent(flags, invoker, eventid, Float:delay, Float:origin[3], Float:angles[3], Float:fparam1, Float:fparam2, iParam1, iParam2, bParam1, bParam2)
{
	if (eventid != g_orig_event_m249 || !g_IsInPrimaryAttack)
		return FMRES_IGNORED
	if (!(1 <= invoker <= g_MaxPlayers))
		return FMRES_IGNORED
 
	playback_event(flags | FEV_HOSTONLY, invoker, eventid, delay, origin, angles, fparam1, fparam2, iParam1, iParam2, bParam1, bParam2)
	return FMRES_SUPERCEDE
}
 
public fw_Aug_PrimaryAttack_Post(Weapon)
{
	g_IsInPrimaryAttack = 0
	new Player = get_pdata_cbase(Weapon, 41, 5)
 
	if(g_has_guitar[Player])
	{
		new Float:push[3]
		pev(Player,pev_punchangle,push)
		xs_vec_sub(push,cl_pushangle[Player],push)
 
		xs_vec_mul_scalar(push,get_pcvar_float(cvar_recoil_guitar),push)
		xs_vec_add(push,cl_pushangle[Player],push)
		set_pev(Player,pev_punchangle,push)
 
		if (!g_clip_ammo[Player])
			return
 
		emit_sound(Player, CHAN_WEAPON, Sound_Fire[0], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
 
		switch(random_num(0,2))
		{
		case 0:
		UTIL_PlayWeaponAnimation(Player, anim_shoot1)
		case 1:
		UTIL_PlayWeaponAnimation(Player, anim_shoot2)
		case 2:
		UTIL_PlayWeaponAnimation(Player, anim_shoot3)
		}
 
		make_blood_and_bulletholes(Player)
	}	
}
 
public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if (victim != attacker && is_user_connected(attacker))
	{
		if(get_user_weapon(attacker) == CSW_GALIL)
		{
			if(g_has_guitar[attacker])
				SetHamParamFloat(4, damage * get_pcvar_float(cvar_dmg_guitar))
		}
	}
}
 
public message_DeathMsg(msg_id, msg_dest, id)
{
	static szTruncatedWeapon[33], iAttacker, iVictim
 
	get_msg_arg_string(4, szTruncatedWeapon, charsmax(szTruncatedWeapon))
 
	iAttacker = get_msg_arg_int(1)
	iVictim = get_msg_arg_int(2)
 
	if(!is_user_connected(iAttacker) || iAttacker == iVictim)
		return PLUGIN_CONTINUE
 
	if(equal(szTruncatedWeapon, "galil") && get_user_weapon(iAttacker) == CSW_GALIL)
	{
		if(g_has_guitar[iAttacker])
			set_msg_arg_string(4, "[guitar]")		
	}
 
	return PLUGIN_CONTINUE
}
 
stock fm_cs_get_current_weapon_ent(id)
{
	return get_pdata_cbase(id, OFFSET_ACTIVE_ITEM, OFFSET_LINUX);
}
 
stock fm_cs_get_weapon_ent_owner(ent)
{
	return get_pdata_cbase(ent, OFFSET_WEAPONOWNER, OFFSET_LINUX_WEAPONS);
}
 
stock UTIL_PlayWeaponAnimation(const Player, const Sequence)
{
	set_pev(Player, pev_weaponanim, Sequence)
 
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, .player = Player)
	write_byte(Sequence)
	write_byte(pev(Player, pev_body))
	message_end()
}
 
stock make_blood_and_bulletholes(id)
{
	new aimOrigin[3], target, body
	get_user_origin(id, aimOrigin, 3)
	get_user_aiming(id, target, body)
 
	if(target > 0 && target <= g_MaxPlayers)
	{
		new Float:fStart[3], Float:fEnd[3], Float:fRes[3], Float:fVel[3]
		pev(id, pev_origin, fStart)
 
		velocity_by_aim(id, 64, fVel)
 
		fStart[0] = float(aimOrigin[0])
		fStart[1] = float(aimOrigin[1])
		fStart[2] = float(aimOrigin[2])
		fEnd[0] = fStart[0]+fVel[0]
		fEnd[1] = fStart[1]+fVel[1]
		fEnd[2] = fStart[2]+fVel[2]
 
		new res
		engfunc(EngFunc_TraceLine, fStart, fEnd, 0, target, res)
		get_tr2(res, TR_vecEndPos, fRes)
 
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY) 
		write_byte(TE_BLOODSPRITE)
		write_coord(floatround(fStart[0])) 
		write_coord(floatround(fStart[1])) 
		write_coord(floatround(fStart[2])) 
		write_short( m_iBlood [ 1 ])
		write_short( m_iBlood [ 0 ] )
		write_byte(70)
		write_byte(random_num(1,2))
		message_end()
 
 
	} 
	else if(!is_user_connected(target))
	{
		if(target)
		{
			message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
			write_byte(TE_DECAL)
			write_coord(aimOrigin[0])
			write_coord(aimOrigin[1])
			write_coord(aimOrigin[2])
			write_byte(GUNSHOT_DECALS[random_num ( 0, sizeof GUNSHOT_DECALS -1 ) ] )
			write_short(target)
			message_end()
		} 
		else 
		{
			message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
			write_byte(TE_WORLDDECAL)
			write_coord(aimOrigin[0])
			write_coord(aimOrigin[1])
			write_coord(aimOrigin[2])
			write_byte(GUNSHOT_DECALS[random_num ( 0, sizeof GUNSHOT_DECALS -1 ) ] )
			message_end()
		}
 
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
		write_byte(TE_GUNSHOTDECAL)
		write_coord(aimOrigin[0])
		write_coord(aimOrigin[1])
		write_coord(aimOrigin[2])
		write_short(id)
		write_byte(GUNSHOT_DECALS[random_num ( 0, sizeof GUNSHOT_DECALS -1 ) ] )
		message_end()
	}
}
 
public guitar__ItemPostFrame(weapon_entity) 
{
     new id = pev(weapon_entity, pev_owner)
     if (!is_user_connected(id))
          return HAM_IGNORED;
 
     if (!g_has_guitar[id])
          return HAM_IGNORED;
 
     static iClipExtra
 
     if(g_has_guitar[id])
          iClipExtra = get_pcvar_num(cvar_clip_guitar)	  
 
     new Float:flNextAttack = get_pdata_float(id, m_flNextAttack, PLAYER_LINUX_XTRA_OFF)
 
     new iBpAmmo = cs_get_user_bpammo(id, CSW_GALIL);
     new iClip = get_pdata_int(weapon_entity, m_iClip, WEAP_LINUX_XTRA_OFF)
 
     new fInReload = get_pdata_int(weapon_entity, m_fInReload, WEAP_LINUX_XTRA_OFF) 
 
     if( fInReload && flNextAttack <= 0.0 )
     {
          new j = min(iClipExtra - iClip, iBpAmmo)
 
          set_pdata_int(weapon_entity, m_iClip, iClip + j, WEAP_LINUX_XTRA_OFF)
          cs_set_user_bpammo(id, CSW_GALIL, iBpAmmo-j);
 
          set_pdata_int(weapon_entity, m_fInReload, 0, WEAP_LINUX_XTRA_OFF)
          fInReload = 0
     }
 
     return HAM_IGNORED;
}
 
public guitar__Reload(weapon_entity) 
{
     new id = pev(weapon_entity, pev_owner)
     if (!is_user_connected(id))
          return HAM_IGNORED;
 
     if (!g_has_guitar[id])
          return HAM_IGNORED;
 
     static iClipExtra
 
     if(g_has_guitar[id])
          iClipExtra = get_pcvar_num(cvar_clip_guitar)
 
     g_guitar_TmpClip[id] = -1;
 
     new iBpAmmo = cs_get_user_bpammo(id, CSW_GALIL);
     new iClip = get_pdata_int(weapon_entity, m_iClip, WEAP_LINUX_XTRA_OFF)
 
     if (iBpAmmo <= 0)
          return HAM_SUPERCEDE;
 
     if (iClip >= iClipExtra)
          return HAM_SUPERCEDE;
 
     g_guitar_TmpClip[id] = iClip;
 
     return HAM_IGNORED;
}
 
public guitar__Reload_Post(weapon_entity) 
{
	new id = pev(weapon_entity, pev_owner)
	if (!is_user_connected(id))
		return HAM_IGNORED;
 
	if (!g_has_guitar[id])
		return HAM_IGNORED;
 
	if (g_guitar_TmpClip[id] == -1)
		return HAM_IGNORED;
 
	static Float:iReloadTime
	if(g_has_guitar[id])
		iReloadTime = guitar_RELOAD_TIME
 
	set_pdata_int(weapon_entity, m_iClip, g_guitar_TmpClip[id], WEAP_LINUX_XTRA_OFF)
 
	set_pdata_float(weapon_entity, m_flTimeWeaponIdle, iReloadTime, WEAP_LINUX_XTRA_OFF)
 
	set_pdata_float(id, m_flNextAttack, iReloadTime, PLAYER_LINUX_XTRA_OFF)
 
	set_pdata_int(weapon_entity, m_fInReload, 1, WEAP_LINUX_XTRA_OFF)
 
	UTIL_PlayWeaponAnimation(id, 1)
 
	return HAM_IGNORED;
}
 
stock drop_weapons(id, dropwhat)
{
     static weapons[32], num, i, weaponid
     num = 0
     get_user_weapons(id, weapons, num)
 
     for (i = 0; i < num; i++)
     {
          weaponid = weapons[i]
 
          if (dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM))
          {
               static wname[32]
               get_weaponname(weaponid, wname, sizeof wname - 1)
               engclient_cmd(id, "drop", wname)
          }
     }
}