hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.03.29. 11:48



Jelenlévő felhasználók

Jelenleg 323 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 323 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  [ 3 hozzászólás ] 
Szerző Üzenet
 Hozzászólás témája: játékos infó
HozzászólásElküldve: 2014.07.29. 16:46 
Offline
Beavatott
Avatar

Csatlakozott: 2014.04.14. 21:21
Hozzászólások: 88
Megköszönt másnak: 6 alkalommal
Megköszönték neki: 4 alkalommal
Sziasztok!
Azt a plugint keresem, amikor ráviszem a célkeresztet a társamra, akkor kiírja kék/piros színnel a nevét, hp-ját, pajzsát. :)


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: játékos infó
HozzászólásElküldve: 2014.07.29. 16:47 
Offline
Nagyúr
Avatar

Csatlakozott: 2013.09.04. 15:21
Hozzászólások: 635
Megköszönt másnak: 1 alkalommal
Megköszönték neki: 141 alkalommal
SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <fakemeta>
  3. #include <hamsandwich>
  4.  
  5. #define UPDATE_INTERVAL 0.5
  6. #define TID_TIMER 26642
  7.  
  8. #define _Set(%1,%2) %1|=1<<%2
  9. #define _UnSet(%1,%2) %1&=~(1<<%2)
  10. #define _Is(%1,%2) (%1&1<<%2)
  11. new _alive, _in_server
  12.  
  13. new g_max_players
  14. new g_timer_entid
  15. new Float:g_t_time
  16. new g_HSO
  17.  
  18. new pc_enabled
  19. new pc_team_color
  20. new pc_details
  21. new pc_req_flags
  22. new pc_dead_only
  23.  
  24. new g_enabled
  25. new g_team_color
  26. new g_details
  27. new g_req_flags
  28. new g_dead_only
  29.  
  30. new g_target[33]
  31. new g_name[33][32]
  32. new g_weap_name[32][32] = {"", "p228", "", "scout", "HE",
  33. "xm1014", "c4", "mac10", "aug", "SG", "elite",
  34. "fiveseven", "ump45", "sg550", "galil", "famas", "usp", "glock",
  35. "awp", "mp5", "m249", "m3", "m4a1", "tmp",
  36. "g3sg1", "FB", "deagle", "sg552", "ak47",
  37. "knife", "p90", ""}
  38. new g_hp[33]
  39. new g_ap[33]
  40. new g_weapon[33]
  41. new g_team[33]
  42.  
  43.  
  44. public plugin_init(){
  45. register_plugin("Target Info on HUD", "1.2", "Sylwester")
  46.  
  47. register_message(get_user_msgid("StatusValue"), "update_target")
  48. register_message(get_user_msgid("Health"), "update_hp")
  49. register_message(get_user_msgid("Battery"), "update_ap")
  50. register_message(get_user_msgid("CurWeapon"), "update_weapon")
  51. register_event("TeamInfo", "join_team","a")
  52. register_event("HLTV", "update_cvars", "a", "1=0", "2=0")
  53.  
  54. RegisterHam(Ham_Spawn, "player", "Player_Spawn", 1)
  55. RegisterHam(Ham_Killed, "player", "Player_Killed", 1)
  56.  
  57. pc_enabled = register_cvar("ti_enabled", "1") //0 - plugin disabled //1 - plugin enabled
  58. pc_team_color = register_cvar("ti_team_color", "1") //0-same color for all teams//1-team color
  59. pc_details = register_cvar("ti_details", "2") //0-only name//1-show details//2-teammates details
  60. pc_req_flags = register_cvar("ti_req_flags", "") //0 - plugin disabled //1 - plugin enabled
  61. pc_dead_only = register_cvar("ti_dead_only", "0") //0-same color for all teams//1-team color
  62.  
  63. g_max_players = get_maxplayers()
  64. g_HSO = CreateHudSyncObj()
  65. create_timer()
  66. }
  67.  
  68.  
  69. public plugin_cfg(){
  70. update_cvars()
  71. }
  72.  
  73.  
  74. public update_weapon(msg_id, msg_dest, id){
  75. if(get_msg_arg_int(1))
  76. g_weapon[id] = get_msg_arg_int(2)
  77. }
  78.  
  79.  
  80. public update_hp(msg_id, msg_dest, id){
  81. g_hp[id] = get_user_health(id)
  82. }
  83.  
  84.  
  85. public update_ap(msg_id, msg_dest, id){
  86. g_ap[id] = get_user_armor(id)
  87. }
  88.  
  89.  
  90. public update_target(msg_id, msg_dest, id){
  91. if(get_msg_arg_int(1) == 2)
  92. g_target[id] = get_msg_arg_int(2)
  93. }
  94.  
  95.  
  96. public client_connect(id){
  97. g_target[id] = 0
  98. g_team[id] = 0
  99. get_user_name(id, g_name[id], 31)
  100. }
  101.  
  102.  
  103. public client_putinserver(id){
  104. _Set(_in_server, id)
  105. }
  106.  
  107.  
  108. public client_disconnect(id){
  109. _UnSet(_alive, id)
  110. _UnSet(_in_server, id)
  111. }
  112.  
  113.  
  114. public Player_Spawn(id){
  115. if(!is_user_alive(id))
  116. return
  117. _Set(_alive, id)
  118. }
  119.  
  120.  
  121. public Player_Killed(id){
  122. _UnSet(_alive, id)
  123. }
  124.  
  125.  
  126. public update_cvars(){
  127. g_enabled = get_pcvar_num(pc_enabled)
  128. g_team_color = get_pcvar_num(pc_team_color)
  129. g_details = get_pcvar_num(pc_details)
  130. g_dead_only = get_pcvar_num(pc_dead_only)
  131. new tmp[32]
  132. get_pcvar_string(pc_req_flags, tmp, 31)
  133. g_req_flags = read_flags(tmp)
  134. }
  135.  
  136.  
  137. public client_infochanged(id){ //update name
  138. get_user_info(id, "name", g_name[id], 31)
  139. }
  140.  
  141.  
  142. public join_team(){
  143. static id, team[2]
  144. id = read_data(1)
  145. read_data(2, team, 1)
  146. switch(team[0]){
  147. case 'C': g_team[id] = 2
  148. case 'T': g_team[id] = 1
  149. default : g_team[id] = 0
  150. }
  151. }
  152.  
  153.  
  154. public create_timer(){
  155. g_timer_entid = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString,"info_target"))
  156.  
  157. if(pev_valid(g_timer_entid)){
  158. set_pev(g_timer_entid, pev_classname, "ti_timer")
  159. global_get(glb_time, g_t_time)
  160. set_pev(g_timer_entid, pev_nextthink, g_t_time + UPDATE_INTERVAL)
  161. register_forward(FM_Think, "fwd_Think")
  162. }else{
  163. log_amx("Warning: Failed to create timer entity, using task instead.")
  164. set_task(UPDATE_INTERVAL, "timer_cycle", TID_TIMER, "", 0, "b")
  165. }
  166. }
  167.  
  168.  
  169. public fwd_Think(Ent){
  170. if(Ent != g_timer_entid)
  171. return FMRES_IGNORED
  172. g_t_time += UPDATE_INTERVAL
  173. set_pev(Ent, pev_nextthink, g_t_time)
  174. timer_cycle()
  175. return FMRES_IGNORED
  176. }
  177.  
  178.  
  179. public plugin_unpause(){
  180. if(pev_valid(g_timer_entid)){
  181. global_get(glb_time, g_t_time)
  182. g_t_time += UPDATE_INTERVAL
  183. set_pev(g_timer_entid, pev_nextthink, g_t_time)
  184. }
  185. }
  186.  
  187.  
  188. public timer_cycle(){
  189. static id, cache[512], tar, pos
  190. if(!g_enabled)
  191. return
  192. for(id = 1; id<=g_max_players; id++){
  193. if(!_Is(_in_server, id) || (get_user_flags(id)&g_req_flags != g_req_flags))
  194. continue
  195. tar = g_target[id]
  196. if(_Is(_alive, id)){
  197. if(g_dead_only)
  198. continue
  199. }else{
  200. if(pev(id, pev_iuser2) == g_target[id])
  201. tar = g_target[tar]
  202. }
  203. if(tar == 0)
  204. continue
  205. if(g_team_color == 0){
  206. set_hudmessage(250, 150, 50, -1.0, 0.53, 1, _, UPDATE_INTERVAL-0.1, 0.1, 0.1, -1)
  207. }else{
  208. switch(g_team[tar]){
  209. case 1: set_hudmessage(255, 30, 30, -1.0, 0.53, 1, _, UPDATE_INTERVAL-0.1, 0.1, 0.1, -1)
  210. case 2: set_hudmessage(30, 30, 255, -1.0, 0.53, 1, _, UPDATE_INTERVAL-0.1, 0.1, 0.1, -1)
  211. default: set_hudmessage(150, 150, 150, -1.0, 0.53, 1, _, UPDATE_INTERVAL-0.1, 0.1, 0.1, -1)
  212. }
  213. }
  214.  
  215. pos = formatex(cache, 511, "%s", g_name[tar])
  216. if(g_details == 1 || (g_details == 2 && g_team[id] == g_team[tar]))
  217. pos += formatex(cache[pos], 511-pos, " -- %d HP / %d AP / %s", g_hp[tar], g_ap[tar], g_weap_name[g_weapon[tar]])
  218. ShowSyncHudMsg(id, g_HSO, cache)
  219. }
  220. }
  221.  

_________________
My Steam:
KépKép

Ők köszönték meg Golo nek ezt a hozzászólást: mattboy (2014.07.29. 16:50)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: játékos infó
HozzászólásElküldve: 2014.07.29. 16:50 
Offline
Beavatott
Avatar

Csatlakozott: 2014.04.14. 21:21
Hozzászólások: 88
Megköszönt másnak: 6 alkalommal
Megköszönték neki: 4 alkalommal
Ment a gombocska. :) Köszönöm.


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  [ 3 hozzászólás ] 


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 10 vendég


Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole