hlmod.hu

ÜDV egy olyan plugint szeretnék kérni mint a kés választó csak awp választóban hogy a skint át cserélje soundot nem kell előre is köszi!

ha adod a modelleket vagy az elérési útjukat megírom

_________________

Megírom én hagyd csak crazy:D amúgy drop parancsra is előjöjjön a menü, vagy /awp vagy mi? picit részletesebben

drop parancsra? az az eldobás, mit akarsz te arra menüt?

_________________
http://www.ebateam.eu/

A hangokra senki nem kíváncsi

[spoiler]Az awpmenu_on cvarral tudod kikapcsolni és bekapcsolni
Használat:
A MAX_WP ben beállítod mennyi awpt szeretnél
A neveket megváltoztathatod, átírhatod, bővítheted. Akár 10 model is lehet.
A P és V modeleknél ugyanez. A pontos elérési utat add meg.
Fontos: Ugyanannyi név, p model, és v model legyen.

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Awp menu"
#define VERSION "1.0"
#define AUTHOR "HunGamer"

#define MAX_WP 4

new OnOff

new valasztott[33]

new const awp_name[MAX_WP+1][] =
{
   "",
   "Elso AWP",//Elso awp neve
   "Masodik AWP",//Masodik awp neve
   "Harmadik AWP",//Harmadik awp neve
   "Negyedik AWP"//Negyedik awp neve és így tovább
}
new const awp_p_model[MAX_WP+1][] =
{
   "",
   "models/awpmenu/p_awp1.mdl",//Elso P modelje
   "models/awpmenu/p_awp2.mdl",//Masodik P modelje
   "models/awpmenu/p_awp3.mdl",//Harmadik P modelje
   "models/awpmenu/p_awp4.mdl"//Negyedik P modelje és így tovább
}
new const awp_v_model[MAX_WP+1][] =
{
   "",
   "models/awpmenu/v_awp1.mdl",//Elso V modelje
   "models/awpmenu/v_awp2.mdl",//Masodik V modelje
   "models/awpmenu/v_awp3.mdl",//Harmadik V modelje
   "models/awpmenu/v_awp4.mdl"//Negyedik V modelje és így tovább
}

public plugin_init()
{
   register_plugin(PLUGIN, VERSION, AUTHOR)
   register_event("CurWeapon", "Event_Change_Weapon", "be", "1=1")
   register_clcmd("say /awp", "awpmenu")
   OnOff = register_cvar("awpmenu_on", "1")
}
public plugin_precache() 
{
   for(new i=1; i<=MAX_WP; i++)
   {
      precache_model(awp_p_model[i])     
      precache_model(awp_v_model[i])
   }

   return PLUGIN_CONTINUE
}
public awpmenu(id)
{
   if(get_pcvar_num(OnOff))
   {
      if(is_user_alive(id))
      {
         new szTempid[10]
         new Menu = menu_create("Awp menu", "awpmenuh")
         
         for(new i=1; i<=MAX_WP; i++)
         {
            num_to_str(i, szTempid, 9)
            menu_additem(Menu, awp_name[i], szTempid)
         }
         menu_setprop(Menu, MPROP_EXIT, MEXIT_ALL)
         menu_display(id, Menu)
      }
      else
      {
         client_print(id, print_chat, "Halott nem hasznalhatja")
      }
   }
   else
   {
      client_print(id, print_chat, "A valasztas jelenleg ki van kapcsolva")
   }
   return PLUGIN_HANDLED
}
public client_connect(id)
{
   valasztott[id] = 0
}
public client_disconnect(id)
{
   valasztott[id] = 0
}
public awpmenuh(id, menu, item)
{
   if( item == MENU_EXIT )
   {
      menu_destroy(menu)
      return PLUGIN_HANDLED
   }
   new data[6], iName[64]
   new access, callback
   menu_item_getinfo(menu, item, access, data,5, iName, 63, callback)
   
   new key = str_to_num(data)
   
   valasztott[id] = key
   set_pev(id, pev_viewmodel2, awp_v_model[key])
   set_pev(id, pev_weaponmodel2, awp_p_model[key])
   
   menu_destroy(menu)
   return PLUGIN_HANDLED
}
public Event_Change_Weapon(id)
{
   new weaponID = read_data(2) 
   
   if(weaponID == CSW_AWP && get_pcvar_num(OnOff) && valasztott[id])
   {
      set_pev(id, pev_viewmodel2, awp_v_model[valasztott[id]])
      set_pev(id, pev_weaponmodel2, awp_p_model[valasztott[id]])
   }
   return PLUGIN_CONTINUE 
}

[/spoiler]

_________________
Megköszönni nem szégyen!
Csak kattints a jelre. --->

Olyan kellene hogy beírja mondjuk hogy /awp és választhat a sknikek kozul de a skinek neveit sárgán írja a menüben és a fmodel elérési utja lehetne pl: /model/awp/awp1.mdl| /model/awp/awp2.mdl kb így meglehetne oldani???
jah meg hogy az összes körre vonatkozzon ne csak 1 re lécci

Ott van amit írtam (ha nem vetted volna észre: a spoilerben van).
Át tudod írni a neveket és az elérési utakat.
(Gondolom nem kell mondani hogy a P model az az amit más játékosnál látsz, a V model meg az amit a saját kezedben.)

_________________
Megköszönni nem szégyen!
Csak kattints a jelre. --->

Köszi HunGamer!

Szívesen. Ha elakadtál segítek. A spoilerben írtam egy kis segítséget hogy kell használni.

_________________
Megköszönni nem szégyen!
Csak kattints a jelre. --->

betudja az valaki nekem írni ebbe a pluginba hogy ne parancsra jöjjön elő a menü hanem akkor amikor felveszi az awp-t?