hlmod.hu

#include <amxmodx>
#define ADMIN_CHECK ADMIN_KICK
 
new maxplayers
new gmsgSayText
 
public plugin_init()
{
	register_plugin("Admin Check", "1.51", "OneEyed")
	maxplayers = get_maxplayers()
	gmsgSayText = get_user_msgid("SayText")
	register_clcmd("say", "handle_say")
}
public handle_say(id)
{
	new said[192]
	read_args(said,192)
	if( ( containi(said, "who") != -1 && containi(said, "admin") != -1 ) || contain(said, "/admin") != -1 )
		set_task(0.1,"print_adminlist",id)
 
	return PLUGIN_CONTINUE
}
public print_adminlist(user)
{
	new adminnames[33][32]
	new message[256]
	new id, count, x, len
	for(id = 1 ; id <= maxplayers ; id++)
		if(is_user_connected(id))
			if(get_user_flags(id) & ADMIN_CHECK)
				get_user_name(id, adminnames[count++], 31)
 
	len = format(message, 255, "^x04[S][M] DR] ^x01Jelenlevo adminok:")
	if(count > 0)
	{
		for(x = 0 ; x < count ; x++)
		{
			len += format(message[len], 255-len, "^x04%s%s ", adminnames[x], x < (count-1) ? "^x01 | ":"")
			if(len > 96 )
			{
				print_message(user, message)
				len = format(message, 255, "^x04")
			}
		}
		print_message(user, message)
	}
	else
	{
		format(message, 255, "^x04[S][M] DR] ^x01 Nincs jelen admin ^x03!!!")
		print_message(user, message)
	}
}
print_message(id, msg[])
{
	message_begin(MSG_ONE, gmsgSayText, {0,0,0}, id)
	write_byte(id)
	write_string(msg)
	message_end()
}