hlmod.hu

Magyar Half-Life Mód közösség!
Pontos idő: 2024.03.28. 13:26



Jelenlévő felhasználók

Jelenleg 277 felhasználó van jelen :: 2 regisztrált, 0 rejtett és 275 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: Bing [Bot], Google [Bot] az elmúlt 5 percben aktív felhasználók alapján

Utoljára aktív
Ahhoz hogy lásd ki volt utoljára aktív, be kell jelentkezned.



Az oldal teljeskörű
használatához regisztrálj.

Regisztráció

Kereső


Új téma nyitása  Hozzászólás a témához  [ 32 hozzászólás ]  Oldal Előző 1 2 3 4 Következő
Szerző Üzenet
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.02. 11:17 
Offline
Őskövület
Avatar

Csatlakozott: 2012.03.22. 18:22
Hozzászólások: 2978
Megköszönt másnak: 115 alkalommal
Megköszönték neki: 368 alkalommal
Amit írtál (vagy Nandee nem tudom) az nem azt nézi hogy csatlakozva van-e és hogy él-e?

_________________
Blasenkampfwagen

https://discord.gg/uBYnNnZP
GTA:PURSUIT MTA


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.02. 12:40 
Offline
Tud valamit
Avatar

Csatlakozott: 2011.12.23. 16:16
Hozzászólások: 100
Megköszönt másnak: 4 alkalommal
Nandee írta:
Használj podbotot és menni fog ;)

Mit értesz ezalatt?

_________________
[mozgo]Counter-Strike Source[/mozgo]
[kozep]Kalapács mod
Fun_VP3 Pálya
Anti Frag Lopó & Sebzés Kiíró & Kezdő Kill Blockoló

Menekülj![/kozep]


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.02. 13:02 
Offline
Félisten
Avatar

Csatlakozott: 2010.09.16. 20:57
Hozzászólások: 950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
Bence én mindig biztosra megyek, nemakarok runtime errorokat :D
PodBot

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.02. 13:33 
Offline
Félisten

Csatlakozott: 2012.01.07. 21:10
Hozzászólások: 850
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 154 alkalommal
És fegyver kódot küldesz?:) Kíváncsi vagyok a lövési sebesség/ujratöltési idő/ előhúzási idő stb re

_________________
Megköszönni nem szégyen!
Csak kattints a Kép jelre. --->


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.02. 13:50 
Offline
Félisten
Avatar

Csatlakozott: 2010.09.16. 20:57
Hozzászólások: 950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
holnap talán ;)

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.02. 17:24 
Offline
Félisten
Avatar

Csatlakozott: 2010.09.16. 20:57
Hozzászólások: 950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
erre...
Szerk.:
Amúgy a sebzést máshogy nem tudod megoldani meg a pluginokat nem a botoknak írjuk...
Ha szeretnéd hogy sebezzen akkor be kell rakni a PodBot-ot...

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.03. 08:10 
Offline
Félisten
Avatar

Csatlakozott: 2010.09.16. 20:57
Hozzászólások: 950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
2,5 órás munka becsüljétek meg, több nem jutott eszembe, amit belerakhatnék :)
Ha tetszik és érthető akkor meglehet köszönni :D
A modellt szerintem mindenki megtalálja :P
Ha valakinek kérdése van írjon!
Arany ak47 Nandee módra:
SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <fakemeta>
  3. #include <fakemeta_util>
  4. #include <engine>
  5. #include <xs>
  6. #include <fun>
  7. #include <hamsandwich>
  8. #include <cstrike>
  9.  
  10. //Az alsó stock része(drop_pri)
  11. new const priwpns[][] = {
  12. "weapon_shield",
  13. "weapon_scout",
  14. "weapon_xm1014",
  15. "weapon_mac10",
  16. "weapon_aug",
  17. "weapon_ump45",
  18. "weapon_sg550",
  19. "weapon_galil",
  20. "weapon_famas",
  21. "weapon_awp",
  22. "weapon_mp5navy",
  23. "weapon_m249",
  24. "weapon_m3",
  25. "weapon_m4a1",
  26. "weapon_tmp",
  27. "weapon_g3sg1",
  28. "weapon_sg552",
  29. "weapon_ak47",
  30. "weapon_p90"
  31. }
  32.  
  33. #define GAK47_WEAPONKEY 12553 //ez teljesen mindegy mi csak random legyen és két fegyónál ne használjuk egyan azt...
  34.  
  35. new bool:has_gak47[33]
  36. new lastammo[33],in_reload[33],gak_clip[33]
  37.  
  38. new Float:cl_pushangle[33][3]
  39.  
  40. new v_model[64] = "models/v_goldak47.mdl"
  41. new p_model[64] = "models/p_goldak47.mdl"
  42. new w_model[64] = "models/w_goldak47.mdl"
  43.  
  44. new cvar_dmgx,cvar_cost,cvar_recoil,cvar_rof,cvar_clip,cvar_ammo,cvar_reload_time
  45.  
  46. public plugin_init() {
  47. register_plugin("Arany AK","1.0","Nandee")
  48.  
  49. cvar_dmgx=register_cvar("gak47_dmgx","1.8")//Sebzés szorzó
  50. cvar_cost=register_cvar("gak47_cost","5000")//Ár
  51. cvar_recoil=register_cvar("gak47_recoil","1.5")//Visszalökés szorzó
  52. cvar_rof=register_cvar("gak47_rof","1.2")//Sebzés sebesség szorzó(Rate of fire)
  53. cvar_clip=register_cvar("gak47_clip","45")//Egyszerre betárazható golyók száma
  54. cvar_ammo=register_cvar("gak47_ammo","4")//Tárolható tárak száma
  55. cvar_reload_time=register_cvar("gak47_reload_time","4.0")//Újratöltési idő szorzó
  56.  
  57. register_clcmd("say /gak47","buy_gak47")
  58. register_clcmd("weapon_gak47","switch_weapon")
  59.  
  60. register_event("CurWeapon","event_curwpn","be","1=1")
  61. register_event("CurWeapon","make_tracer", "be", "1=1", "3>0")
  62. register_event("DeathMsg","event_death","a")
  63. register_message(get_user_msgid("DeathMsg"),"msg_death")
  64. register_forward(FM_SetModel, "fw_setmodel")
  65. RegisterHam(Ham_Item_AddToPlayer,"weapon_ak47","hevent_atp",.Post=true)
  66. RegisterHam(Ham_TakeDamage,"player","hevent_damage")
  67. RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_ak47", "hevent_primary_attack")
  68. RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_ak47", "hevent_primary_attack_post",1)
  69. RegisterHam(Ham_Item_PostFrame,"weapon_ak47","hevent_postframe")
  70. RegisterHam(Ham_Weapon_Reload,"weapon_ak47","hevent_reload")
  71. RegisterHam(Ham_Weapon_Reload,"weapon_ak47","hevent_reload_post",1)
  72. }
  73.  
  74. public plugin_precache()
  75. {
  76. precache_model(p_model)
  77. precache_model(v_model)
  78. precache_model(w_model)
  79. }
  80. //Vásárlás
  81. public buy_gak47(id)
  82. {
  83. new cost=get_pcvar_num(cvar_cost)
  84. if(!is_user_alive(id)||!is_user_connected(id))
  85. return
  86. else if(cs_get_user_money(id)<cost)
  87. {
  88. client_print(id,print_chat,"[GAK47] Nem eleg a penzed!")
  89. return
  90. }
  91. else if(has_gak47[id]&&user_has_weapon(id,CSW_AK47))
  92. {
  93. client_print(id,print_chat,"[GAK47] Neked mar van Arany AK47-d!")
  94. return
  95. }
  96. else
  97. {
  98. client_print(id,print_chat,"[GAK47] Sikeres vasarlas!")
  99. cs_set_user_money(id,cs_get_user_money(id)-cost)
  100. drop_pri(id)
  101. new wpn=give_item(id,"weapon_ak47")
  102. if(wpn>0)
  103. {
  104. cs_set_weapon_ammo(wpn,get_pcvar_num(cvar_clip))
  105. //Ha a következő sort kitörlöd, akkor nem teljes tárral kapja
  106. cs_set_user_bpammo (id,CSW_AK47,get_pcvar_num(cvar_clip)*get_pcvar_num(cvar_ammo))
  107. }
  108. engclient_cmd(id,"weapon_ak47")
  109. has_gak47[id]=true
  110. replace_weapon_models(id)
  111. }
  112. }
  113. //Csatlakozáskor/lekapcsolódáskor/halálkor elveszik
  114. public client_connect(id)
  115. has_gak47[id]=false
  116.  
  117. public client_disconnect(id)
  118. has_gak47[id]=false
  119.  
  120. public event_death()
  121. has_gak47[read_data(2)]=false
  122. //konzol üzenet megváltoztatása
  123. public msg_death(msg_id, msg_dest, id)
  124. {
  125. new weapon[33], attacker
  126. get_msg_arg_string(4,weapon, charsmax(weapon))
  127. attacker=get_msg_arg_int(1)
  128. if(equal(weapon,"ak47")&&get_user_weapon(attacker)==CSW_AK47&&has_gak47[attacker]&&is_user_connected(attacker))
  129. set_msg_arg_string(4,"golden ak47")
  130. return PLUGIN_CONTINUE
  131. }
  132. //konzol parancsra elővétel, ez szokott lenni a fegyvereknél...
  133. public switch_weapon(id)
  134. {
  135. if(has_gak47[id]&&get_user_weapon(id)!=CSW_AK47)
  136. engclient_cmd(id,"weapon_ak47")
  137. }
  138. //ha ak47 van a kezébe és van gold ak-ja akkor megszorozza a sebzést a cvarral
  139. public hevent_damage(id, inflictor, attacker, Float:damage)
  140. {
  141. if(get_user_weapon(attacker)==CSW_AK47&&has_gak47[attacker])
  142. {
  143. SetHamParamFloat(4,damage*get_pcvar_float(cvar_dmgx))
  144. }
  145. }
  146. //Modellek megváltoztatása
  147. public replace_weapon_models(id)
  148. {
  149. if(is_user_alive(id)&&get_user_weapon(id)==CSW_AK47&&has_gak47[id])
  150. {
  151. set_pev(id, pev_viewmodel2,v_model)
  152. set_pev(id, pev_weaponmodel2,p_model)
  153. }
  154. }
  155. //Amikor ak47-re vált modellt változtat
  156. //Lövés sebesség beállítása
  157. public event_curwpn(id)
  158. {
  159. replace_weapon_models(id)
  160. if(is_user_alive(id)&&get_user_weapon(id)==CSW_AK47&&has_gak47[id])
  161. {
  162. new ent=fm_find_ent_by_owner(-1,"weapon_ak47",id)//fm_util kell hozzá!
  163. if(!ent)
  164. return PLUGIN_CONTINUE
  165. new Float:delay,Float:m_delay
  166. delay=get_pdata_float(ent,46,4)*get_pcvar_float(cvar_rof)
  167. m_delay=get_pdata_float(ent,47,4)*get_pcvar_float(cvar_rof)
  168. if(delay>0.0)
  169. {
  170. set_pdata_float(ent,46,delay,4)
  171. set_pdata_float(ent,47,m_delay,4)
  172. }
  173. }
  174. return PLUGIN_HANDLED
  175. }
  176. //Eldobáskor megváltoztatja a modell-t és eltárolja rajta az GAK47_WEAPONKEY-t
  177. //azért hogyha felveszi betudja azonosítani, hogy ez nem sima ak...
  178. public fw_setmodel(ent, model[])
  179. {
  180. if(!is_valid_ent(ent))
  181. return FMRES_IGNORED
  182. new classname[33]
  183. entity_get_string(ent, EV_SZ_classname, classname, charsmax(classname))
  184. if(!equal(classname, "weaponbox"))
  185. return FMRES_IGNORED
  186. new owner=entity_get_edict(ent,EV_ENT_owner)
  187. if(equal(model, "models/w_ak47.mdl"))
  188. {
  189. new weaponid=find_ent_by_owner(-1,"weapon_ak47", ent)
  190. if(!is_valid_ent(weaponid))
  191. return FMRES_IGNORED
  192. if(has_gak47[owner])
  193. {
  194. entity_set_int(weaponid,EV_INT_impulse, GAK47_WEAPONKEY)
  195. has_gak47[owner]=false
  196.  
  197. entity_set_model(ent,w_model)
  198. return FMRES_SUPERCEDE
  199. }
  200. }
  201. return FMRES_IGNORED
  202. }
  203. //Felvételkor megnézi, hogy arany ak-e
  204. public hevent_atp(item,id)
  205. {
  206. if(entity_get_int(item,EV_INT_impulse)==GAK47_WEAPONKEY)
  207. {
  208. has_gak47[id]=true
  209. entity_set_int(item,EV_INT_impulse,0)
  210. }
  211. }
  212. //Visszalökés szorzó beállítása
  213. public hevent_primary_attack(ent)
  214. {
  215. new id = pev(ent,pev_owner)
  216. if(get_user_weapon(id)==CSW_AK47&&has_gak47[id])
  217. pev(id,pev_punchangle,cl_pushangle[id])
  218. return HAM_IGNORED
  219. }
  220.  
  221. public hevent_primary_attack_post(ent)
  222. {
  223. new id = pev(ent,pev_owner)
  224. if(get_user_weapon(id)==CSW_AK47&&has_gak47[id])
  225. {
  226. new Float:push[3]
  227. pev(id,pev_punchangle,push)
  228. xs_vec_sub(push,cl_pushangle[id],push)
  229. xs_vec_mul_scalar(push,get_pcvar_float(cvar_recoil),push)
  230. xs_vec_add(push,cl_pushangle[id],push)
  231. set_pev(id,pev_punchangle,push)
  232. }
  233. return HAM_IGNORED
  234. }
  235. //Arany golyók létrehozása...
  236. public make_tracer(id)
  237. {
  238. new clip=read_data(3)
  239. if(lastammo[id]>clip&&get_user_weapon(id)==CSW_AK47&&has_gak47[id])
  240. {
  241. new o1[3],o2[3]
  242. get_user_origin(id,o1,1)//Fegyver végpontja
  243. get_user_origin(id,o2,4)//Utolsó lövés koordinátája
  244. message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
  245. write_byte(TE_TRACER)//Arany golyók
  246. write_coord(o1[0])//kezdő koordináta x
  247. write_coord(o1[1])//kezdő koordináta y
  248. write_coord(o1[2])//kezdő koordináta z
  249. write_coord(o2[0])//végső koordináta x
  250. write_coord(o2[1])//végső koordináta y
  251. write_coord(o2[2])//végső koordináta z
  252. message_end()
  253. lastammo[id]=clip
  254. }
  255. }
  256. //Lőszer beállítása
  257. public hevent_postframe(ent)
  258. {
  259. new id=pev(ent,pev_owner)
  260. if(!is_user_connected(id)||!has_gak47[id])
  261. return HAM_IGNORED
  262.  
  263. new Float:nextattack=get_pdata_float(id,83, 5)
  264. new bpammo=cs_get_user_bpammo(id, CSW_AK47)
  265. new clip=get_pdata_int(ent,51,4)
  266. new inreload=get_pdata_int(ent,54, 4)
  267.  
  268. if(inreload&&nextattack<= 0.0 )
  269. {
  270. new j=min(get_pcvar_num(cvar_clip)-clip,bpammo)
  271. set_pdata_int(ent,51,clip+j,4)
  272. cs_set_user_bpammo(id, CSW_AK47, bpammo-j)
  273. set_pdata_int(ent,54, 0,4)
  274. inreload=0
  275. in_reload[id]=0
  276. }
  277. return HAM_IGNORED
  278. }
  279.  
  280.  
  281. public hevent_reload(ent)
  282. {
  283. new id=pev(ent,pev_owner)
  284. if(!is_user_connected(id)||!has_gak47[id])
  285. return HAM_IGNORED
  286. gak_clip[id] = -1
  287.  
  288. new bpammo=cs_get_user_bpammo(id, CSW_AK47)
  289. new clip=get_pdata_int(ent,51,4)
  290.  
  291. if(bpammo<=0||clip>=get_pcvar_num(cvar_clip))
  292. return HAM_SUPERCEDE
  293. gak_clip[id]=clip
  294. in_reload[id]=1
  295. return HAM_IGNORED
  296. }
  297.  
  298. public hevent_reload_post(ent)
  299. {
  300. new id=pev(ent,pev_owner)
  301. if(!is_user_connected(id)||!has_gak47[id]||gak_clip[id]==1)
  302. return HAM_IGNORED
  303.  
  304. new bpammo=cs_get_user_bpammo(id, CSW_AK47)
  305. new clip=get_pdata_int(ent,51,4)
  306. if(bpammo<=0||clip>=get_pcvar_num(cvar_clip))
  307. return HAM_SUPERCEDE
  308.  
  309. set_pdata_int(ent,51,gak_clip[id], 4)
  310. set_pdata_float(ent,48,get_pdata_float(ent,48,4)*get_pcvar_float(cvar_reload_time),4)
  311. set_pdata_float(id,83,get_pdata_float(id,83,5)*get_pcvar_float(cvar_reload_time),5)
  312. set_pdata_int(ent,54,1,4)
  313. return HAM_IGNORED;
  314. }
  315. //:::STOCK:::
  316. //Egy saját stockom(erre copyright van xD)
  317. //Eldobja ez elsődleges fegyvert
  318. stock drop_pri(id)
  319. {
  320. for(new j = 0; j < sizeof priwpns; j++)
  321. {
  322. engclient_cmd(id,"drop", priwpns[j])
  323. }
  324. }

_________________
Weboldalam: nandee.smmg.hu
Kép

Ők köszönték meg Nandee nek ezt a hozzászólást (összesen 2): peti.97 (2012.11.03. 15:46) • Akosch:. (2015.06.24. 03:08)
  Népszerűség: 4.55%


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.03. 09:46 
Offline
Félisten

Csatlakozott: 2012.01.07. 21:10
Hozzászólások: 850
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 154 alkalommal
90%-a ugyanaz mint az enyémnek xD

_________________
Megköszönni nem szégyen!
Csak kattints a Kép jelre. --->


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.03. 09:55 
Offline
Félisten
Avatar

Csatlakozott: 2010.09.16. 20:57
Hozzászólások: 950
Megköszönt másnak: 9 alkalommal
Megköszönték neki: 101 alkalommal
HunGamer írta:
90%-a ugyanaz mint az enyémnek xD

Mit hagytál ki?

_________________
Weboldalam: nandee.smmg.hu
Kép


Hozzászólás jelentése
Vissza a tetejére
   
 Hozzászólás témája: Re: Egyedi fegyver létrehozása
HozzászólásElküldve: 2012.11.03. 15:42 
Offline
Tud valamit
Avatar

Csatlakozott: 2011.12.23. 16:16
Hozzászólások: 100
Megköszönt másnak: 4 alkalommal
Nah, itt az ennyim:
[kozep]Hp lopó kalapács[/kozep]
SMA Forráskód: [ Mindet kijelol ]
  1. #include <amxmodx>
  2. #include <amxmisc>
  3. #include <fakemeta>
  4. #include <fun>
  5. #include <hamsandwich>
  6.  
  7.  
  8. #define PLUGIN "kalapacs"
  9. #define VERSION "1.0"
  10. #define AUTHOR "Itep"
  11.  
  12. new bool:g_hasHammer[33], bol;
  13. new const v_knife[] = "models/v_knife.mdl",
  14. p_knife[] = "models/p_knife.mdl",
  15. v_hammer[] = "models/v_hammer.mdl",
  16. p_hammer[] = "models/p_hammer.mdl";
  17.  
  18.  
  19.  
  20.  
  21.  
  22. public plugin_init() {
  23. register_plugin(PLUGIN, VERSION, AUTHOR)
  24. register_concmd("amx_hammer", "Hammer", ADMIN_BAN,"amx_hammer <id>");
  25. register_event("CurWeapon","elvalt","be","1=1");
  26. register_event("Damage", "tam", "b", "2!0", "3=0", "4!0");
  27. register_event("DeathMsg","event_death","a");
  28. RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_knife", "tam2");
  29. }
  30.  
  31. public plugin_precache() {
  32. precache_model(v_knife);
  33. precache_model(p_knife);
  34. precache_model(v_hammer);
  35. precache_model(p_hammer);
  36. }
  37.  
  38. public Hammer(id, level, cid) {
  39. if (!cmd_access(id, level, cid, 2)) return PLUGIN_HANDLED;
  40.  
  41. new aarg1[3]
  42. read_argv(1,aarg1,2)
  43. new arg1 = str_to_num(aarg1)
  44.  
  45. if (is_user_alive(arg1) && !g_hasHammer[arg1]) {
  46. g_hasHammer[arg1] = true;
  47. if (get_user_weapon(arg1) != CSW_KNIFE) {
  48. engclient_cmd(arg1, "weapon_knife");
  49. set_task(0.1, "akcio", arg1);
  50. return PLUGIN_HANDLED;
  51. } else {
  52. akcio(arg1);
  53. }
  54. } else {
  55. client_cmd(arg1, "cl_righthand ^"1^"");
  56. set_pev(arg1, pev_viewmodel2,v_knife);
  57. set_pev(arg1, pev_weaponmodel2,p_knife);
  58. vege(arg1);
  59. }
  60. return PLUGIN_HANDLED;
  61. }
  62.  
  63. public akcio(id) {
  64. client_cmd(id, "cl_righthand ^"1^"");
  65. set_pev(id, pev_viewmodel2,v_hammer);
  66. set_pev(id, pev_weaponmodel2,p_hammer);
  67. g_hasHammer[id] = true;
  68. }
  69.  
  70. public vege(id) {
  71. g_hasHammer[id] = false;
  72. bol=0;
  73. set_user_noclip(id,bol);
  74. }
  75.  
  76. public client_connect(id)
  77. vege(id);
  78.  
  79. public client_disconnect(id)
  80. vege(id);
  81.  
  82. public event_death()
  83. vege(read_data(2));
  84.  
  85. public elvalt(id) {
  86. if(g_hasHammer[id])
  87. {
  88. if (get_user_weapon(id)==CSW_KNIFE) {
  89. client_cmd(id, "cl_righthand ^"1^"");
  90. set_pev(id, pev_viewmodel2,v_hammer);
  91. set_pev(id, pev_weaponmodel2,p_hammer);
  92. }else {
  93. bol=0;
  94. set_user_noclip(id,bol);
  95. }
  96. }
  97. }
  98.  
  99. public tam2(ent) {
  100. new id = pev(ent, pev_owner);
  101. if (g_hasHammer[id]) {
  102. if (!bol) bol=1; else bol=0;
  103. set_user_noclip(id,bol);
  104. return HAM_SUPERCEDE;
  105. }
  106. return HAM_IGNORED;
  107. }
  108.  
  109. public tam(id)
  110. {
  111. new attacker, damage;
  112. attacker = get_user_attacker(id); damage = read_data(2);
  113. if(g_hasHammer[attacker]&&get_user_weapon(attacker)==CSW_KNIFE)
  114. {
  115. if (get_user_health(id)>1+damage) set_user_health(id,get_user_health(id)-damage);
  116. else set_user_health(id,1);
  117.  
  118. if (get_user_health(attacker)+damage*2<255) set_user_health(attacker,get_user_health(attacker)+damage*2)
  119. else set_user_health(attacker,255)
  120. }
  121. }
  122.  


-) Az amx_hammer <id> parancsra ad 1 kalapácsot.
-) Nem csak sz@r PodBot-ok ellen jó, az alap ellen is.(Ezzel sz@roztam a legtöbbet míg rájöttem, hogy nem csak Ham létezik)
-) 2x-es sebzés, és ezt a sebzést oda adja a használójának Hp formájában (külön levédtem max 255 Hp)
-) A másodlagos támadással át lehet menni a falon, de csak ha a kézben marad a fegyver.
-) Ha meghal, kilép, belép a kalapács tulajdonosa, elveszíti a kalapácsát és a falon átjárást is.
-) Külön le lett még védve: Ha a 2x-es szorzó miatt meghalna, akkor 1 hp-ja marad, a kalapácsütést szenvedőnek.

_________________
[mozgo]Counter-Strike Source[/mozgo]
[kozep]Kalapács mod
Fun_VP3 Pálya
Anti Frag Lopó & Sebzés Kiíró & Kezdő Kill Blockoló

Menekülj![/kozep]


Hozzászólás jelentése
Vissza a tetejére
   
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása  Hozzászólás a témához  [ 32 hozzászólás ]  Oldal Előző 1 2 3 4 Következő


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 28 vendég


Nyithatsz új témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Keresés:
Ugrás:  
Powered by phpBB® Forum Software © phpBB Limited
Magyar fordítás © Magyar phpBB Közösség
Portal: Kiss Portal Extension © Michael O'Toole