hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.03.29. 09:22



Jelenlévő felhasználók

Jelenleg 339 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 339 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  [ 5 hozzászólás ] 
Szerző Üzenet
 Hozzászólás témája: Paintball skin
HozzászólásElküldve: 2016.11.07. 12:28 
Offline
Tud valamit

Csatlakozott: 2016.08.09. 16:08
Hozzászólások: 121
Megköszönt másnak: 37 alkalommal
Sziasztok a segítségeteket kérem! itt van ez a paintball mod: PaintBall Fegyverek & Mód Az a helyzet hogy csináltam egy usp és egy glock skint és elképzelésem sincs hogy tudom megoldani hogy ne az alap skin legyen a szerveren hanem amit készítettem. Remélem tudtok segíteni! Aki segít megy a gomb!

_________________
Kép


A hozzászólást 1 alkalommal szerkesztették, utoljára rusky18 2016.11.07. 21:42-kor.

Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Paitball skin
HozzászólásElküldve: 2016.11.07. 14:20 
Offline
Jómunkásember

Csatlakozott: 2015.11.29. 17:07
Hozzászólások: 375
Megköszönt másnak: 76 alkalommal
Megköszönték neki: 53 alkalommal
Szia.
Átírtam az elérési utakat a paintballgun.sma-ban.
Elérés: [Edit: rosszul írtam le az elérési utakat utólag vettem észre mostmár jó]
v_pbusp: models/paintball/v_pbusp.mdl
p_pbusp: models/paintball/p_pbusp.mdl

v_pbglock: models/paintball/v_pbglock.mdl
p_pbglock: models/paintball/p_pbglock.mdl

  1. #include <amxmodx>
  2. #include <fakemeta>
  3. #include <hamsandwich>
  4.  
  5. #define PLUGIN "Paintball Gun"
  6. #define VERSION "3.4"
  7. #define AUTHOR "WhooKid"
  8.  
  9. #define MAX_PAINTBALLS  200
  10. #define TASK_PB_RESET   1000
  11. #define TASK_RELOAD 2000
  12.  
  13. new g_paintballs[MAX_PAINTBALLS], g_pbstatus[MAX_PAINTBALLS], g_pbcount, Float:lastshot[33], Float:nextattack[33], freezetime;
  14. new pbgun, pbusp, pbglock, color, shots, veloc, speed, blife, sound, bglow, damge, friendlyfire, tgun, ctgun, beamspr;
  15.  
  16. static const g_shot_anim[4] = {0, 3, 9, 5};
  17. static const g_pbgun_models[11][] = {"models/v_pbgun.mdl", "models/v_pbgun1.mdl", "models/v_pbgun2.mdl", "models/v_pbgun3.mdl", "models/v_pbgun4.mdl", "models/v_pbgun5.mdl", "models/v_pbgun6.mdl", "models/v_pbgun7.mdl", "models/v_pbgun8.mdl", "models/v_pbgun9.mdl", "models/v_pbgun10.mdl"};
  18.  
  19. public plugin_init()
  20. {
  21.     register_plugin(PLUGIN, VERSION, AUTHOR);
  22.     register_cvar("paintballgun", VERSION, FCVAR_SERVER|FCVAR_UNLOGGED);
  23.     register_clcmd("say /ent", "ent_info", ADMIN_SLAY);
  24.     pbgun = register_cvar("amx_pbgun", "1");
  25.     pbusp = register_cvar("amx_pbusp", "1");
  26.     pbglock = register_cvar("amx_pbglock", "1");
  27.  
  28.     if (get_pcvar_num(pbgun) || get_pcvar_num(pbusp) || get_pcvar_num(pbglock))
  29.     {
  30.         register_event("CurWeapon", "ev_curweapon", "be");
  31.         register_logevent("ev_roundstart", 2, "0=World triggered", "1=Round_Start");
  32.         if (get_cvar_num("mp_freezetime") > 0)
  33.             register_event("HLTV", "ev_freezetime", "a", "1=0", "2=0");
  34.  
  35.         register_forward(FM_Touch, "fw_touch");
  36.         register_forward(FM_SetModel, "fw_setmodel");
  37.         register_forward(FM_PlayerPreThink, "fw_playerprethink", 1);
  38.         register_forward(FM_UpdateClientData, "fw_updateclientdata", 1);
  39.  
  40.         color = register_cvar("pbgun_color", "2");
  41.         shots = register_cvar("pbgun_shots", "100");
  42.         veloc = register_cvar("pbgun_velocity", "2000");
  43.         speed = register_cvar("pbgun_speed", "0.08");
  44.         blife = register_cvar("pbgun_life", "15");
  45.         sound = register_cvar("pbgun_sound", "1");
  46.         bglow = register_cvar("pbgun_glow", "b");
  47.         damge = register_cvar("pbgun_damage", "100");
  48.         friendlyfire = get_cvar_pointer("mp_friendlyfire");
  49.  
  50.         new a, max_ents_allow = global_get(glb_maxEntities) - 5;
  51.         for (a = 1; a <= get_pcvar_num(shots); a++)
  52.             if (a < MAX_PAINTBALLS)
  53.                 if (engfunc(EngFunc_NumberOfEntities) < max_ents_allow)
  54.                 {
  55.                     g_paintballs[a] = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"));
  56.                     if (pev_valid(g_paintballs[a]))
  57.                     {
  58.                         set_pev(g_paintballs[a], pev_effects, pev(g_paintballs[a], pev_effects) | EF_NODRAW);
  59.                         g_pbcount++;
  60.                     }
  61.                 }
  62.         if (g_pbcount < 1)
  63.             set_fail_state("[AMXX] Failed to load Paintball Gun (unable to create ents)");
  64.  
  65.         server_print("*** %s v%s by %s Enabled ***", PLUGIN, VERSION, AUTHOR);
  66.     }
  67. }
  68.  
  69. public plugin_precache()
  70. {
  71.     register_cvar("amx_pbgun", "1");
  72.     register_cvar("amx_pbusp", "1");
  73.     register_cvar("amx_pbglock", "1");
  74.     register_cvar("pbgun_tgun", "2");
  75.     register_cvar("pbgun_ctgun", "7");
  76.     tgun = get_cvar_num("pbgun_tgun");
  77.     ctgun = get_cvar_num("pbgun_ctgun");
  78.     if (get_cvar_num("amx_pbgun")) {
  79.         precache_model(g_pbgun_models[tgun]);
  80.         precache_model(g_pbgun_models[ctgun]);
  81.         precache_model((ctgun) ? "models/p_pbgun1.mdl" : "models/p_pbgun.mdl");
  82.         precache_model("models/w_pbgun.mdl");
  83.     }
  84.     if (get_cvar_num("amx_pbusp")) {
  85.         //precache_model("models/v_pbusp.mdl");
  86.         precache_model("models/paintball/v_pbusp.mdl");
  87.         precache_model("models/paintball/p_pbusp.mdl");
  88.         //precache_model("models/p_pbusp.mdl");
  89.     }
  90.     if (get_cvar_num("amx_pbglock")) {
  91.         //precache_model("models/v_pbglock.mdl");
  92.         //precache_model("models/p_pbglock.mdl");
  93.         precache_model("models/paintball/v_pbglock.mdl");
  94.         precache_model("models/paintball/p_pbglock.mdl");
  95.     }
  96.     if (get_cvar_num("amx_pbgun") || get_cvar_num("amx_pbusp") || get_cvar_num("amx_pbglock")) {
  97.         precache_sound("misc/pb1.wav");
  98.         precache_sound("misc/pb2.wav");
  99.         precache_sound("misc/pb3.wav");
  100.         precache_sound("misc/pb4.wav");
  101.         precache_sound("misc/pbg.wav");
  102.         precache_model("models/w_paintball.mdl");
  103.         precache_model("sprites/paintball.spr");
  104.     }
  105.     beamspr = precache_model("sprites/laserbeam.spr");
  106. }
  107.  
  108. public ent_info(id)
  109.     client_print(id, print_chat, "[AMXX] [Ent Info (Current/Max)] Paintballs: (%d/%d)   Entities: (%d/%d)", g_pbcount, get_pcvar_num(shots), engfunc(EngFunc_NumberOfEntities), global_get(glb_maxEntities));
  110.  
  111. public ev_curweapon(id)
  112. {
  113.     new model[25];
  114.     pev(id, pev_viewmodel2, model, 24);
  115.     if (equali(model, "models/v_mp5.mdl") && get_pcvar_num(pbgun))
  116.     {
  117.         set_pev(id, pev_viewmodel2, (get_user_team(id) == 1) ? g_pbgun_models[tgun] : g_pbgun_models[ctgun]);
  118.         set_pev(id, pev_weaponmodel2, (ctgun) ? "models/p_pbgun1.mdl" : "models/p_pbgun.mdl");
  119.     }
  120.     else if (equali(model, "models/v_usp.mdl") && get_pcvar_num(pbusp))
  121.     {
  122.         set_pev(id, pev_viewmodel2, "models/paintball/v_pbusp.mdl");
  123.         set_pev(id, pev_weaponmodel2, "models/paintball/p_pbusp.mdl");
  124.     }
  125.     else if (equali(model, "models/v_glock18.mdl") && get_pcvar_num(pbglock))
  126.     {
  127.         set_pev(id, pev_viewmodel2, "models/paintball/v_pbglock.mdl");
  128.         set_pev(id, pev_weaponmodel2, "models/paintball/p_pbglock.mdl");
  129.     }
  130. }
  131.  
  132. public fw_setmodel(ent, model[])
  133. {
  134.     if (equali(model, "models/w_mp5.mdl"))
  135.         if (get_pcvar_num(pbgun))
  136.         {
  137.             engfunc(EngFunc_SetModel, ent, "models/w_pbgun.mdl");
  138.             return FMRES_SUPERCEDE;
  139.         }
  140.     return FMRES_IGNORED;
  141. }
  142.  
  143. public fw_updateclientdata(id, sw, cd_handle)
  144. {
  145.     if (user_has_pbgun(id) && cd_handle)
  146.     {
  147.         set_cd(cd_handle, CD_ID, 1);
  148.         get_cd(cd_handle, CD_flNextAttack, nextattack[id]);
  149.         //set_cd(cd_handle, CD_flNextAttack, 10.0);
  150.         return FMRES_HANDLED;
  151.     }
  152.     return FMRES_IGNORED;
  153. }
  154.  
  155. public fw_playerprethink(id)
  156. {
  157.     new my_pbgun = user_has_pbgun(id);
  158.     if (my_pbgun)
  159.     {
  160.         new buttons = pev(id, pev_button);
  161.         if (buttons & IN_ATTACK)
  162.         {
  163.             new ammo, null = get_user_weapon(id, ammo, null);
  164.             if (ammo)
  165.             {
  166.                 set_pev(id, pev_button, buttons & ~IN_ATTACK);
  167.                 new Float:gametime = get_gametime(), Float:g_speed;
  168.                 if (my_pbgun == 1)
  169.                     g_speed = get_pcvar_float(speed);
  170.                 else
  171.                     g_speed = (my_pbgun == 2) ? get_pcvar_float(speed) * 2.0 : get_pcvar_float(speed) * 3.0;
  172.                 if (gametime-lastshot[id] > g_speed  && nextattack[id] < 0.0 && !freezetime)
  173.                 {
  174.                     if (paint_fire(id))
  175.                     {
  176.                         lastshot[id] = gametime;
  177.                         set_user_clip(id, ammo - 1);
  178.                         set_pev(id, pev_punchangle, Float:{-0.5, 0.0, 0.0});
  179.                         message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, _, id);
  180.                         write_byte(g_shot_anim[my_pbgun]);
  181.                         write_byte(0);
  182.                         message_end();
  183.                         if (get_pcvar_num(sound))
  184.                             emit_sound(id, CHAN_AUTO, "misc/pbg.wav", 1.0, ATTN_NORM, 0, PITCH_NORM);
  185.                     }
  186.                 }
  187.             }
  188.         }
  189.     }
  190.     return FMRES_IGNORED;
  191. }
  192.  
  193. public paint_fire(id)
  194. {
  195.     new a, ent;
  196.     while (a++ < g_pbcount - 1 && !ent)
  197.         if (g_pbstatus[a] == 0)
  198.             ent = g_pbstatus[a] = g_paintballs[a];
  199.     if (!ent)
  200.         while (a-- > 1 && !ent)
  201.             if (g_pbstatus[a] == 2)
  202.                 ent = g_pbstatus[a] = g_paintballs[a];
  203.  
  204.     if (pev_valid(ent) && is_user_alive(id))
  205.     {
  206.         new Float:vangles[3], Float:nvelocity[3], Float:voriginf[3], vorigin[3], clr;
  207.         set_pev(ent, pev_classname, "pbBullet");
  208.         set_pev(ent, pev_owner, id);
  209.         engfunc(EngFunc_SetModel, ent, "models/w_paintball.mdl");
  210.         engfunc(EngFunc_SetSize, ent, Float:{-1.0, -1.0, -1.0}, Float:{1.0, 1.0, 1.0});
  211.  
  212.         switch (get_pcvar_num(color))
  213.         {
  214.             case 2: clr = (get_user_team(id) == 1) ? 0 : 1;
  215.             case 3: clr = (get_user_team(id) == 1) ? 4 : 3;
  216.             case 4: clr = (get_user_team(id) == 1) ? 2 : 5;
  217.             default: clr = random_num(0, 6);
  218.         }
  219.         set_pev(ent, pev_skin, clr);
  220.        
  221.         get_user_origin(id, vorigin, 1);
  222.         IVecFVec(vorigin, voriginf);
  223.         engfunc(EngFunc_SetOrigin, ent, voriginf);
  224.  
  225.         vangles[0] = random_float(-180.0, 180.0);
  226.         vangles[1] = random_float(-180.0, 180.0);
  227.         set_pev(ent, pev_angles, vangles);
  228.  
  229.         pev(id, pev_v_angle, vangles);
  230.         set_pev(ent, pev_v_angle, vangles);
  231.         pev(id, pev_view_ofs, vangles);
  232.         set_pev(ent, pev_view_ofs, vangles);
  233.  
  234.         set_pev(ent, pev_solid, 2);
  235.         set_pev(ent, pev_movetype, 5);
  236.  
  237.         velocity_by_aim(id, get_pcvar_num(veloc), nvelocity);
  238.         set_pev(ent, pev_velocity, nvelocity);
  239.         set_pev(ent, pev_effects, pev(ent, pev_effects) & ~EF_NODRAW);
  240.  
  241.         set_task(0.1, "paint_glow", ent);
  242.         set_task(15.0 , "paint_reset", ent+TASK_PB_RESET);
  243.     }
  244.  
  245.     return ent;
  246. }
  247.  
  248. public fw_touch(bullet, ent)
  249. {
  250.     new class[20];
  251.     pev(bullet, pev_classname, class, 19);
  252.     if (!equali(class, "pbBullet"))
  253.         return FMRES_IGNORED;
  254.  
  255.     new Float:origin[3], class2[20], owner = pev(bullet, pev_owner), is_ent_alive = is_user_alive(ent);
  256.     pev(ent, pev_classname, class2, 19);
  257.     pev(bullet, pev_origin, origin);
  258.  
  259.     if (is_ent_alive)
  260.     {
  261.         if (owner == ent || pev(ent, pev_takedamage) == DAMAGE_NO)
  262.             return FMRES_IGNORED;
  263.         if (get_user_team(owner) == get_user_team(ent))
  264.             if (!get_pcvar_num(friendlyfire))
  265.                 return FMRES_IGNORED;
  266.  
  267.         ExecuteHam(Ham_TakeDamage, ent, owner, owner, float(get_pcvar_num(damge)), 4098);
  268.     }
  269.  
  270.     if (!equali(class, class2))
  271.     {  
  272.         set_pev(bullet, pev_velocity, Float:{0.0, 0.0, 0.0});
  273.         set_pev(bullet, pev_classname, "pbPaint");
  274.         set_pev(bullet, pev_solid, 0);
  275.         set_pev(bullet, pev_movetype, 0);
  276.         engfunc(EngFunc_SetModel, bullet, "sprites/paintball.spr");
  277.  
  278.         new a, findpb = 0;
  279.         while (a++ < g_pbcount && !findpb)
  280.             if (g_paintballs[a] == bullet)
  281.                 findpb = g_pbstatus[a] = 2;
  282.  
  283.         remove_task(bullet);
  284.         remove_task(bullet+TASK_PB_RESET);
  285.  
  286.         if (get_pcvar_num(sound))
  287.         {
  288.             static wav[20];
  289.             formatex(wav, 20, is_ent_alive ? "player/pl_pain%d.wav" : "misc/pb%d.wav", is_ent_alive ? random_num(4,7) : random_num(1,4));
  290.             emit_sound(bullet, CHAN_AUTO, wav, 1.0, ATTN_NORM, 0, PITCH_NORM);
  291.         }
  292.  
  293.         new bool:valid_surface = (is_ent_alive || containi(class2, "door") != -1) ? false : true;
  294.         if (pev(ent, pev_health) && !is_ent_alive)
  295.         {
  296.             ExecuteHam(Ham_TakeDamage, ent, owner, owner, float(pev(ent, pev_health)), 0);
  297.             valid_surface = false;
  298.         }
  299.         if (valid_surface)
  300.         {
  301.             paint_splat(bullet);
  302.             set_task(float(get_pcvar_num(blife)), "paint_reset", bullet+TASK_PB_RESET);
  303.         }
  304.         else
  305.             paint_reset(bullet+TASK_PB_RESET);
  306.  
  307.         return FMRES_HANDLED;
  308.     }
  309.  
  310.     return FMRES_IGNORED;
  311. }
  312.  
  313. public paint_splat(ent)
  314. {
  315.     new Float:origin[3], Float:norigin[3], Float:viewofs[3], Float:angles[3], Float:normal[3], Float:aiming[3];
  316.     pev(ent, pev_origin, origin);
  317.     pev(ent, pev_view_ofs, viewofs);
  318.     pev(ent, pev_v_angle, angles);
  319.  
  320.     norigin[0] = origin[0] + viewofs[0];
  321.     norigin[1] = origin[1] + viewofs[1];
  322.     norigin[2] = origin[2] + viewofs[2];
  323.     aiming[0] = norigin[0] + floatcos(angles[1], degrees) * 1000.0;
  324.     aiming[1] = norigin[1] + floatsin(angles[1], degrees) * 1000.0;
  325.     aiming[2] = norigin[2] + floatsin(-angles[0], degrees) * 1000.0;
  326.  
  327.     engfunc(EngFunc_TraceLine, norigin, aiming, 0, ent, 0);
  328.     get_tr2(0, TR_vecPlaneNormal, normal);
  329.  
  330.     vector_to_angle(normal, angles);
  331.     angles[1] += 180.0;
  332.     if (angles[1] >= 360.0) angles[1] -= 360.0;
  333.     set_pev(ent, pev_angles, angles);
  334.     set_pev(ent, pev_v_angle, angles);
  335.  
  336.     origin[0] += (normal[0] * random_float(0.3, 2.7));
  337.     origin[1] += (normal[1] * random_float(0.3, 2.7));
  338.     origin[2] += (normal[2] * random_float(0.3, 2.7));
  339.     engfunc(EngFunc_SetOrigin, ent, origin);
  340.     set_pev(ent, pev_frame, float(random_num( (pev(ent, pev_skin) * 18), (pev(ent, pev_skin) * 18) + 17 ) ));
  341.     if (pev(ent, pev_renderfx) != kRenderFxNone)
  342.         set_rendering(ent);
  343. }
  344.  
  345. public paint_glow(ent)
  346. {
  347.     if (pev_valid(ent))
  348.     {
  349.         static pbglow[5], clr[3];
  350.         get_pcvar_string(bglow, pbglow, 4);
  351.         switch (get_pcvar_num(color))
  352.         {
  353.             case 2: clr = (get_user_team(pev(ent, pev_owner))==1) ? {239, 221, 17} : {0, 255, 255};
  354.             default: clr = {255, 255, 255};
  355.         }
  356.         if (read_flags(pbglow) & (1 << 0))
  357.             set_rendering(ent, kRenderFxGlowShell, clr[0], clr[1], clr[2], kRenderNormal, 255);
  358.         if (read_flags(pbglow) & (1 << 1))
  359.         {
  360.             message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
  361.             write_byte(TE_BEAMFOLLOW);
  362.             write_short(ent);
  363.             write_short(beamspr);
  364.             write_byte(4);
  365.             write_byte(2);
  366.             write_byte(clr[0]);
  367.             write_byte(clr[1]);
  368.             write_byte(clr[2]);
  369.             write_byte(255);
  370.             message_end();
  371.         }
  372.     }
  373. }
  374.  
  375. public paint_reset(ent)
  376. {
  377.     remove_task(ent);
  378.     ent -= TASK_PB_RESET;
  379.     new a, findpb = 1;
  380.     while (a++ <= g_pbcount && findpb)
  381.         if (g_paintballs[a] == ent)
  382.             findpb = g_pbstatus[a] = 0;
  383.  
  384.     set_pev(ent, pev_effects, pev(ent, pev_effects) | EF_NODRAW);
  385.     engfunc(EngFunc_SetSize, ent, Float:{0.0, 0.0, 0.0}, Float:{0.0, 0.0, 0.0});
  386.     set_pev(ent, pev_velocity, Float:{0.0, 0.0, 0.0});
  387.     engfunc(EngFunc_SetOrigin, ent, Float:{-2000.0, -2000.0, -2000.0});
  388.     if (pev(ent, pev_renderfx) != kRenderFxNone)
  389.         set_rendering(ent);
  390. }
  391.  
  392. public ev_roundstart()
  393. {
  394.     for (new a = 1; a <= g_pbcount; a++)
  395.         if (g_pbstatus[a] != 0)
  396.             paint_reset(g_paintballs[a]+TASK_PB_RESET);
  397.     if (freezetime)
  398.         freezetime = 0;
  399. }
  400.  
  401. public ev_freezetime()
  402.     freezetime = 1;
  403.  
  404. stock user_has_pbgun(id)
  405. {
  406.     if (is_user_alive(id))
  407.     {
  408.         new model[25];
  409.         pev(id, pev_viewmodel2, model, 24);
  410.         if (containi(model, "models/v_pbgun") != -1)
  411.             return 1;
  412.         else if (equali(model, "models/v_pbusp.mdl"))
  413.             return 2;
  414.         else if (equali(model, "models/v_pbglock.mdl"))
  415.             return 3;
  416.     }
  417.     return 0;
  418. }
  419.  
  420. stock set_user_clip(id, ammo)
  421. {
  422.     new weaponname[32], weaponid = -1, weapon = get_user_weapon(id, _, _);
  423.     get_weaponname(weapon, weaponname, 31);
  424.     while ((weaponid = engfunc(EngFunc_FindEntityByString, weaponid, "classname", weaponname)) != 0)
  425.         if (pev(weaponid, pev_owner) == id) {
  426.             set_pdata_int(weaponid, 51, ammo, 4);
  427.             return weaponid;
  428.         }
  429.     return 0;
  430. }
  431.  
  432. // teame06's function
  433. stock set_rendering(index, fx=kRenderFxNone, r=0, g=0, b=0, render=kRenderNormal, amount=16)
  434. {
  435.     set_pev(index, pev_renderfx, fx);
  436.     new Float:RenderColor[3];
  437.     RenderColor[0] = float(r);
  438.     RenderColor[1] = float(g);
  439.     RenderColor[2] = float(b);
  440.     set_pev(index, pev_rendercolor, RenderColor);
  441.     set_pev(index, pev_rendermode, render);
  442.     set_pev(index, pev_renderamt, float(amount));
  443. }

