hlmod.hu

#include <amxmodx>
#include <colorchat>
#include <engine>
#include <fun>
 
#define MAX_PLAYERS 32
 
#define GIFT_ITEM_NUM 6
new const GIFT_ITEM[GIFT_ITEM_NUM][] = {
	"item_kevlar",
	"item_assaultsuit",
	"weapon_hegrenade",
	"weapon_flashbang",
	"weapon_smokegrenade",
        "weapon_deagle"
}
 
#define GIFT_MODEL "models/w_battery.mdl"
#define GIFT_NAME "gift"
 
public plugin_init() {
	register_plugin("New Round Gift", "0.1", "VEN")
	register_logevent("logevent_round_start", 2, "0=World triggered", "1=Round_Start")
	register_event("RoundTime", "event_round_time", "bc")
	register_touch(GIFT_NAME, "player", "touch_gift")
	register_cvar("amx_newround_gift", "1")
}
 
public plugin_modules() {
	require_module("engine")
	require_module("fun")
}
 
public plugin_precache() {
	precache_model(GIFT_MODEL)
}
 
public logevent_round_start() {
	if (!get_cvar_num("amx_newround_gift"))
		return
 
	new pnum[2], origin[3], minor[2][3], maxor[2][3], bool:compare[2]
	for (new i = 1; i <= MAX_PLAYERS; ++i) {
		if (!is_user_alive(i))
			continue
 
		new team = get_user_team(i) - 1
		if (team != 0 && team != 1)
			continue
 
		pnum[team]++
		get_user_origin(i, origin)
		if (compare[team]) {
			for (new j = 0; j < 3; ++j) {
				if (origin[j] < minor[team][j])
					minor[team][j] = origin[j]
				if (origin[j] > maxor[team][j])
					maxor[team][j] = origin[j]
			}
		}
		else {
			minor[team] = origin
			maxor[team] = origin
			compare[team] = true
		}
	}
	for (new i = 0; i < 2; ++i) {
		if (pnum[i] < 2)
			continue
 
		new gift = create_entity("info_target")
		if (!gift) {
			log_amx("ERROR: Couldn't create gift entity!")
			continue
		}
 
		entity_set_string(gift, EV_SZ_classname, GIFT_NAME)
		entity_set_int(gift, EV_INT_solid, SOLID_TRIGGER)
 
		new Float:gift_origin[3]
		for (new j = 0; j < 3; ++j)
			gift_origin[j] = float(random_num(minor[i][j], maxor[i][j]))
		gift_origin[2] += 40
		entity_set_vector(gift, EV_VEC_origin, gift_origin)
 
		entity_set_model(gift, GIFT_MODEL)
	}
}
 
public touch_gift(gift, id) {
        new name[33]
	new client
	get_user_name(id, name, 32)
 
	ColorChat(client, GREEN, "^3%s ^1ajandekot kapott!", name)  
	give_item(id, GIFT_ITEM[random(GIFT_ITEM_NUM)])
	remove_entity(gift)
}
 
public event_round_time() {
	if (read_data(1) == get_cvar_num("mp_freezetime")) {
		new gift = 0
		while ((gift = find_ent_by_class(gift, GIFT_NAME)))
			remove_entity(gift)
	}
}