hlmod.hu :: Egy gránátból több

hlmod.hu https://hlmod.hu/

Egy gránátból több https://hlmod.hu/viewtopic.php?f=101&t=18159	Oldal: 1 / 1

Szerző:

alfaanero [ 2014.11.16. 14:20 ]

Hozzászólás témája:

Egy gránátból több

Plugin Neve:	Egy gránátból több	Plugint készitette:	Alexander.3
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Megnézem	Jóváhagyó:	norbee.16

Leírás:
-Ez a plugin annyit tesz lehetővé ,hogy amikor eldobod a gránátodat akkor "szétválik,több lesz belőle" is úgy robban fel.
Nem tudom hogy fogalmazzam meg de itt egy videó

Videó
http://zombie-mod.ru/counter-strike/raz ... enade.html

#include < amxmodx >
#include < engine >
#include < fakemeta >
#include < hamsandwich >

#define NAME			"[ZL] ClusterGrenade"
#define VERSION			"Public [1.0]"
#define AUTHOR			"Alexander.3"

#define TRAIL			
#define SHOCKWAVE		
#define SCREENFADE		
#define SCREENSHACKE		
#define RANDOM

const cluster_num =		10	
const Float:cluster_radius = 	200.0	
const Float:cluster_dradius =	240.0	
const Float:cluster_damage =	100.0

new const cluster_models[] =	"models/w_hegrenade.mdl"	
new const cluster_sprite[] =	"sprites/dexplo.spr"

#if defined TRAIL
new g_Trail
new const cluster_trail[] =	"sprites/laserbeam.spr"		
new cluster_trail_red =		255	
new cluster_trail_green =	0	
new cluster_trail_blue =	50	
#endif

#if defined SHOCKWAVE
new g_sw
new const cluster_sw[] =		"sprites/shockwave.spr"		
new cluster_sw_red =		255	
new cluster_sw_green =		0	
new cluster_sw_blue =		50	
#endif

#if defined SCREENFADE
new cluster_sf_red =		255	
new cluster_sf_green =		0	
new cluster_sf_blue =		50 	
#endif

new g_Exlplosion

public plugin_init() {
	register_plugin(NAME, VERSION, AUTHOR)
	
	RegisterHam(Ham_Think, "grenade", "Hook_Grenade", 1)	
	
	register_touch("cluster_bomb", "*", "Hook_Touch")
}

public Hook_Grenade( Ent ) {
	if (!pev_valid( Ent ))	
		return HAM_IGNORED
	
	static Float:dmgtime
	
	pev(Ent, pev_dmgtime, dmgtime)	
	
	if (dmgtime > get_gametime())	
		return HAM_IGNORED
	
	new szModels[32]
	pev(Ent, pev_model, szModels, charsmax(szModels))	
	
	if (!equal(szModels, "models/w_hegrenade.mdl"))		
		return HAM_IGNORED
	
	new Float:b_origin[3]
	pev(Ent, pev_origin, b_origin)	
	
	for (new i; i < cluster_num; i++) {
		#if defined RANDOM
		cluster_effect()
		#endif
		
		new bomb			
		bomb = create_entity("info_target")		
		engfunc(EngFunc_SetOrigin, bomb, b_origin)	
		engfunc(EngFunc_SetModel, bomb, cluster_models)	
		set_pev(bomb, pev_solid, SOLID_TRIGGER)		
		set_pev(bomb, pev_classname, "cluster_bomb")	
		set_pev(bomb, pev_movetype, MOVETYPE_TOSS)	
		set_pev(bomb, pev_owner, pev(Ent, pev_owner))	
		
		
		new Float:velocity[3]
		velocity[0] = random_float(-(cluster_radius), cluster_radius)	
		velocity[1] = random_float(-(cluster_radius), cluster_radius)
		velocity[2] = cluster_radius + 185.0
		
		set_pev(bomb, pev_velocity, velocity)	
		
		#if defined TRAIL
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
		write_byte(TE_BEAMFOLLOW)
		write_short(bomb)
		write_short(g_Trail)
		write_byte(13)
		write_byte(5)
		write_byte(cluster_trail_red)
		write_byte(cluster_trail_green)
		write_byte(cluster_trail_blue)
		write_byte(255)
		message_end()
		#endif
	}
	set_pev(Ent, pev_flags, FL_KILLME)	
	return HAM_HANDLED
}

public Hook_Touch(grenade, went) {
	if (!pev_valid( grenade ))	
		return
	
	new szWEnt[32]
	pev(went, pev_classname, szWEnt, charsmax(szWEnt))	
	
	if (equal(szWEnt, "cluster_bomb"))	
		return
	
	new Float:origin[3]	
	new victim = -1		
	
	pev(grenade, pev_origin, origin)	
	
	while((victim = engfunc(EngFunc_FindEntityInSphere, victim, origin, cluster_dradius))) {
		if (!is_user_alive( victim ))	
			continue
			
		if (get_user_team(victim) == get_user_team(pev(grenade, pev_owner)))	
			continue
	
		ExecuteHamB(Ham_TakeDamage, victim, 0, grenade, cluster_damage, (1<<24))	
		
		
		message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("Damage"), {0,0,0}, victim)
		write_byte(0)
		write_byte(100)
		write_long(1<<1)
		engfunc(EngFunc_WriteCoord, origin[0])
		engfunc(EngFunc_WriteCoord, origin[1])
		engfunc(EngFunc_WriteCoord, origin[2])
		message_end()
		
		#if defined SCREENFADE
		ZL_ScreenFade(victim, 2, 1, cluster_sf_red, cluster_sf_green, cluster_sf_blue, 130, 1)
		#endif
		
		
		#if defined SCREENSHACKE		
		message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("ScreenShake"), {0,0,0}, victim)
		write_short(1<<14)
		write_short((1<<12) * 8)
		write_short((2<<12) * 7)
		message_end()
		#endif
	}
	
	
	#if defined SHOCKWAVE
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, origin, 0)
	write_byte(TE_BEAMCYLINDER)
	engfunc(EngFunc_WriteCoord, origin[0])
	engfunc(EngFunc_WriteCoord, origin[1])
	engfunc(EngFunc_WriteCoord, origin[2])
	engfunc(EngFunc_WriteCoord, origin[0])
	engfunc(EngFunc_WriteCoord, origin[1])
	engfunc(EngFunc_WriteCoord, origin[2] + cluster_dradius)
	write_short(g_sw)
	write_byte(0)
	write_byte(0)
	write_byte(4)
	write_byte(20)
	write_byte(0)
	write_byte(cluster_sw_red)
	write_byte(cluster_sw_green)
	write_byte(cluster_sw_blue)
	write_byte(255)
	write_byte(0)
	message_end()
	#endif

engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, origin, 0)
	write_byte(TE_EXPLOSION)
	engfunc(EngFunc_WriteCoord, origin[0])
	engfunc(EngFunc_WriteCoord, origin[1])
	engfunc(EngFunc_WriteCoord, origin[2] + 25.0)
	write_short(g_Exlplosion)
	write_byte(20)
	write_byte(10)
	write_byte(0)
	message_end()
	
	
	engfunc(EngFunc_RemoveEntity, grenade)
}

public plugin_precache() {
	g_Exlplosion = precache_model(cluster_sprite)
	#if defined TRAIL
	g_Trail = precache_model(cluster_trail)
	#endif
	#if defined SHOCKWAVE
	g_sw = precache_model(cluster_sw)
	#endif
}

#if defined RANDOM
cluster_effect() {
	#if defined TRAIL
	cluster_trail_red = random(255)
	cluster_trail_green = random(255)
	cluster_trail_blue = random(255)
	#endif
	
	#if defined SHOCKWAVE
	cluster_sw_red = random(255)
	cluster_sw_green = random(255)
	cluster_sw_blue = random(255)
	#endif
	
	#if defined SCREENFADE
	cluster_sf_red = random(255)
	cluster_sf_green = random(255)
	cluster_sf_blue = random(255)
	#endif
}
#endif

stock ZL_ScreenFade(id, Timer, FadeTime, red, green, blue, Alpha, type) {
	if(id) if(!is_user_connected(id)) return

if (Timer > 0xFFFF) Timer = 0xFFFF
	if (FadeTime <= 0) FadeTime = 4
	
	message_begin(id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, get_user_msgid("ScreenFade"), _, id);
	write_short(Timer * 1 << 12)
	write_short(FadeTime * 1 << 12)
	switch (type) {
		case 1: write_short(0x0000)		// IN ( FFADE_IN )
		case 2: write_short(0x0001)		// OUT ( FFADE_OUT )
		case 3: write_short(0x0002)		// MODULATE ( FFADE_MODULATE )
		case 4: write_short(0x0004)		// STAYOUT ( FFADE_STAYOUT )
		default: write_short(0x0001)
	}
	write_byte(red)
	write_byte(green)
	write_byte(blue)
	write_byte(Alpha)
	message_end()
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	david19 [ 2014.11.16. 15:01 ]
Hozzászólás témája:	Re: 1 gránátból több
Érdekes

Szerző:	Somterno [ 2014.11.16. 15:38 ]
Hozzászólás témája:	Re: 1 gránátból több
Am nem sebez az miért van?

Szerző:	alfaanero [ 2014.11.16. 22:04 ]
Hozzászólás témája:	Re: 1 gránátból több
Az nem lehet mivel amikor nyáron teszteltük akkor tökéletesen működött

Szerző:	Zolika_36 [ 2020.12.10. 17:26 ]
Hozzászólás témája:	Re: Egy gránátból több
Hello Nálam sem sebez néha. Van olyan amikor az egyik mapon sebez, a következő mapon már 1HP-t sem

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/