Ők köszönték meg Krisznitro nek ezt a hozzászólást: rusky18 (2016.11.07. 21:18)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Paitball skin
HozzászólásElküldve: 2016.11.07. 14:39 
Offline
Tud valamit

Csatlakozott: 2016.08.09. 16:08
Hozzászólások: 121
Megköszönt másnak: 37 alkalommal
Köszönöm de valamiért nem jó a régi skin van bent ugyan úgy!

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Paitball skin
HozzászólásElküldve: 2016.11.07. 21:07 
Offline
Nagyúr
Avatar

Csatlakozott: 2016.03.05. 20:56
Hozzászólások: 663
Megköszönt másnak: 27 alkalommal
Megköszönték neki: 124 alkalommal
Használd ki azt, hogy ha egy tömbnek nem adsz értéket az alapból nulla.

Példa:

  1. //Jelen esetben ha Valami[id] kissebb vagy egyenlő mint 0 és a kézben lévő fegyver usp, akkor a következő parancs fut le, vagyis:
  2. //models/mappa/skin.mdl nevezetű skint fogja megjeleníteni az adott játékosnak
  3. //Tehát nem a kliens alap skinjét fogja megjeleníteni, hanem amit te megadtál, addig amíg a jelenlegi tömb értéke 0 vagy kissebb
  4. if(Valami[id] <= 0 && get_user_weapon(id) == CSW_USP)
  5. {
  6.     set_pev(id, pev_viewmodel2, "models/mappa/skin.mdl");
  7. }
  8.  
  9. //Ha pedig felszerel egy skint akkor a Valami[id] értéke változzon meg mondjuk: +1-el

_________________
Global Offensive modok:

Global Offensive Mode 1.0
Global Offensive Mode 3.0
exodus Global Offensive 4.0

Ők köszönték meg exodus nek ezt a hozzászólást: rusky18 (2016.11.07. 21:17)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Paintball skin
HozzászólásElküldve: 2016.11.07. 21:43 
Offline
Tud valamit

Csatlakozott: 2016.08.09. 16:08
Hozzászólások: 121
Megköszönt másnak: 37 alkalommal
Valamiért nem jó

_________________
Kép


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  [ 5 hozzászólás ] 


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 8 vendég


Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole