hlmod.hu ::Csapatok pénzének mutatása

hlmod.hu https://hlmod.hu/

Csapatok pénzének mutatása https://hlmod.hu/viewtopic.php?f=101&t=13754	Oldal: 1 / 1

Szerző:

Badboy.killer [2014.01.11. 11:38 ]

Hozzászólás témája:

Csapatok pénzének mutatása

Plugin Neve:	Csapatpénzek	Plugint készitette:	K.K.Lv
Játék:	Counter-Strike	Kategória:	Statisztikai
Eredeti link:	Nincs megadva	Jóváhagyó:	norbee.16

A plugin segítségével megtudjuk nézni a csapatok pénzét valamint a csapatodban lévő játékosok pénzét.

Képek:

http://forums.alliedmods.net/attachment.php?attachmentid=56185&d=1261997769

Parancsok (játékban): /money

Cvarok:

stm_on 1/0 - a plugin be és kikapcsolása
stm_st_on 1/0 - a státuszt textbe mutassa vagy ne

Telepítés:

amxx -> addons/amxmodx/plugins mappába
Majd írd be az addons/amxmodx/configs/plugins.ini -be a plugin nevét.

/*
   Ford�totta: BBk - Death of Legend
*/

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define NAME "show teammate's money"
#define VERSION "1.3.1"
#define AUTHOR "K.K.Lv"

new g_max_players, g_sync_creat_statustext, g_sync_creat_list

new bool:g_teammate[33]

new cvar_plugin_on
new cvar_status_on

public plugin_init()
{
	register_plugin(NAME, VERSION, AUTHOR)
	
	RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
	
	register_clcmd("say /money", "clcmd_money")
	
	register_event("StatusValue", "show_teammate_money", "be", "1=2", "2!0")
	register_event("StatusValue", "set_team", "be", "1=1")
	
	cvar_plugin_on = register_cvar("stm_on", "1")
	cvar_status_on = register_cvar("stm_st_on", "1")
	
	g_max_players = get_maxplayers()
	g_sync_creat_statustext = CreateHudSyncObj()
	g_sync_creat_list = CreateHudSyncObj()
}

public clcmd_money(client)
{
	if (!get_pcvar_num(cvar_plugin_on))
	{
		client_print(client, print_chat, "[AMXX]: Csapatok penzenek mutatasa ki volt kapcsolva.")
		return PLUGIN_HANDLED
	}
	show_money(client)
	return PLUGIN_CONTINUE
}

public player_spawn(client)
{
	remove_task(client)
	if (is_user_alive(client) && get_pcvar_num(cvar_plugin_on))
	{
		set_task(1.0, "show_money", client)
	}
}

public show_money(client)
{
	static message[1024];
	static name[32];
	
	new money, id, len;
	
	len = format(message, charsmax(message), "A csapatok penze:^n");
	for (id = 1; id <= g_max_players; id++)
	{
		if (id != client && is_user_connected(id) && cs_get_user_team(id) == cs_get_user_team(client))
		{
			money = cs_get_user_money(id);
			get_user_name(id, name, 31);
			len += format(message[len], charsmax(message) - len, "%-22.22s: %d^n", name, money);
		}
	}
	set_hudmessage(100, 200, 0, 0.05, 0.35, 0, 0.02, 5.0, 0.1, 0.2, 2);
	ShowSyncHudMsg(client, g_sync_creat_list, message);
}

public set_team(id)
	g_teammate[id] = bool:(read_data(2) == 1);

public show_teammate_money(id)
{
	if (!get_pcvar_num(cvar_plugin_on))
		return PLUGIN_HANDLED
	if(!is_user_bot(id) && is_user_connected(id) && get_pcvar_num(cvar_status_on))
	{
		static name[32]
		
		new pid = read_data(2)
		new red = 0, blue = 0
		
		if (cs_get_user_team(pid) == CS_TEAM_T)
			red = 255
		else if(cs_get_user_team(pid) == CS_TEAM_CT)
			blue = 255
		
		get_user_name(pid, name, charsmax(name))
		new money = cs_get_user_money(pid)
		if (g_teammate[id])
		{
			set_hudmessage(red, 50, blue, -1.0, 0.60, 1, 0.01, 0.6, 0.01, 0.01, 8)
			ShowSyncHudMsg(id, g_sync_creat_statustext, "Barat:%s -- Penz:%d", name, money)
		}
		else {
			set_hudmessage(red, 50, blue, -1.0, 0.60, 1, 0.01, 0.6, 0.01, 0.01, 8)
			ShowSyncHudMsg(id, g_sync_creat_statustext, "Ellenseg:%s", name)
		}
	}
	return PLUGIN_CONTINUE
}

public client_disconnect(client)
{
	remove_task(client)
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/