hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.03.28. 20:16



Jelenlévő felhasználók

Jelenleg 236 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 236 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  [ 5 hozzászólás ] 
Szerző Üzenet
HozzászólásElküldve: 2017.12.13. 10:30 
Offline
Jómunkásember
Avatar

Csatlakozott: 2016.02.10. 12:46
Hozzászólások: 429
Megköszönt másnak: 61 alkalommal
Megköszönték neki: 157 alkalommal
Sziasztok.

Megoldható-e, hogy a következő képen látható játékos modell ne legyen áttetsző, amikor 3D-s Kamera nézetbe vagyok?

Kép:

Kép

Az általam használt plugin csatolva!


Csatolmányok:
camera.sma [1.25 KiB]
Letöltve 128 alkalommal.
Hozzászólás jelentése
Vissza a tetejére
   
HozzászólásElküldve: 2017.12.13. 13:04 
Offline
Jómunkásember

Csatlakozott: 2016.06.20. 10:23
Hozzászólások: 489
Megköszönt másnak: 47 alkalommal
Megköszönték neki: 15 alkalommal
Dooz írta:
Sziasztok.

Megoldható-e, hogy a következő képen látható játékos modell ne legyen áttetsző, amikor 3D-s Kamera nézetbe vagyok?

Kép:

Kép

Az általam használt plugin csatolva!


Ez a csapattárs átjárás miatt van, mármint nekem az miatt volt ez. :D

_________________
BfS* #Team ~Global Offensive IP: 217.144.54.193:27148

Kép


Hozzászólás jelentése
Vissza a tetejére
   
HozzászólásElküldve: 2017.12.13. 17:20 
Offline
Jómunkásember
Avatar

Csatlakozott: 2016.02.10. 12:46
Hozzászólások: 429
Megköszönt másnak: 61 alkalommal
Megköszönték neki: 157 alkalommal
Mivel csak ez az egy plugin van bent a szerveren, így nem azzal lesz a gond.


Hozzászólás jelentése
Vissza a tetejére
   
HozzászólásElküldve: 2017.12.13. 18:37 
Offline
Őstag
Avatar

Csatlakozott: 2015.07.27. 22:56
Hozzászólások: 1367
Megköszönt másnak: 28 alkalommal
Megköszönték neki: 351 alkalommal
Próbáld ki ezt:

  1. #include <amxmodx>
  2. #include <fakemeta>
  3. #include <hamsandwich>
  4.  
  5. #define VERSION "0.0.2"
  6.  
  7. #define MAX_PLAYERS    32
  8.  
  9. #define USE_TOGGLE 3
  10.  
  11. new g_iPlayerCamera[MAX_PLAYERS+1]
  12.  
  13. new g_bInCamera
  14. //#define MarkUserInCamera(%0)        g_bInCamera |= 1<<(%0&31)
  15. #define ClearUserInCamera(%0)        g_bInCamera &= ~(1<<(%0&31))
  16. #define IsUserInCamera(%0)            ( g_bInCamera & 1<<(%0&31) )
  17. #define ToggleUserCameraState(%0)    g_bInCamera ^= 1<<(%0&31)
  18.  
  19. new g_iMaxPlayers
  20.  
  21. public plugin_init()
  22. {
  23.     register_plugin("Camera View", VERSION, "ConnorMcLeod")
  24.  
  25.     register_clcmd("say /cam", "ClCmd_ToggleCamera")
  26.  
  27.     g_iMaxPlayers = get_maxplayers()
  28. }
  29.  
  30. public ClCmd_ToggleCamera( id )
  31. {
  32.     if( !is_user_alive(id) )
  33.     {
  34.         return
  35.     }
  36.  
  37.     new iEnt = g_iPlayerCamera[id]
  38.     if( !pev_valid(iEnt) )
  39.     {
  40.         static iszTriggerCamera
  41.         if( !iszTriggerCamera )
  42.         {
  43.             iszTriggerCamera = engfunc(EngFunc_AllocString, "trigger_camera")
  44.         }
  45.         iEnt = engfunc(EngFunc_CreateNamedEntity, iszTriggerCamera)
  46.         set_kvd(0, KV_ClassName, "trigger_camera")
  47.         set_kvd(0, KV_fHandled, 0)
  48.         set_kvd(0, KV_KeyName, "wait")
  49.         set_kvd(0, KV_Value, "999999")
  50.         dllfunc(DLLFunc_KeyValue, iEnt, 0)
  51.  
  52.         set_pev(iEnt, pev_spawnflags, SF_CAMERA_PLAYER_TARGET|SF_CAMERA_PLAYER_POSITION)
  53.         set_pev(iEnt, pev_flags, pev(iEnt, pev_flags) | FL_ALWAYSTHINK)
  54.  
  55.         dllfunc(DLLFunc_Spawn, iEnt)
  56.  
  57.         g_iPlayerCamera[id] = iEnt
  58.     }
  59.  
  60.     ToggleUserCameraState( id )
  61.     CheckForward()
  62.  
  63.     new Float:flMaxSpeed, iFlags = pev(id, pev_flags)
  64.     pev(id, pev_maxspeed, flMaxSpeed)
  65.  
  66.     ExecuteHam( Ham_Use, iEnt, id, id, USE_TOGGLE, 1.0)
  67.  
  68.     set_pev(id, pev_flags, iFlags)
  69.     // depending on mod, you may have to send SetClientMaxspeed here.
  70.     // engfunc(EngFunc_SetClientMaxspeed, id, flMaxSpeed)
  71.     set_pev(id, pev_maxspeed, flMaxSpeed)
  72. }
  73.  
  74. public SetView(id, iEnt)
  75. {
  76.     if( IsUserInCamera(id) && is_user_alive(id) )
  77.     {
  78.         new iCamera = g_iPlayerCamera[id]
  79.         if( iCamera && iEnt != iCamera )
  80.         {
  81.             new szClassName[16]
  82.             pev(iEnt, pev_classname, szClassName, charsmax(szClassName))
  83.             if( !equal(szClassName, "trigger_camera") ) // should let real cams enabled
  84.             {
  85.                 engfunc(EngFunc_SetView, id, iCamera) // shouldn't be always needed
  86.                 return FMRES_SUPERCEDE
  87.             }
  88.         }
  89.     }
  90.     return FMRES_IGNORED
  91. }
  92.  
  93. public client_disconnect(id)
  94. {
  95.     new iEnt = g_iPlayerCamera[id]
  96.     if( pev_valid(iEnt) )
  97.     {
  98.         engfunc(EngFunc_RemoveEntity, iEnt)
  99.     }
  100.     g_iPlayerCamera[id] = 0
  101.     ClearUserInCamera(id)
  102.     CheckForward()
  103. }
  104.  
  105. public client_putinserver(id)
  106. {
  107.     g_iPlayerCamera[id] = 0
  108.     ClearUserInCamera(id)
  109. }
  110.  
  111. get_cam_owner(iEnt)
  112. {
  113.     static id
  114.     for(id = 1; id<=g_iMaxPlayers; id++)
  115.     {
  116.         if( g_iPlayerCamera[id] == iEnt )
  117.         {
  118.             return id
  119.         }
  120.     }
  121.     return 0
  122. }
  123.  
  124. public Camera_Think( iEnt )
  125. {
  126.     static id
  127.     if( !(id = get_cam_owner( iEnt )) )
  128.     {
  129.         return
  130.     }
  131.  
  132.     static Float:fVecPlayerOrigin[3], Float:fVecCameraOrigin[3], Float:fVecAngles[3], Float:fVecBack[3]
  133.  
  134.     pev(id, pev_origin, fVecPlayerOrigin)
  135.     pev(id, pev_view_ofs, fVecAngles)
  136.     fVecPlayerOrigin[2] += fVecAngles[2]
  137.  
  138.     pev(id, pev_v_angle, fVecAngles)
  139.  
  140.     // See player from front ?
  141.     //fVecAngles[0] = 15.0
  142.     //fVecAngles[1] += fVecAngles[1] > 180.0 ? -180.0 : 180.0
  143.  
  144.     angle_vector(fVecAngles, ANGLEVECTOR_FORWARD, fVecBack)
  145.  
  146.     //Move back to see ourself (150 units)
  147.     fVecCameraOrigin[0] = fVecPlayerOrigin[0] + (-fVecBack[0] * 150.0)
  148.     fVecCameraOrigin[1] = fVecPlayerOrigin[1] + (-fVecBack[1] * 150.0)
  149.     fVecCameraOrigin[2] = fVecPlayerOrigin[2] + (-fVecBack[2] * 150.0)
  150.  
  151.     engfunc(EngFunc_TraceLine, fVecPlayerOrigin, fVecCameraOrigin, IGNORE_MONSTERS, id, 0)
  152.     static Float:flFraction
  153.     get_tr2(0, TR_flFraction, flFraction)
  154.     if( flFraction != 1.0 ) // adjust camera place if close to a wall
  155.     {
  156.         flFraction *= 150.0
  157.         fVecCameraOrigin[0] = fVecPlayerOrigin[0] + (-fVecBack[0] * flFraction)
  158.         fVecCameraOrigin[1] = fVecPlayerOrigin[1] + (-fVecBack[1] * flFraction)
  159.         fVecCameraOrigin[2] = fVecPlayerOrigin[2] + (-fVecBack[2] * flFraction)
  160.     }
  161.  
  162.     set_pev(iEnt, pev_origin, fVecCameraOrigin)
  163.     set_pev(iEnt, pev_angles, fVecAngles)
  164. }
  165.  
  166. CheckForward()
  167. {
  168.     static HamHook:iHhCameraThink, iFhSetView
  169.     if( g_bInCamera )
  170.     {
  171.         if( !iFhSetView )
  172.         {
  173.             iFhSetView = register_forward(FM_SetView, "SetView")
  174.         }
  175.         if( !iHhCameraThink )
  176.         {
  177.             iHhCameraThink = RegisterHam(Ham_Think, "trigger_camera", "Camera_Think")
  178.         }
  179.         else
  180.         {
  181.             EnableHamForward( iHhCameraThink )
  182.         }
  183.     }
  184.     else
  185.     {
  186.         if( iFhSetView )
  187.         {
  188.             unregister_forward(FM_SetView, iFhSetView)
  189.             iFhSetView = 0
  190.         }
  191.         if( iHhCameraThink )
  192.         {
  193.             DisableHamForward( iHhCameraThink )
  194.         }
  195.     }
  196. }

Ők köszönték meg regener nek ezt a hozzászólást: Dooz (2017.12.14. 09:23)
  Népszerűség: 2.27%


Hozzászólás jelentése
Vissza a tetejére
   
HozzászólásElküldve: 2017.12.14. 09:23 
Offline
Jómunkásember
Avatar

Csatlakozott: 2016.02.10. 12:46
Hozzászólások: 429
Megköszönt másnak: 61 alkalommal
Megköszönték neki: 157 alkalommal
Köszönöm, tökéletesen müködik. :)


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  [ 5 hozzászólás ] 


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 30 vendég


Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole