hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.03.28. 19:33



Jelenlévő felhasználók

Jelenleg 204 felhasználó van jelen :: 1 regisztrált, 0 rejtett és 203 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: Google [Bot] az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  [ 6 hozzászólás ] 
Szerző Üzenet
 Hozzászólás témája: Regisztrációs Rendszer
HozzászólásElküldve: 2016.09.12. 15:21 
Offline
Nagyúr
Avatar

Csatlakozott: 2016.03.05. 20:56
Hozzászólások: 663
Megköszönt másnak: 27 alkalommal
Megköszönték neki: 124 alkalommal
Üdv fórumozók.

Olyan problémám lenne, hogy ennel a regisztrációs rendszernél bejelentkezésnél a regusers.ini-ből olvassa a felhasználónevet és a jelszót.

Na most ezt nemtudom, hogyan is kellen úgy, hogy sql-ből kérje le.

Maga az sql-be való mentés már kész van a rendszerhez, menti is a felhasználót és jelszót (Regisztrációnál) De bejelentkezésnél már a regusers.iniből akarja olvasni.

Valaki tudna ebben segíteni?

  1. #include <amxmodx>
  2. #include <amxmisc>
  3. #include <colorchat>
  4.  
  5. new const PLUGIN[] = "Regisztracios Menu";
  6. new const VERSION[] = "1.0";
  7. new const AUTHOR[] = "Star";
  8.  
  9. new const Chat_Prefix[] = "[Információ]";
  10.  
  11. new Username[33][32], Password[33][32];
  12. new bool: Loggedin[33];
  13. new Menu[33];
  14.  
  15. enum _:info
  16. {
  17.     uname[32],
  18.     pass[32]
  19. };
  20.  
  21. new Array:regusers, data[info];
  22.  
  23. public plugin_init() {
  24.     register_plugin(PLUGIN, VERSION, AUTHOR);
  25.    
  26.     regusers = ArrayCreate(info);
  27.    
  28.     LoadUsers();
  29.    
  30.     register_clcmd("say /reg", "Regisztracio_Menu");
  31.    
  32.     register_clcmd("Felhasznalo", "GetUsername");
  33.     register_clcmd("Jelszo", "GetPassword");
  34. }
  35.  
  36. public client_putinserver(id)
  37. {
  38.     Loggedin[id] = false;
  39.     Username[id] = "";
  40.     Password[id] = "";
  41. }
  42.  
  43. public Regisztracio_Menu(id)
  44. {
  45.     new menu = menu_create("[\ySzerver] \r- \dRegisztracios Rendszer^n\rÜdv a szerveren!", "RegFo_h");
  46.    
  47.     if(!Loggedin[id])
  48.     {
  49.         menu_additem(menu, "\yRegisztracio^n", "1", 0);
  50.         menu_additem(menu, "\yBejelentkezes^n", "2", 0);
  51.     }
  52.     else menu_additem(menu, "\yKijeletkezes", "1", 0);
  53.    
  54.     menu_display(id, menu, 0);
  55. }
  56. public RegFo_h(id, menu, item)
  57. {
  58.     if(item == MENU_EXIT)
  59.     {
  60.         menu_destroy(menu);
  61.         return;
  62.     }
  63.    
  64.     if(Loggedin[id])
  65.     {
  66.         Loggedin[id] = false;
  67.         ColorChat(0, GREEN, "%s^1Sikeresen kijelentkeztel.", Chat_Prefix);
  68.         return;
  69.     }
  70.     Menu[id] = item;
  71.     Reg_Menu(id);
  72. }
  73. public Reg_Menu(id)
  74. {
  75.     new cim[121];
  76.     new menu = menu_create(Menu[id] == 0 ? "[\ySzerver] \r- \dRegisztracio" : "[\ySzerver] \r- \dBejelentkezes", "Reg_h");
  77.    
  78.     formatex(cim, charsmax(cim), "Felhasznalonev: \r%s^n", Username[id]);
  79.     menu_additem(menu, cim, "1", 0);
  80.    
  81.     formatex(cim, charsmax(cim), "Jelszo: \r%s\n^n^n", Password[id]);
  82.     menu_additem(menu, cim, "2", 0);
  83.    
  84.     menu_additem(menu, Menu[id] == 0 ? "\yRegisztralas!" : "\yBejelentkezes!", "3", 0);
  85.    
  86.     menu_display(id, menu, 0);
  87. }
  88. public Reg_h(id, menu, item)
  89. {
  90.     if(item == MENU_EXIT)
  91.     {
  92.         menu_destroy(menu);
  93.         return;
  94.     }
  95.    
  96.     switch(item)
  97.     {
  98.         case 0:client_cmd(id, "messagemode Felhasznalo");
  99.         case 1:client_cmd(id, "messagemode Jelszo");
  100.         case 2:
  101.         {
  102.             new User = CheckUser(Username[id]);
  103.             if(Menu[id] == 0)
  104.             {
  105.                 if(User == -1)
  106.                 {
  107.                     ColorChat(0, GREEN, "%s^1Sikeresen regisztraltal, most mar bejelentkezhetsz! ^4Felhasznalo:^1 %s | ^4Jelszo:^1 %s", Chat_Prefix, Username[id], Password[id]);
  108.                     SaveUser(Username[id], Password[id])
  109.                     Menu[id] = 1;
  110.                     Reg_Menu(id);
  111.                 }
  112.                 else
  113.                 {
  114.                     ColorChat(0, GREEN, "%s^3%s ^1Felhasznalo mar letezik!", Chat_Prefix, Username[id]);
  115.                     Reg_Menu(id);
  116.                 }
  117.             }
  118.             else if(Menu[id] == 1)
  119.             {
  120.                 if(User > -1)
  121.                 {
  122.                     ArrayGetArray(regusers, User, data);
  123.                     if(equal(data[pass], Password[id]))
  124.                     {
  125.                         ColorChat(0, GREEN, "%s^1Üdv újra itt^4 %s^1!", Chat_Prefix, Username[id]);
  126.                         Loggedin[id] = true;
  127.                     }
  128.                     else
  129.                     {
  130.                         ColorChat(0, GREEN, "%s^1Hibas jelszo, probald ujra.", Chat_Prefix);
  131.                         Reg_Menu(id);
  132.                     }
  133.                 }
  134.             }
  135.         }
  136.     }
  137. }
  138.  
  139. public GetUsername(id) {
  140.     new u[32];
  141.     read_args(u, charsmax(u));
  142.     remove_quotes(u);
  143.     if(strlen(u) < 3)
  144.     {
  145.         ColorChat(0, GREEN, "%s^1A felhasznalonevednek hosszabb kell hogy legyen mint 3 karakter!", Chat_Prefix, Username[id]);
  146.         client_cmd(id, "messagemode Felhasznalo");
  147.     }
  148.     else copy(Username[id], charsmax(Username[]), u);
  149.    
  150.     Reg_Menu(id);
  151. }
  152.  
  153. public GetPassword(id) {
  154.     new p[32];
  155.     read_args(p, charsmax(p));
  156.     remove_quotes(p);
  157.     if(strlen(p) < 6)
  158.     {
  159.         ColorChat(0, GREEN, "%s^1A jelszavad hosszabb kell hogy legyen mint 6 karakter!", Chat_Prefix);
  160.         client_cmd(id, "messagemode Jelszo");
  161.     }
  162.     else copy(Password[id], charsmax(Password[]), p);
  163.    
  164.     Reg_Menu(id);
  165. }
  166.  
  167. public CheckUser(const sName[])
  168. {
  169.     for(new i = 0; i < ArraySize(regusers); i++)
  170.     {
  171.         ArrayGetArray(regusers, i, data);
  172.    
  173.         if(equal(sName, data[uname])) return i;
  174.     }
  175.     return -1;
  176. }
  177.  
  178. public LoadUsers()
  179. {
  180.     new file[200];
  181.  
  182.     get_configsdir(file, 199);
  183.     format(file, 199, "%s/regusers.ini", file);
  184.    
  185.     if (!file_exists(file))
  186.         return PLUGIN_HANDLED;
  187.    
  188.     new pFile  = fopen(file, "rt");
  189.    
  190.     if(pFile)
  191.     {
  192.         new Line[192];
  193.        
  194.         new s[2][32];
  195.         while(!feof(pFile))
  196.         {
  197.             fgets(pFile, Line, 191);
  198.             if(Line[0] == ';' || strlen(Line) < 5)
  199.                 continue;
  200.  
  201.             parse(Line, s[0], 31, s[1], 31);
  202.            
  203.             copy(data[uname], charsmax(data[uname]), s[0]);
  204.             copy(data[pass], charsmax(data[pass]), s[1]);
  205.            
  206.             ArrayPushArray(regusers, data);
  207.         }
  208.         fclose(pFile);
  209.     }
  210.     return 0;
  211. }
  212.  
  213. public SaveUser(const sName[], const sPass[])
  214. {
  215.     new file[200];
  216.    
  217.     copy(data[uname], charsmax(data[uname]), sName);
  218.     copy(data[pass], charsmax(data[pass]), sPass);
  219.    
  220.     ArrayPushArray(regusers, data);
  221.  
  222.     get_configsdir(file, 199);
  223.     format(file, 199, "%s/regusers.ini", file);
  224.    
  225.     new pFile  = fopen(file, "at");
  226.    
  227.     if(pFile)
  228.     {
  229.         new line[70];
  230.        
  231.         formatex(line, 69, "^"%s^" ^"%s^"", sName, sPass);
  232.        
  233.         fputs(pFile, line);
  234.         fclose(pFile);
  235.     }
  236.     return PLUGIN_HANDLED;
  237. }

_________________
Global Offensive modok:

Global Offensive Mode 1.0
Global Offensive Mode 3.0
exodus Global Offensive 4.0


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Regisztrációs Rendszer
HozzászólásElküldve: 2016.09.12. 16:43 
Offline
Jómunkásember
Avatar

Csatlakozott: 2013.01.15. 19:04
Hozzászólások: 407
Megköszönt másnak: 17 alkalommal
Megköszönték neki: 176 alkalommal
new const AUTHOR[] = "Star";
WTF?!


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Regisztrációs Rendszer
HozzászólásElküldve: 2016.09.12. 21:05 
Offline
Nagyúr
Avatar

Csatlakozott: 2016.03.05. 20:56
Hozzászólások: 663
Megköszönt másnak: 27 alkalommal
Megköszönték neki: 124 alkalommal
demon írta:
new const AUTHOR[] = "Star";
WTF?!


Innen hlmodrol kukáztam valahonnan.. :D ez volt beleírva.

_________________
Global Offensive modok:

Global Offensive Mode 1.0
Global Offensive Mode 3.0
exodus Global Offensive 4.0


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Regisztrációs Rendszer
HozzászólásElküldve: 2016.09.12. 21:27 
Offline
Fanatikus

Csatlakozott: 2015.03.25. 18:06
Hozzászólások: 179
Megköszönt másnak: 43 alkalommal
Megköszönték neki: 6 alkalommal
  1. .
  2. public LoadUsers()
  3. {
  4.     new file[200];
  5.  
  6.     get_configsdir(file, 199);
  7.     format(file, 199, "%s/regusers.ini", file);
  8.    
  9.     if (!file_exists(file))
  10.         return PLUGIN_HANDLED;


Ezt ird at :D


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Regisztrációs Rendszer
HozzászólásElküldve: 2016.09.12. 23:17 
Offline
Jómunkásember
Avatar

Csatlakozott: 2013.01.15. 19:04
Hozzászólások: 407
Megköszönt másnak: 17 alkalommal
Megköszönték neki: 176 alkalommal
Tessék, próbáld:
  1. #include < amxmodx >
  2. #include < sqlx >
  3.  
  4. new const g_sPrefix[ ] = "RegSystem";
  5. new const g_sSQL_INFOS[ ][ ] =
  6. {
  7.     "",     // HOST
  8.     "",     // USERNAME
  9.     "",     // PASSWORD
  10.     ""  // DATABASE
  11. };
  12. new Handle: g_iSqlTuple, g_sUserName[ 33 ][ 32 ], g_sPassword[ 33 ][ 32 ], g_iLoggedIn[ 33 ];
  13.  
  14. public plugin_init( )
  15. {
  16.     register_plugin( "Sql Reg System", "1.0", "Demon" );
  17.    
  18.     g_iSqlTuple = SQL_MakeDbTuple( g_sSQL_INFOS[ 0 ], g_sSQL_INFOS[ 1 ], g_sSQL_INFOS[ 2 ], g_sSQL_INFOS[ 3 ] );
  19.  
  20.     new sThread[ 512 ];
  21.     formatex( sThread, charsmax( sThread ), "CREATE TABLE IF NOT EXISTS `reg_users` (`username` varchar( 32 ) NOT NULL, `password` varchar( 32 ) NOT NULL, `id` INT( 11 ) NOT NULL AUTO_INCREMENT PRIMARY KEY );" );
  22.    
  23.     SQL_ThreadQuery( g_iSqlTuple, "ThreadHandler", sThread, { 0 }, 1 );
  24.    
  25.     register_clcmd( "Felhasznalonev", "GetUserName" );
  26.     register_clcmd( "Jelszo", "GetPassword" );
  27.    
  28.     register_clcmd( "say /reg", "cmdReg" );
  29. }
  30.  
  31. public cmdReg( iId ) { MainMenu( iId, 0 ); }
  32.  
  33. public MainMenu( iId, iMenu )
  34. {
  35.     static sTxt[ 256 ], iMenuId, sItemId[ 8 ];
  36.     static const iNum = charsmax( sTxt );
  37.    
  38.     formatex( sTxt, iNum, "\r[\w%s\r]\y ", g_sPrefix );
  39.    
  40.     switch( iMenu )
  41.     {
  42.         case 0:
  43.         {
  44.             add( sTxt, iNum, "Regisztracios menu" );
  45.             iMenuId = menu_create( sTxt, "MainMenuH" );
  46.            
  47.             if ( g_iLoggedIn[ iId ] == 3 ) menu_additem( iMenuId, "Kijelentkezes", "0 0" );
  48.             else
  49.             {
  50.                 menu_additem( iMenuId, "Regisztracio", "1 0" );
  51.                 menu_additem( iMenuId, "Bejelentkezes", "2 0" );
  52.             }
  53.         }
  54.         case 1, 2:
  55.         {
  56.             add( sTxt, iNum, iMenu == 1 ? "Regisztracio" : "Bejelentkezes" );
  57.             iMenuId = menu_create( sTxt, "MainMenuH" );
  58.            
  59.             formatex( sTxt, iNum, "Felhasznalonev: \r%s", g_sUserName[ iId ] );
  60.             formatex( sItemId, charsmax( sItemId ), "1 %d", iMenu );
  61.             menu_additem( iMenuId, sTxt, sItemId );
  62.            
  63.             formatex( sTxt, iNum, "Jelszo: \r%s^n", g_sPassword[ iId ] );
  64.             formatex( sItemId, charsmax( sItemId ), "2 %d", iMenu );
  65.             menu_additem( iMenuId, sTxt, sItemId );
  66.            
  67.             formatex( sItemId, charsmax( sItemId ), "3 %d", iMenu );
  68.             menu_additem( iMenuId, iMenu == 1 ? "Regisztralas" : "Bejelentkezes", sItemId );
  69.         }
  70.     }
  71.     menu_display( iId, iMenuId, 0 );
  72. }
  73.  
  74. public MainMenuH( iId, iMenuId, iItem )
  75. {
  76.     if ( iItem != MENU_EXIT )
  77.     {
  78.         new sMenuName[ 78 ], sInfo[ 32 ], sDatas[ 2 ][ 16 ], iKey, iMenuNum;
  79.         menu_item_getinfo( iMenuId, iItem, iKey, sInfo, charsmax( sInfo ), sMenuName, charsmax( sMenuName ), iMenuNum );
  80.         parse( sInfo, sDatas[ 0 ], charsmax( sDatas[ ] ), sDatas[ 1 ], charsmax( sDatas[ ] ) );
  81.         iKey = str_to_num( sDatas[ 0 ] );
  82.         iMenuNum = str_to_num( sDatas[ 1 ] );
  83.        
  84.        
  85.         switch( iMenuNum )
  86.         {
  87.             case 0:
  88.             {
  89.                 if ( ( g_iLoggedIn[ iId ] = iKey ) == 0 ) ChatColor( iId, "Sikeresen kijelentkeztel." );
  90.                 else MainMenu( iId, ( g_iLoggedIn[ iId ] = iKey ) );
  91.             }
  92.             case 1, 2:
  93.             {
  94.                 switch( iKey )
  95.                 {
  96.                     case 1: { client_cmd( iId, "messagemode Felhasznalonev" ); }
  97.                     case 2: { client_cmd( iId, "messagemode Jelszo" ); }
  98.                     case 3: { LoadDatas( iId, iMenuNum ); }
  99.                 }
  100.             }
  101.         }
  102.     }
  103.     menu_destroy( iMenuId );
  104.     return PLUGIN_HANDLED;
  105. }
  106.  
  107. public SaveDatas( iId )
  108. {
  109.     static sText[ 128 ];
  110.    
  111.     formatex( sText, charsmax( sText ), "INSERT INTO `reg_users` (`username`, `password`) VALUES (^"%s^", ^"%s^");", g_sUserName[ iId ], g_sPassword[ iId ] );
  112.    
  113.     SQL_ThreadQuery( g_iSqlTuple, "ThreadHandler", sText, { 0 }, 1 );
  114. }
  115.  
  116. public LoadDatas( iId, iMode )
  117. {
  118.     static sText[ 128 ], iArray[ 1 ];
  119.    
  120.     iArray[ 0 ] = iId;
  121.    
  122.     if ( iMode == 1 )
  123.     {
  124.         formatex( sText, charsmax( sText ), "SELECT * FROM `reg_users` WHERE username = ^"%s^";", g_sUserName[ iId ] );
  125.         iArray[ 0 ] += 100;
  126.     }
  127.     else formatex( sText, charsmax( sText ), "SELECT * FROM `reg_users` WHERE username = ^"%s^" AND password = ^"%s^";", g_sUserName[ iId ], g_sPassword[ iId ] );
  128.    
  129.     SQL_ThreadQuery( g_iSqlTuple, "ThreadHandler", sText, iArray, sizeof( iArray ) );
  130. }
  131.  
  132. public ThreadHandler( iFailState, Handle:iQuery, const sErrorMsg[ ], iErrorCode, const iARRAY[ ], iArraySize, Float:fQueueTime )
  133. {
  134.     if ( iFailState == TQUERY_CONNECT_FAILED )
  135.     {
  136.         set_fail_state( "Nem tudtam csatlakozni az adatbazishoz." );
  137.         return;
  138.     }
  139.     else if ( iFailState == TQUERY_QUERY_FAILED )
  140.     {
  141.         set_fail_state( "Query Error" );
  142.         return;
  143.     }
  144.    
  145.     if ( iErrorCode )
  146.     {
  147.         log_amx( "%i - %s", iErrorCode, sErrorMsg );
  148.         return;
  149.     }
  150.    
  151.     new iId = iARRAY[ 0 ];
  152.     if ( iId )
  153.     {
  154.         if ( iId > 100 )
  155.         {
  156.             iId -= 100;
  157.             if ( SQL_NumResults( iQuery ) > 0 )
  158.             {
  159.                 g_iLoggedIn[ iId ] = 3;
  160.                 ChatColor( iId, "Sikeresen bejelentkeztel." );
  161.                 MainMenu( iId, 0 );
  162.             }
  163.             else
  164.             {
  165.                 ChatColor( iId, "Hibas felhasznalonev es/vagy jelszo." );
  166.                 MainMenu( iId, 2 );
  167.             }
  168.         }
  169.         else
  170.         {
  171.             if ( SQL_NumResults( iQuery ) > 0 )
  172.             {
  173.                 ChatColor( iId, "Ez a felhasznalonev mar foglalt." );
  174.                 MainMenu( iId, 1 );
  175.             }
  176.             else
  177.             {
  178.                 g_iLoggedIn[ iId ] = 3;
  179.                 ChatColor( iId, "Sikeresen regisztraltal. Felhasznaloneved: %s, Jelszavad: %s.", g_sUserName[ iId ], g_sPassword[ iId ] );
  180.                 SaveDatas( iId );
  181.                 MainMenu( iId, 0 );
  182.             }
  183.         }
  184.     }
  185.    
  186.     return;
  187. }
  188.  
  189. public GetUserName( iId )
  190. {
  191.     static sUser[ 32 ];
  192.     read_args( sUser, charsmax( sUser ) );
  193.     remove_quotes( sUser );
  194.     if ( strlen( sUser ) < 5 )
  195.     {
  196.         ChatColor( iId, "A felhasznalonevednek hosszabb kell hogy legyen mint 5 karakter!" );
  197.         client_cmd( iId, "messagemode Felhasznalonev" );
  198.     }
  199.     else copy( g_sUserName[ iId ], charsmax( g_sUserName[ ] ), sUser );
  200.    
  201.     MainMenu( iId, g_iLoggedIn[ iId ] );
  202. }
  203.  
  204. public GetPassword( iId )
  205. {
  206.     static sPass[ 32 ];
  207.     read_args( sPass, charsmax( sPass ) );
  208.     remove_quotes( sPass );
  209.     if ( strlen( sPass ) < 5 )
  210.     {
  211.         ChatColor( iId, "A jelszavad hosszabb kell hogy legyen mint 5 karakter!" );
  212.         client_cmd( iId, "messagemode Jelszo" );
  213.     }
  214.     else copy( g_sPassword[ iId ], charsmax( g_sPassword[ ] ), sPass );
  215.  
  216.     MainMenu( iId, g_iLoggedIn[ iId ] );
  217. }
  218.  
  219. public client_putinserver( iId )
  220. {
  221.     g_iLoggedIn[ iId ] = 0;
  222.     g_sUserName[ iId ] = "";
  223.     g_sPassword[ iId ] = "";
  224. }
  225.  
  226. public plugin_end( ) { SQL_FreeHandle( g_iSqlTuple ); }
  227.  
  228. stock ChatColor( iId, const sMessage[ ], any:... )
  229. {
  230.     static iPlrNum, iPlayers[ 32 ], sMsg[ 256 ], iIdMsg, iMsgLen = charsmax( sMsg );
  231.    
  232.     vformat( sMsg, iMsgLen, sMessage, 3 );
  233.     format( sMsg, iMsgLen, "^4[%s]^1 %s", g_sPrefix, sMsg );
  234.    
  235.     if ( !iIdMsg ) iIdMsg = get_user_msgid( "SayText" );
  236.    
  237.     if ( iId )
  238.     {
  239.         iPlayers[ 0 ] = iId;
  240.         iPlrNum = 1;
  241.     }
  242.     else get_players( iPlayers, iPlrNum, "ch" );
  243.    
  244.     for ( new i, iPId; i < iPlrNum; ++i )
  245.     {
  246.         iPId = iPlayers[ i ];
  247.        
  248.         if ( !is_user_connected( iPId ) ) continue;
  249.        
  250.         message_begin( MSG_ONE, iIdMsg, _, iPId );
  251.         write_byte( iPId );
  252.         write_string( sMsg );
  253.         message_end( );
  254.     }
  255. }


Ha a g_iLoggedIn[ iId ] egyenlő 3-mal akkor van bejelentkezve a játékos.

Ők köszönték meg demon nek ezt a hozzászólást: exodus (2016.09.13. 14:56)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Regisztrációs Rendszer
HozzászólásElküldve: 2016.09.13. 14:56 
Offline
Nagyúr
Avatar

Csatlakozott: 2016.03.05. 20:56
Hozzászólások: 663
Megköszönt másnak: 27 alkalommal
Megköszönték neki: 124 alkalommal
Működik, köszönöm. :)

_________________
Global Offensive modok:

Global Offensive Mode 1.0
Global Offensive Mode 3.0
exodus Global Offensive 4.0


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  [ 6 hozzászólás ] 


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 28 vendég


Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole