hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.03.29. 12:56



Jelenlévő felhasználók

Jelenleg 318 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 318 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  [ 7 hozzászólás ] 
Szerző Üzenet
 Hozzászólás témája: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.01. 17:58 
Offline
Senior Tag

Csatlakozott: 2013.07.29. 13:15
Hozzászólások: 233
Megköszönt másnak: 125 alkalommal
Sziasztok. Nekem egy olyan plugin kellene hogy ha beírom /hoza akkor bejön egy menü amiben a szerveren lévők nevei vanna és onnan kiválaszok egyet és akit kiválasztok az bekerül egy másik menübe és ott a menü be akár ki választunk ki ne csináljon semmit ha rányomunk és felül a menü címében írja ki hogy hány jatekos van a menüben. Ha és valakit törölni akarok akkor beírm /torol és bejön egy menü amiben azoknak a nevei vannak akiket hozzá adtam és ki kell választani akit törlöni szeretnék és mikor kiválasztom az törölje ki. Amikor csak simán megszeretném nézni kik vannak a menüben akiket hozzá adtam akkor csak /jelenlevok és bejön a menü amiben azok vannak akiket hozzá adtam és akár kire nyomok ne csináljon semmit. és ezekhez kellene egy kis Chat üzenet is ha
Chat üezenetek:
Mikor hozzáadok: XY hozzáadta YX -et a listájához.
Mikor törlök: XY törölte YX-et a listájárol.
Aki megcsinálja annak 50 hozzá szólását megköszönöm mert ez nagyon fontos lenne nekem. :)


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.01. 23:41 
Offline
Jómunkásember
Avatar

Csatlakozott: 2013.01.15. 19:04
Hozzászólások: 407
Megköszönt másnak: 17 alkalommal
Megköszönték neki: 176 alkalommal
Tessék próbáld.
SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <amxmisc>
  3.  
  4. #define PLUGIN "Hulyeseg"
  5. #define VERSION "1.0"
  6. #define AUTHOR "Demon"
  7.  
  8. new JSzListaban[33] = 0; //Jatekosok Szama a Listaban
  9. new jatekos_lista[33][32]
  10.  
  11. public plugin_init() {
  12. register_plugin(PLUGIN, VERSION, AUTHOR)
  13.  
  14. register_clcmd("say /hoza", "JatekosMenu");
  15. register_clcmd("say /jelenlevok", "Lista");
  16. register_clcmd("say /torol", "TorolMenu");
  17. }
  18.  
  19. public client_connect(id) JSzListaban[id]=0;
  20. public client_disconnect(id)
  21. {
  22. JSzListaban[id]=0;
  23. new p[32], pnum, pid;
  24.  
  25. get_players(p, pnum);
  26.  
  27. for( new i; i<pnum; i++ ) {
  28. pid = p[i];
  29. for( new j; j<JSzListaban[pid]; j++ )
  30. {
  31. if(jatekos_lista[pid][j]==id)
  32. {
  33. JatekosTorleseListabol(pid, j)
  34. break;
  35. }
  36. }
  37. }
  38. }
  39.  
  40. public TorolMenu(id) {
  41.  
  42. new menu = menu_create("\yLista:", "torolmenu_h")
  43. new szName[32], szid[10];
  44.  
  45. for( new i; i<JSzListaban[id]; i++ ) {
  46. get_user_name(jatekos_lista[id][i], szName, charsmax(szName));
  47. num_to_str(i, szid, charsmax(szid));
  48. menu_additem(menu, szName, szid, 0);
  49. }
  50. menu_display(id, menu, 0);
  51. }
  52.  
  53. public torolmenu_h(id, menu, item) {
  54. if( item == MENU_EXIT ) {
  55. menu_destroy(menu);
  56. return PLUGIN_HANDLED;
  57. }
  58.  
  59. new data[6], szName[64];
  60. new access, callback;
  61.  
  62. menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
  63.  
  64. new szam = str_to_num(data);
  65.  
  66.  
  67. new Name[32], Name2[32]
  68. get_user_name(id, Name, charsmax(Name));
  69. get_user_name(jatekos_lista[id][szam], Name2, charsmax(Name2));
  70.  
  71. client_print(0, print_chat, "%s torolte %s -t a listajarol.", Name, Name2)
  72. JatekosTorleseListabol(id, szam)
  73. TorolMenu(id);
  74.  
  75. return PLUGIN_HANDLED;
  76. }
  77.  
  78. public Lista(id) {
  79.  
  80. new menu = menu_create("\yLista:", "lista_h")
  81. new szName[32], szid[10];
  82.  
  83. for( new i; i<JSzListaban[id]; i++ ) {
  84. get_user_name(jatekos_lista[id][i], szName, charsmax(szName));
  85. num_to_str(i, szid, charsmax(szid));
  86. menu_additem(menu, szName, szid, 0);
  87. }
  88. menu_display(id, menu, 0);
  89. }
  90.  
  91. public lista_h(id, menu, item) {
  92. if( item == MENU_EXIT ) {
  93. menu_destroy(menu);
  94. return PLUGIN_HANDLED;
  95. }
  96.  
  97. new data[6], szName[64];
  98. new access, callback;
  99.  
  100. menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
  101.  
  102. new szam = str_to_num(data);
  103.  
  104.  
  105. new Name[32]
  106. get_user_name(jatekos_lista[id][szam], Name, charsmax(Name));
  107.  
  108. client_print(id, print_chat, "Kivalasztottad %s-t.", Name)
  109.  
  110. Lista(id);
  111.  
  112. return PLUGIN_HANDLED;
  113. }
  114.  
  115. public JatekosMenu(id) {
  116.  
  117. new menu = menu_create("\yJátékosok:", "jatekosmenu_h")
  118. new players[32], pnum, tempid;
  119. new szName[32], szTempid[10];
  120.  
  121. get_players(players, pnum);
  122.  
  123. for( new i; i<pnum; i++ ) {
  124. tempid = players[i];
  125. get_user_name(tempid, szName, charsmax(szName));
  126. num_to_str(tempid, szTempid, charsmax(szTempid));
  127.  
  128. menu_additem(menu, szName, szTempid, 0);
  129. }
  130. menu_display(id, menu, 0);
  131. }
  132.  
  133. public jatekosmenu_h(id, menu, item) {
  134. if( item == MENU_EXIT ) {
  135. menu_destroy(menu);
  136. return PLUGIN_HANDLED;
  137. }
  138.  
  139. new data[6], szName[64];
  140. new access, callback;
  141.  
  142. menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
  143.  
  144. new tempid = str_to_num(data);
  145.  
  146. if(JSzListaban[id]>=32)
  147. {
  148. client_print(id, print_center, "Nem adhatsz a listadhoz tobb jatekost.")
  149. return PLUGIN_HANDLED;
  150. }
  151.  
  152. for( new i; i<JSzListaban[id]; i++ ) {
  153. if(jatekos_lista[id][i]==tempid)
  154. {
  155. client_print(id, print_center, "Ez a jatekos mar a listadon van.")
  156. JatekosMenu(id);
  157. return PLUGIN_HANDLED;
  158. }
  159. }
  160.  
  161. new Name[32], Name2[32]
  162. get_user_name(id, Name, charsmax(Name));
  163. get_user_name(tempid, Name2, charsmax(Name2));
  164.  
  165. client_print(0, print_chat, "%s hozzaadta %s -t a listajahoz.", Name, Name2)
  166. jatekos_lista[id][JSzListaban[id]]=tempid;
  167. JSzListaban[id]++;
  168. JatekosMenu(id);
  169.  
  170. return PLUGIN_HANDLED;
  171. }
  172.  
  173. public JatekosTorleseListabol(id, szam)
  174. {
  175. for( new i = szam; i < JSzListaban[id]-1; i++ )
  176. jatekos_lista[id][i]=jatekos_lista[id][i+1];
  177.  
  178. JSzListaban[id]--;
  179. }

Ők köszönték meg demon nek ezt a hozzászólást: AsD# (2015.07.04. 01:03)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.02. 01:18 
Offline
Senior Tag

Csatlakozott: 2013.07.29. 13:15
Hozzászólások: 233
Megköszönt másnak: 125 alkalommal
Nagyon szépen köszönöm nemsokára tesztelem de lenne egy kérdésem hogy ha lemegyek a szerverröl asztán vissza akkor is megmaradnak a listán lévő emberek ugye? Lementi akiket a listámba raktam ugye? Mert ha nem akkor még az is kellene hogy le mentse :)
Meg a listába maximum 90 ember férjen és csak ADMIN_LEVEL_B joguak tudjanak hozzá adni és törölni a /jelenlevok parancsot az az a listán lévőket bárki megnézhesse.
pluszba ha megvan hozzá a mentés akkor azt még hozzá lehetne írni hogy amikor /jelenlevok parancsot beírjuk és kiválaszok egy embert olyan kor ezt írja jelenleg: Kivalasztottad XY-t Ezt ki lehetne még azzal bővíteni hogy írja azt is ki hogy ki adta hozzá a listához? szóval akkor ilyen üzenetet írjon: XY-t XY adta a listához!
Ezek ha megvannak akkor megy az 50 megköszönés :)


(Amúgy müködik csak nincs mentés benne :( Meg kellene az a kis plusz dolog amit leírtam és akor tökéletes:))


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.02. 18:12 
Offline
Jómunkásember
Avatar

Csatlakozott: 2013.01.15. 19:04
Hozzászólások: 407
Megköszönt másnak: 17 alkalommal
Megköszönték neki: 176 alkalommal
Tessék:
SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <amxmisc>
  3.  
  4. #define PLUGIN "Hulyeseg"
  5. #define VERSION "1.0"
  6. #define AUTHOR "Demon"
  7.  
  8. #define MAXJATEKOS 90
  9. #define JOG ADMIN_LEVEL_B
  10.  
  11. new JSzListaban = 0;
  12.  
  13. enum _:ListaInfo { Nev[32], Nev2[32] };
  14. new jatekos_lista[MAXJATEKOS][ListaInfo]
  15.  
  16. public plugin_init() {
  17. register_plugin(PLUGIN, VERSION, AUTHOR)
  18.  
  19. register_clcmd("say /hoza", "JatekosMenu");
  20. register_clcmd("say /jelenlevok", "Lista");
  21. register_clcmd("say /torol", "TorolMenu");
  22.  
  23. set_task(1.0, "ListaBetoltes")
  24. }
  25.  
  26. public ListaMentes()
  27. {
  28. new fajl[200]
  29.  
  30. get_configsdir(fajl, 199)
  31. format(fajl, 199, "%s/lista", fajl)
  32.  
  33. if (!dir_exists(fajl)) mkdir(fajl)
  34.  
  35. format(fajl, 199, "%s/lista.ini", fajl)
  36. delete_file(fajl)
  37.  
  38. for(new i; i<JSzListaban; i++)
  39. {
  40. new sor[128]
  41. formatex(sor, 127, "^"%s^" ^"%s^"", jatekos_lista[i][Nev], jatekos_lista[i][Nev2])
  42. write_file(fajl, sor)
  43. }
  44. }
  45.  
  46. public ListaBetoltes()
  47. {
  48. new fajl[200]
  49.  
  50. get_configsdir(fajl, 199)
  51. format(fajl, 199, "%s/lista", fajl)
  52.  
  53. format(fajl, 199, "%s/lista.ini", fajl)
  54.  
  55. JSzListaban=0;
  56.  
  57. if (!file_exists(fajl))
  58. return
  59.  
  60.  
  61. new ertekek[128], len, sor=0, nev[32], nev2[32]
  62.  
  63. while( (sor = read_file(fajl , sor , ertekek , 127 , len) ) != 0 )
  64. {
  65. parse(ertekek, nev, 31, nev2, 31)
  66. copy(jatekos_lista[JSzListaban][Nev], 31, nev);
  67. copy(jatekos_lista[JSzListaban][Nev2], 31, nev2);
  68. JSzListaban++;
  69. }
  70. }
  71.  
  72. public TorolMenu(id) {
  73. if(get_user_flags(id) & JOG) {
  74. new menu = menu_create("\yJatekos torlese listabol:", "torolmenu_h")
  75. new szid[10];
  76.  
  77. for( new i; i<JSzListaban; i++ ) {
  78. num_to_str(i, szid, charsmax(szid));
  79. menu_additem(menu, jatekos_lista[i][Nev2], szid, 0);
  80. }
  81. menu_display(id, menu, 0);
  82. }
  83. else
  84. client_print(id, print_chat, "Nincs jogod ehhez a parancshoz!")
  85. }
  86.  
  87. public torolmenu_h(id, menu, item) {
  88. if( item == MENU_EXIT ) {
  89. menu_destroy(menu);
  90. return PLUGIN_HANDLED;
  91. }
  92.  
  93. new data[6], szName[64];
  94. new access, callback;
  95.  
  96. menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
  97.  
  98. new szam = str_to_num(data);
  99.  
  100.  
  101. new Name[32]
  102. get_user_name(id, Name, charsmax(Name));
  103.  
  104. client_print(0, print_chat, "%s torolte %s -t a listarol.", Name, jatekos_lista[szam][Nev2])
  105. JatekosTorleseListabol(id, szam)
  106.  
  107. return PLUGIN_HANDLED;
  108. }
  109.  
  110. public Lista(id) {
  111.  
  112. new menu = menu_create("\yLista:", "lista_h")
  113. new szid[10];
  114.  
  115. for( new i; i<JSzListaban; i++ ) {
  116. num_to_str(i, szid, charsmax(szid));
  117. menu_additem(menu, jatekos_lista[i][Nev2], szid, 0);
  118. }
  119. menu_display(id, menu, 0);
  120. }
  121.  
  122. public lista_h(id, menu, item) {
  123. if( item == MENU_EXIT ) {
  124. menu_destroy(menu);
  125. return PLUGIN_HANDLED;
  126. }
  127.  
  128. new data[6], szName[64];
  129. new access, callback;
  130.  
  131. menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
  132.  
  133. new szam = str_to_num(data);
  134.  
  135. client_print(id, print_chat, "%s -t %s adta a listahoz.", jatekos_lista[szam][Nev2], jatekos_lista[szam][Nev])
  136.  
  137. Lista(id);
  138.  
  139. return PLUGIN_HANDLED;
  140. }
  141.  
  142. public JatekosMenu(id) {
  143. if(get_user_flags(id) & JOG) {
  144. new menu = menu_create("\yJatekosok:", "jatekosmenu_h")
  145. new players[32], pnum, tempid;
  146. new szName[32], szTempid[10];
  147.  
  148. get_players(players, pnum);
  149.  
  150. for( new i; i<pnum; i++ ) {
  151. tempid = players[i];
  152. get_user_name(tempid, szName, charsmax(szName));
  153. num_to_str(tempid, szTempid, charsmax(szTempid));
  154.  
  155. menu_additem(menu, szName, szTempid, 0);
  156. }
  157. menu_display(id, menu, 0);
  158. }
  159. else
  160. client_print(id, print_chat, "Nincs jogod ehhez a parancshoz!")
  161. }
  162.  
  163. public jatekosmenu_h(id, menu, item) {
  164. if( item == MENU_EXIT ) {
  165. menu_destroy(menu);
  166. return PLUGIN_HANDLED;
  167. }
  168.  
  169. new data[6], szName[64];
  170. new access, callback;
  171.  
  172. menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
  173.  
  174. new tempid = str_to_num(data);
  175.  
  176. if(JSzListaban>=MAXJATEKOS)
  177. {
  178. client_print(id, print_center, "Nem adhatsz a listadhoz tobb jatekost.")
  179. return PLUGIN_HANDLED;
  180. }
  181.  
  182. new Name[32], Name2[32]
  183. get_user_name(id, Name, charsmax(Name));
  184. get_user_name(tempid, Name2, charsmax(Name2));
  185.  
  186. for( new i; i<JSzListaban; i++ ) {
  187. if(equali(jatekos_lista[i][Nev2], Name2))
  188. {
  189. client_print(id, print_center, "Ez a jatekos mar a listaban van.")
  190. JatekosMenu(id);
  191. return PLUGIN_HANDLED;
  192. }
  193. }
  194.  
  195.  
  196.  
  197. client_print(0, print_chat, "%s hozzaadta %s -t a listahoz.", Name, Name2)
  198. copy(jatekos_lista[JSzListaban][Nev], 31, Name);
  199. copy(jatekos_lista[JSzListaban][Nev2], 31, Name2);
  200. JSzListaban++;
  201. ListaMentes();
  202. JatekosMenu(id);
  203.  
  204. return PLUGIN_HANDLED;
  205. }
  206.  
  207. public JatekosTorleseListabol(id, szam)
  208. {
  209.  
  210. for( new i = szam; i < JSzListaban; i++ )
  211. {
  212. if( (i + 1) == JSzListaban )
  213. {
  214. copy(jatekos_lista[i][Nev], 31, "");
  215. copy(jatekos_lista[i][Nev2], 31, "");
  216. }
  217. else
  218. {
  219. copy(jatekos_lista[i][Nev], 31, jatekos_lista[i+1][Nev]);
  220. copy(jatekos_lista[i][Nev2], 31, jatekos_lista[i+1][Nev2]);
  221. }
  222. }
  223.  
  224. JSzListaban--;
  225. ListaMentes()
  226. TorolMenu(id);
  227. }


Az 50 megköszönést nem kérem, csakis azért csináltam meg mert unatkoztam.


A hozzászólást 1 alkalommal szerkesztették, utoljára demon 2015.07.02. 20:15-kor.

Ők köszönték meg demon nek ezt a hozzászólást: AsD# (2015.07.04. 01:03)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.02. 20:11 
Offline
Senior Tag

Csatlakozott: 2013.07.29. 13:15
Hozzászólások: 233
Megköszönt másnak: 125 alkalommal
Anyi hibája van még hogy mikor törlök valakit akkor ez helyett: XY törölte YX-t a listárol na ezt kellene írnia de ezt írja: XY törölte (és ide a szerver nevét írja)-t a listárol.


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.02. 20:16 
Offline
Jómunkásember
Avatar

Csatlakozott: 2013.01.15. 19:04
Hozzászólások: 407
Megköszönt másnak: 17 alkalommal
Megköszönték neki: 176 alkalommal
Javítottam az előző hozzászólásomban a plugint.

Ők köszönték meg demon nek ezt a hozzászólást: AsD# (2015.07.04. 01:02)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egy kisebb plugin.
HozzászólásElküldve: 2015.07.04. 01:02 
Offline
Senior Tag

Csatlakozott: 2013.07.29. 13:15
Hozzászólások: 233
Megköszönt másnak: 125 alkalommal
Köszönöm szépen!


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  [ 7 hozzászólás ] 


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 13 vendég


Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole