hlmod.hu

/**
* Parancs, amely lekéri amikor új terroristát választottak (új kör vagy lecsatlakozás).
*
* @param id Player index.
*/
forward dr_chosen_new_terrorist(id);

/**
* Jelenlegi terrorista ID-ének lekérése.
*
* @return Játékos ID.
*/
native dr_get_terrorist();

/**
* Beállítja ki lesz a következő körben a terrorista.
*
* @param id Következő terror ID.
*/
native dr_set_next_terrorist(id);

/**
* Lekéri hogy ki lett az új körben a terrorista.
*
* @return Player index.
*/
native dr_get_next_terrorist();

enum _:ModeData
{
m_Name[32],
m_Mark[16],
m_RoundDelay,
m_CurDelay,
m_CT_BlockWeapon,
m_TT_BlockWeapon,
m_CT_BlockButtons,
m_TT_BlockButtons,
m_Bhop,
m_Usp,
m_Hide
};

/**
* Mode registration.
*
* @param Name Mod neve, ML billentyű használata.
* @param Mark Mod pont, használd ezt hogy megkapd a mod ID-ét más pluginokban.
* @param RoundDelay Mod blokkolása bizonyos körökben.
* @param CT_BlockWeapons Engedélyezi a CT-knek a fegyverfelvételt.
* @param TT_BlockWeapons Engedélyezi a T-knek a fegyverfelvételt.
* @param CT_BlockButtons Engedélyezi a CT-knek a gombok/csapdák használatát.
* @param TT_BlockButtons Engedélyezi a T-knek a gombok/csapdák használatát.
* @param Bhop Bhopp bekapcsolása.
* @param Usp Kezdő USP bekapcsolása CT-knek.
* @param Hide Engedélyezi a mod eltüntetését a menüben.
*
* @return Mod ID.
*/
native dr_register_mode(Name[32], Mark[16], RoundDelay, CT_BlockWeapons, TT_BlockWeapons, CT_BlockButtons, TT_BlockButtons, Bhop, Usp, Hide = 0);

/**
* Jelenlegi mod lekérése.
*
* @param name Mod neve, ide másolja a jelenlegi mod ML kulcsát.
* @param size Névméret.
*
* @return Mod ID.
*/
native dr_get_mode(name[] = "", size = 0);

/**
* Új mod beállítása.
*
* @param mode Mod ID.
* @param fwd Parancs lehívása(dr_kivalasztott_mod).
* @param id Játékos id-e.
*/
native dr_set_mode(mode, fwd = 0, id = 0);

/**
* Mod lekérése jel szerint.
*
* @param mark Mod jele.
*
* @return Mode ID.
*/
native dr_get_mode_by_mark(mark[]);

/**
* Teljes info lekérése a mod-rol.
*
* @param mode Mod ID.
* @param modeinfo Információ/Valami szöveg (pl. "A legjobb mod ever").
*/
native dr_get_mode_info(mode, modeinfo[ModeData]);

/**
* Automatikus bhop beállítása.
*
* @param bhop 0 - KI 1 - BE.
*/
native dr_set_mode_bhop(bhop);

/**
* Automatikus bhop lekérése.
*
* @return 0 - KI, 1 - BE.
*/
native dr_get_mode_bhop();

/**
* Bhop adása egy játékosnak.
*
* @note A bhop modra vonatkozó érték fontosabb mint a játékosra vonatkozó.
*
* @param id Játékos ID.
* @param bhop false - KI, true - BE.
*/
native dr_set_user_bhop(id, bool:bhop);

/**
* Játékos bhop jogainak lekérése.
*
* @param id Játékos ID.
*/
native bool:dr_get_user_bhop(id);

/**
* Parancs, amely lekéri amikor új modot választottak.
*
* @param id Terror ID.
* @param mode Mod ID.
*/
forward dr_selected_mode(id, mode);

enum CancelType
{
CType_TimeOver,
CType_PlayerDisconneced,
CType_PlayerDied,
CType_ModeChanged
}

/**
* Parancs, amely előkészíti a párbajt.
*
* @param duelist_ct Játékos ID.
* @param duelist_t Játékos ID.
*/
forward dr_duel_prestart(duelist_ct, duelist_t);

/**
* Parancs amely elindítsa a párbajt.
*
* @param duelist_ct Játékos ID.
* @param duelist_t Játékos ID.
*/
forward dr_duel_start(duelist_ct, duelist_t);

/**
* Parancs, amely kihirdeti az eredményt.
*
* @param winner Játékos ID.
* @param looser Játékos ID.
*/
forward dr_duel_finish(gyoztes, vesztes);

/**
* Parancs amely leállítja a párbajt.
*
* @param type Leállítás típusa
*/
forward dr_duel_canceled(CancelType:type);

const ITEM_TEAM_T = (1 << 1);
const ITEM_TEAM_CT = (1 << 2);

/**
* Tárgy hozzáadása a bolthoz.
*
* @param name Tárgy neve a menüben.
* @param cost Tárgy ára
* @param team Csapat hozzáférés, bitsum, hásználhatja: ITEM_TEAM_T vagy ITEM_TEAM_CT
* @param access Admin hozzáférés: admin jogok
* @param on_buy OnBuy function(id) A public neve. Pl.: public ShopItem_CanBuy_Health(id) { }
* @param can_buy CanBuy function(id) Ha van valami feltétel a vásárláskor. Lehetséges hogy kell: return ITEM_ENABLED vagy ITEM_DISABLED a public végére
*
* @return Item ID, voltozó árak
*/
native dr_shop_add_item(name[], cost, team = (ITEM_TEAM_T|ITEM_TEAM_CT), access = 0, on_buy[], can_buy[] = "");

/**
* Használd a CanBuy funkciónál
*
* @param addition Leírás a menüben.
*/
native dr_shop_item_addition(addition[]);

/**
* @param item Tárgy ID
* @param cost Új ára a tárgynak
*/
native dr_shop_set_item_cost(item, cost);

#include <amxmodx>
#include <fun>
#include <deathrun_shop>
#include <deathrun_modes>

#define PLUGIN "Deathrun Shop: Items"
#define VERSION "0.1"
#define AUTHOR "Mistrick"

#pragma semicolon 1

#define MAX_USE 3

new g_iGrenadeUsed[33];
new g_iModeDuel;
new g_bDuel;

public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR);

register_event("HLTV", "Event_NewRound", "a", "1=0", "2=0");

dr_shop_add_item("Élet", 100, ITEM_TEAM_T|ITEM_TEAM_CT, 0, "ShopItem_Health", "ShopItem_CanBuy_Health");
dr_shop_add_item("Gravitáció", 100, ITEM_TEAM_T|ITEM_TEAM_CT, 0, "ShopItem_Gravity");
dr_shop_add_item("HE Gránát", 100, ITEM_TEAM_CT, 0, "ShopItem_GrenadeHE", "ShopItem_CanBuy_GrenadeHE");
}
public plugin_cfg()
{
g_iModeDuel = dr_get_mode_by_mark("duel");
}
public client_putinserver(id)
{
g_iGrenadeUsed[id] = MAX_USE;
}
public Event_NewRound()
{
arrayset(g_iGrenadeUsed, MAX_USE, sizeof(g_iGrenadeUsed));
}
public dr_selected_mode(id, mode)
{
g_bDuel = (g_iModeDuel == mode) ? true : false;
}
public ShopItem_Health(id)
{
set_user_health(id, get_user_health(id) + 150);
client_print(id, print_chat, "Vettél +150HP-t.");
}
public ShopItem_Gravity(id)
{
set_user_gravity(id, 0.5);
}
public ShopItem_GrenadeHE(id)
{
g_iGrenadeUsed[id]--;
give_item(id, "weapon_hegrenade");
}
public ShopItem_CanBuy_Health(id)
{
return g_bDuel ? ITEM_DISABLED : ITEM_ENABLED;
}
public ShopItem_CanBuy_GrenadeHE(id)
{
if(g_iGrenadeUsed[id] <= 0)
{
dr_shop_item_addition("\r[Elfogyott]");
return ITEM_DISABLED;
}
new szAddition[32]; formatex(szAddition, charsmax(szAddition), "\y[Van %d DB]", g_iGrenadeUsed[id]);
dr_shop_item_addition(szAddition);
return ITEM_ENABLED;
}